C++ बिल्ड के इस्तेमाल के सामान्य उदाहरण

समस्या की शिकायत करें सोर्स देखें

यहां आपको Basel के साथ C++ प्रोजेक्ट बनाने के लिए, इस्तेमाल के कुछ सबसे सामान्य उदाहरण मिलेंगे. अगर आपने पहले से ऐसा नहीं किया है, तो Basel के साथ C++ प्रोजेक्ट बनाना शुरू करने के लिए, ट्यूटोरियल को पूरा करें.Babel का परिचय: C++ प्रोजेक्ट बनाने के बारे में जानकारी

cc_library और hdrs हेडर फ़ाइलों के बारे में जानकारी पाने के लिए, cc_library देखें.

टारगेट में कई फ़ाइलें शामिल करना

ग्लोब की मदद से, एक ही टारगेट में कई फ़ाइलें शामिल की जा सकती हैं. उदाहरण के लिए:

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

इस टारगेट की मदद से, Basel को सभी .cc और .h फ़ाइलें उसी डायरेक्ट्री में मिलेंगी. साथ ही, वह BUILD फ़ाइल भी बनाएगा जिसमें यह टारगेट शामिल है. इसमें सबडायरेक्ट्री शामिल नहीं हैं.

ट्रांज़िट में शामिल हैं

अगर किसी फ़ाइल में हेडर है, तो सोर्स के तौर पर उस फ़ाइल का कोई भी नियम (यानी, वह फ़ाइल srcs, hdrs या textual_hdrs एट्रिब्यूट में हो) शामिल किए गए हेडर की लाइब्रेरी के नियम पर निर्भर होना चाहिए. वहीं, सिर्फ़ डायरेक्ट डिपेंडेंसी को डिपेंडेंसी के तौर पर बताना ज़रूरी है. उदाहरण के लिए, मान लें कि sandwich.h में bread.h और bread.h में flour.h शामिल है. sandwich.h में flour.h (कौन अपने सैंडविच में आटा चाहिए?) शामिल नहीं होता, इसलिए BUILD फ़ाइल इस तरह दिखेगी:

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

यहां, sandwich लाइब्रेरी, bread लाइब्रेरी पर निर्भर करती है, जो flour लाइब्रेरी पर निर्भर करती है.

शामिल किए गए पाथ जोड़ना

कभी-कभी आप फ़ाइल फ़ोल्डर के रूट में पाथ शामिल नहीं कर सकते (या ऐसा नहीं करना चाहते). मौजूदा लाइब्रेरी में पहले से ही एक इन्क्लूड डायरेक्ट्री मौजूद हो सकती है, जो आपके फ़ाइल फ़ोल्डर के पाथ से मेल नहीं खाती. उदाहरण के लिए, मान लें कि आपके पास नीचे दी गई डायरेक्ट्री का स्ट्रक्चर है:

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Basel को some_lib.h को legacy/some_lib/include/some_lib.h के तौर पर शामिल करने की उम्मीद होगी, लेकिन माना जाएगा कि some_lib.cc को "some_lib.h" में शामिल किया जाएगा. पाथ को शामिल करने की उसे मान्य बनाने के लिए, legacy/some_lib/BUILD को यह बताना होगा कि some_lib/include डायरेक्ट्री एक इन्क्लूड डायरेक्ट्री है:

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

ऐसा करना खास तौर पर बाहरी डिपेंडेंसी के लिए मददगार होता है, क्योंकि उनकी हेडर फ़ाइलों को / प्रीफ़िक्स के साथ शामिल करना ज़रूरी है.

इसमें बाहरी लाइब्रेरी शामिल हैं

मान लीजिए कि Google Test का इस्तेमाल किया जा रहा है. Google Test को डाउनलोड करने और उसे अपनी रिपॉज़िटरी में उपलब्ध कराने के लिए, WORKSPACE फ़ाइल में मौजूद डेटा स्टोर करने की जगह के किसी एक फ़ंक्शन का इस्तेमाल किया जा सकता है:

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

इसके बाद, gtest.BUILD बनाएं. यह एक BUILD फ़ाइल होती है, जिसका इस्तेमाल Google जांच को कंपाइल करने के लिए किया जाता है. Google Test की कई "खास" शर्तें हैं, जो इसके cc_library नियम को ज़्यादा पेचीदा बनाती हैं:

  • googletest-release-1.10.0/src/gtest-all.cc googletest-release-1.10.0/src/ में मौजूद दूसरी सभी फ़ाइलें #include: डुप्लीकेट सिंबल के लिए लिंक की गड़बड़ियां रोकने के लिए, इसे कंपाइल न करें.

  • इसमें उन हेडर फ़ाइलों का इस्तेमाल किया जाता है जो googletest-release-1.10.0/include/ डायरेक्ट्री ("gtest/gtest.h") से जुड़ी होती हैं. इसलिए, आपको उस डायरेक्ट्री को शामिल पाथ में जोड़ना होगा.

  • इसे pthread में लिंक करना होगा. इसलिए, इसे linkopt के तौर पर जोड़ें.

इसलिए, आखिरी नियम कुछ ऐसा दिखेगा:

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/src/*.cc"],
        exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/include/**/*.h",
        "googletest-release-1.10.0/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/include",
        "-Iexternal/gtest/googletest-release-1.10.0"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

यह कुछ हद तक मुश्किल है: संग्रह के स्ट्रक्चर के प्रॉडक्ट के तौर पर, हर चीज़ की शुरुआत googletest-release-1.10.0 से की गई है. strip_prefix एट्रिब्यूट जोड़कर, इस प्रीफ़िक्स को http_archive बार बनाया जा सकता है:

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

फिर gtest.BUILD ऐसा दिखेगा:

cc_library(
    name = "main",
    srcs = glob(
        ["src/*.cc"],
        exclude = ["src/gtest-all.cc"]
    ),
    hdrs = glob([
        "include/**/*.h",
        "src/*.h"
    ]),
    copts = ["-Iexternal/gtest/include"],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

अब cc_ नियम @gtest//:main पर निर्भर हो सकते हैं.

C++ टेस्ट लिखना और चलाना

उदाहरण के लिए, आपके पास जांच के लिए ./test/hello-test.cc बनाने का विकल्प है, जैसे:

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

इसके बाद, जांच करने के लिए ./test/BUILD फ़ाइल बनाएं:

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = ["-Iexternal/gtest/include"],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

hello-greet, hello-test लोगों को दिखे, इसके लिए आपको ./main/BUILD के visibility एट्रिब्यूट में "//test:__pkg__", जोड़ना होगा.

अब जांच करने के लिए, bazel test का इस्तेमाल किया जा सकता है.

bazel test test:hello-test

इससे यह आउटपुट मिलता है:

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

पहले से कंपाइल की गई लाइब्रेरी पर डिपेंडेंसी जोड़ना

अगर आपको किसी ऐसी लाइब्रेरी का इस्तेमाल करना है जिसका सिर्फ़ कंपाइल किया गया वर्शन (उदाहरण के लिए, हेडर और .so फ़ाइल) आपके पास है, तो उसे cc_library नियम में रैप करें:

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

इस तरह, आपके फ़ाइल फ़ोल्डर में दूसरे C++ टारगेट इस नियम पर निर्भर हो सकते हैं.