常见 C++ build 使用场景

下面介绍了使用 Bazel 构建 C++ 项目的一些最常见的用例。如果您尚未完成，请先完成 Bazel 简介：构建 C++ 项目教程，开始使用 Bazel 构建 C++ 项目。

如需了解 cc_library 和 hdrs 头文件，请参阅 cc_library。

在目标中添加多个文件

您可以使用 glob 在单个目标中包含多个文件。例如：

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

使用此目标，Bazel 将构建它在包含此目标的 BUILD 文件（子目录除外）所在的同一目录中找到的所有 .cc 和 .h 文件。

使用传递包含

如果某个文件包含头文件，则任何以该文件为源的规则（即，将该文件包含在 srcs、hdrs 或 textual_hdrs 属性中）都应依赖于所包含头文件的库规则。相反，只有直接依赖项才需要指定为依赖项。例如，假设 sandwich.h 包含 bread.h，bread.h 包含 flour.h。sandwich.h 不包含 flour.h（谁会想在三明治里加面粉？），因此 BUILD 文件将如下所示：

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

在这里，sandwich 库依赖于 bread 库，而 bread 库依赖于 flour 库。

添加包含路径

有时，您无法（或不想）在工作区根目录中设置包含路径的根目录。现有库可能已经有一个包含目录，该目录与工作区中的路径不匹配。例如，假设您具有以下目录结构：

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel 会预期 some_lib.h 作为 legacy/some_lib/include/some_lib.h 包含在内，但假设 some_lib.cc 包含 "some_lib.h"。要使该包含路径有效，legacy/some_lib/BUILD 需要将 some_lib/include 目录指定为 include 目录：

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

这对于外部依赖项尤其有用，因为否则必须在其头文件中添加 / 前缀。

包括外部库

假设您使用的是 Google Test。您可以使用 WORKSPACE 文件中的某个代码库函数下载 Google Test，并使其在您的代码库中可用：

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

然后创建 gtest.BUILD，这是一个用于编译 Google Test 的 BUILD 文件。Google Test 有几个“特殊”要求，这使得其 cc_library 规则更加复杂：

googletest-release-1.10.0/src/gtest-all.cc #include googletest-release-1.10.0/src/ 中的所有其他文件：将其从编译中排除，以防止重复符号出现链接错误。
它使用相对于 googletest-release-1.10.0/include/ 目录 ("gtest/gtest.h") 的头文件，因此您必须将该目录添加到 include 路径中。
它需要在 pthread 中关联，因此请将其添加为 linkopt。

因此，最终规则应如下所示：

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/src/*.cc"],
        exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/include/**/*.h",
        "googletest-release-1.10.0/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/include",
        "-Iexternal/gtest/googletest-release-1.10.0"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

这有点混乱：所有内容都以 googletest-release-1.10.0 为前缀，这是归档结构的副产物。您可以通过添加 strip_prefix 属性来让 http_archive 移除此前缀：

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

那么 gtest.BUILD 将如下所示：

cc_library(
    name = "main",
    srcs = glob(
        ["src/*.cc"],
        exclude = ["src/gtest-all.cc"]
    ),
    hdrs = glob([
        "include/**/*.h",
        "src/*.h"
    ]),
    copts = ["-Iexternal/gtest/include"],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

现在，cc_ 规则可以依赖于 @gtest//:main。

编写和运行 C++ 测试

例如，您可以创建测试 ./test/hello-test.cc，例如：

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

然后，为您的测试创建 ./test/BUILD 文件：

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = ["-Iexternal/gtest/include"],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

若要让 hello-greet 对 hello-test 可见，您必须将 "//test:__pkg__", 添加到 ./main/BUILD 中的 visibility 属性。

现在，您可以使用 bazel test 运行测试了。

bazel test test:hello-test

这会生成以下输出：

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

添加对预编译库的依赖项

如果您要使用的库只有一个编译版本（例如，头文件和 .so 文件），请将其封装在 cc_library 规则中：

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

这样，工作区中的其他 C++ 目标就可以依赖于此规则。