将 Android 原生开发套件与 Bazel 搭配使用

报告问题 查看来源 每晚 · 7.2。 · 7.1敬上 · 7.0。 · 6.5 · 6.4。

如果您刚开始接触 Bazel，请先学习使用 Bazel 教程。

概览

Bazel 可以在许多不同的构建配置中运行，包括使用 Android 原生开发套件 (NDK) 工具链。这意味着 您可以直接在 Android 中编译 cc_library 和 cc_binary 规则 Bazel。Bazel 使用 android_ndk_repository 代码库完成此操作 规则。

前提条件

请确保您已安装 Android SDK 和 NDK。

如需设置 SDK 和 NDK，请将以下代码段添加到 WORKSPACE 中：

android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

如需详细了解 android_ndk_repository 规则，请参阅构建 百科全书条目。

如果您使用的是最新版本的 Android NDK（r22 及更高版本），请使用 android_ndk_repository 的 Starlark 实现。 请按照 自述文件。

快速入门

如需构建适用于 Android 的 C++，只需将 cc_library 依赖项添加到您的 android_binary 或 android_library 规则。

例如，假设存在以下某个 Android 应用的 BUILD 文件：

# In <project>/app/src/main/BUILD.bazel

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

此 BUILD 文件会生成以下目标图表：

图 1. 具有 cc_library 依赖项的 Android 项目的构建图。

如需构建应用，只需运行以下命令：

bazel build //app/src/main:app

bazel build 命令会编译 Java 文件、Android 资源文件以及 cc_library 规则，并将所有内容打包到 APK 中：

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel 会将所有 cc_library 编译成一个共享对象 (.so) 文件， 针对 armeabi-v7a ABI。要更改此 SDK 或针对 多个 ABI，请参阅关于配置目标 ABI.

示例设置

Bazel 示例 代码库。

在 BUILD.bazel 文件中，使用 android_binary 定义了三个目标， android_library 和 cc_library 规则。

android_binary 顶级目标会构建 APK。

cc_library 目标包含具有 JNI 函数的单个 C++ 源文件 实现：

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

android_library 目标用于指定 Java 源文件、资源文件以及 依赖于 cc_library 目标。在此示例中，MainActivity.java 会加载 共享对象文件 libapp.so，并定义了 JNI 的方法签名 函数：

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

注意： 原生库的名称来自于顶部名称为 android_binary 级目标。在此示例中，它是 app。

配置 STL

如需配置 C++ STL，请使用 --android_crosstool_top 标志。

bazel build //:app --android_crosstool_top=target label

@androidndk 中可用的 STL 包括：

STL	目标标签
STLport	@androidndk//:toolchain-stlport
libc++	@androidndk//:toolchain-libcpp
gnustl	@androidndk//:toolchain-gnu-libstdcpp

对于 r16 及更低版本，默认的 STL 为 gnustl。对于 r17 及更高版本 libc++。为方便起见，目标 @androidndk//:default_crosstool 为 别名为各自的默认 STL。

请注意，从 r18 开始，STLport 和 gnustl 将 已移除， 使 libc++ 成为 NDK 中唯一的 STL。

请参阅 NDK 文档 。

配置目标 ABI

如需配置目标 ABI，请使用 --fat_apk_cpu 标志，如下所示：

bazel build //:app --fat_apk_cpu=comma-separated list of ABIs

默认情况下，Bazel 会为 armeabi-v7a 构建原生 Android 代码。针对 x86 进行构建 （例如对于模拟器），请传递 --fat_apk_cpu=x86。为多个 APK 创建一个胖 APK 则可以指定多个 CPU：--fat_apk_cpu=armeabi-v7a,x86。

如果指定了多个 ABI，Bazel 将构建一个 APK，其中包含共享的 对象。

根据 NDK 修订版本和 Android API 级别，以下 ABI 可 可用：

NDK 修订版本	ABI
16 及更低版本	armeabi、armeabi-v7a、arm64-v8a、mips、mips64、x86、x86_64
17 岁及以上	armeabi-v7a、arm64-v8a、x86、x86_64

请参阅 NDK 文档 详细了解这些 ABI。

不建议在发布 build 中使用多 ABI Fat APK，因为它们会增加 APK 的大小，但对于开发和 QA 构建很有用。

选择 C++ 标准

使用以下标志根据 C++ 标准进行构建：

C++ 标准	标志
C++98	默认，无需任何标志
C++11	--cxxopt=-std=c++11
C++14	--cxxopt=-std=c++14

例如：

bazel build //:app --cxxopt=-std=c++11

详细了解如何传递编译器标记和链接器标记（使用 --cxxopt、--copt 和 --linkopt中的用户手册。

编译器标记和链接器标记也可以指定为 cc_library 中的属性 使用 copts 和 linkopts。例如：

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

与平台和工具链集成

Bazel 的配置模型正朝着 平台和 工具链。如果您的 build 使用 --platforms 标志来选择架构或操作系统 您需要将 --extra_toolchains 标志传递给 Bazel 才能使用 NDK。

例如，如需与由 Google 提供的 android_arm64_cgo 工具链集成，请执行以下操作： 不仅要传递 --extra_toolchains=@androidndk//:all --platforms 标志。

bazel build //my/cc:lib \
  --platforms=@io_bazel_rules_go//go/toolchain:android_arm64_cgo \
  --extra_toolchains=@androidndk//:all

您也可以直接在 WORKSPACE 文件中注册它们：

android_ndk_repository(name = "androidndk")
register_toolchains("@androidndk//:all")

注册这些工具链会告知 Bazel 在 NDK BUILD 中查找它们 （适用于 NDK 20）文件：

toolchain(
  name = "x86-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_32",
  ],
  toolchain = "@androidndk//:x86-clang8.0.7-libcpp",
)

toolchain(
  name = "x86_64-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_64",
  ],
  toolchain = "@androidndk//:x86_64-clang8.0.7-libcpp",
)

toolchain(
  name = "arm-linux-androideabi-clang8.0.7-v7a-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:arm",
  ],
  toolchain = "@androidndk//:arm-linux-androideabi-clang8.0.7-v7a-libcpp",
)

toolchain(
  name = "aarch64-linux-android-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:aarch64",
  ],
  toolchain = "@androidndk//:aarch64-linux-android-clang8.0.7-libcpp",
)

工作原理：引入 Android 配置转换

android_binary 规则可以明确要求 Bazel 在 Android 兼容的配置，确保 Bazel 构建能够正常运行， 除了 --fat_apk_cpu 和 --android_crosstool_top 之外， ABI 和 STL 配置。

在后台，这种自动配置使用 Android 配置 过渡效果。

兼容的规则（如 android_binary）会自动更改 将其依赖项配置为 Android 配置，因此 build 的 Android 专用子树会受到影响。构建的其他部分 均使用顶级目标配置进行处理。甚至 在两种配置中都处理同一个目标（如果 来支持这一点

将 Bazel 置于与 Android 兼容的配置中后， 顶级过渡期，或者由于更高级别的过渡点而额外增加过渡 不会进一步修改配置。

唯一会触发向 Android 转换的内置位置 是 android_binary 的 deps 属性。

注意 ：android_binary 的 data 属性是有意避免的 触发过渡。此外，android_local_test 和 android_library 故意完全不触发过渡。

例如，如果您尝试使用 cc_library 构建 android_library 目标， 依赖项，则可能会遇到有关缺少 JNI 的错误 标头：

ERROR: project/app/src/main/BUILD.bazel:16:1: C++ compilation of rule '//app/src/main:jni_lib' failed (Exit 1)
app/src/main/cpp/native-lib.cpp:1:10: fatal error: 'jni.h' file not found
#include <jni.h>
         ^~~~~~~
1 error generated.
Target //app/src/main:lib failed to build
Use --verbose_failures to see the command lines of failed build steps.

理想情况下，这些自动转换应该能够让 Bazel 在 大多数情况下都是这样。但是，如果 Bazel 命令行上的目标已经 例如 C++ 开发者测试特定的 cc_library，则必须使用自定义 --crosstool_top。

在不使用 android_binary 的情况下构建适用于 Android 的 cc_library

如需针对 Android 构建独立的 cc_binary 或 cc_library，而不使用 android_binary，请使用 --crosstool_top、--cpu 和 --host_crosstool_top 标志。

例如：

bazel build //my/cc/jni:target \
      --crosstool_top=@androidndk//:default_crosstool \
      --cpu=<abi> \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

在此示例中，我们构建了顶级 cc_library 和 cc_binary 目标 使用 NDK 工具链。不过，这样会导致需要构建 Bazel 自己的托管工具 NDK 工具链（以及 Android 也如此），因为主机工具链是 从目标工具链复制而来的命令。要解决此问题，请指定 --host_crosstool_top将变为@bazel_tools//tools/cpp:toolchain至 明确设置主机的 C++ 工具链。

使用此方法，整个 build 树都会受到影响。

注意 ：命令行中的所有目标都必须与 针对 Android 进行构建时，可能会指定这些标志，这可能会导致 可以使用Bazel 通配符 /... 和 :all。

这些标志可以放入 bazelrc 配置（每个 ABI 一个）中， project/.bazelrc：

common:android_x86 --crosstool_top=@androidndk//:default_crosstool
common:android_x86 --cpu=x86
common:android_x86 --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

common:android_armeabi-v7a --crosstool_top=@androidndk//:default_crosstool
common:android_armeabi-v7a --cpu=armeabi-v7a
common:android_armeabi-v7a --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

# In general
common:android_<abi> --crosstool_top=@androidndk//:default_crosstool
common:android_<abi> --cpu=<abi>
common:android_<abi> --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

然后，如需为 x86 构建 cc_library，请运行以下命令：

bazel build //my/cc/jni:target --config=android_x86

通常，此方法适用于较低级别的目标（例如 cc_library），或者在 您清楚自己要构建的是什么？依赖于自动配置 为您期望的高层级目标从 android_binary 转换 构建大量不受您控制的目标