Bazel 튜토리얼: C++ 도구 모음 구성

문제 신고 소스 보기 1박 · 7.2 · 7.1 · 7.0 · 6.5 · 6.4

이 가이드에서는 예시 시나리오를 사용하여 C++를 구성하는 방법을 설명합니다. 도구 모음을 제공합니다 이 것은 C++ 프로젝트 예시 clang를 사용하여 오류 없이 빌드합니다.

학습할 내용

이 튜토리얼에서는 다음 방법을 알아봅니다.

  • 빌드 환경 설정
  • C++ 도구 모음 구성
  • 추가 항목을 제공하는 Starlark 규칙 만들기 Bazel이 애플리케이션을 빌드할 수 있도록 cc_toolchain 구성 clang
  • 다음을 실행하여 예상 결과 확인 Linux 시스템의 bazel build --config=clang_config //main:hello-world
  • C++ 애플리케이션 빌드

시작하기 전에

빌드 환경 설정

이 튜토리얼에서는 Linux를 사용 중이며 빌드를 성공적으로 마쳤다고 가정합니다. C++ 애플리케이션을 빌드하고 적절한 도구와 라이브러리를 설치했습니다. 이 가이드에서는 시스템에 설치할 수 있는 clang version 9.0.1를 사용합니다.

빌드 환경을 다음과 같이 설정합니다.

  1. 아직 조치를 취하지 않으셨다면 Bazel 0.23 이상을 다운로드하고 설치합니다.

  2. 지금 바로 C++ 프로젝트 예시 를 선택하고 로컬 머신의 빈 디렉터리에 저장합니다.

  3. main/BUILD 파일에 다음 cc_binary 대상을 추가합니다.

    cc_binary(
    name = "hello-world",
    srcs = ["hello-world.cc"],
)

  4. 다음 명령어로 작업공간 디렉터리의 루트에 .bazelrc 파일을 만듭니다. --config 플래그를 사용할 수 있도록 다음 콘텐츠를 추가합니다.

    # Use our custom-configured c++ toolchain.

build:clang_config --crosstool_top=//toolchain:clang_suite

# Use --cpu as a differentiator.

build:clang_config --cpu=k8

# Use the default Bazel C++ toolchain to build the tools used during the
# build.

build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

build:{config_name} --flag=value 항목의 경우 명령줄 플래그 --config={config_name}는 이 특정 플래그와 연결됩니다. 자세한 내용은 다음 문서를 참조하세요. crosstool_top님, cpu 및 host_crosstool_top:

타겟을 빌드할 때는 bazel build --config=clang_config //main:hello-world를 사용하면 Bazel이 커스텀 도구 모음을 cc_toolchain_suite //toolchain:clang_suite 스위트룸에는 도구 모음입니다. 그래서 --cpu=k8 플래그로 구분됩니다.

Bazel은 빌드 중에 C++로 작성된 많은 내부 도구를 사용하기 때문입니다. 프로세스 래퍼를 사용하여 기존 기본 C++ 툴체인이 이러한 도구는 해당 툴체인을 사용하는 대신 해당 툴체인을 사용하여 빌드됩니다. 이 튜토리얼에서 만든 인스턴스입니다

C++ 도구 모음 구성

C++ 도구 모음을 구성하려면 먼저 애플리케이션을 반복적으로 빌드하고 하나씩 살펴보겠습니다.

  1. 다음 명령어를 사용하여 빌드를 실행합니다.

    bazel build --config=clang_config //main:hello-world

    --crosstool_top=//toolchain:clang_suite .bazelrc 파일이 없으면 Bazel에서 다음 오류가 발생합니다.

    No such package `toolchain`: BUILD file not found on package path.

    작업공간 디렉터리에서 패키지의 toolchain 디렉터리를 만듭니다. toolchain 디렉터리 내에 빈 BUILD 파일이 있어야 합니다.

  2. 빌드를 다시 실행합니다. toolchain 패키지는 아직 clang_suite 타겟이면 Bazel에서 다음 오류가 발생합니다.

    No such target '//toolchain:clang_suite': target 'clang_suite' not declared
in package 'toolchain' defined by .../toolchain/BUILD

    toolchain/BUILD 파일에서 다음과 같이 빈 파일 그룹을 정의합니다.

    package(default_visibility = ["//visibility:public"])

filegroup(name = "clang_suite")

  3. 빌드를 다시 실행합니다. Bazel에서 다음 오류가 발생합니다.

    '//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'

    Bazel은 --crosstool_top 플래그가 필요한 ToolchainInfo를 제공하지 않음 제공업체 따라서 --crosstool_top가 ToolchainInfo: cc_toolchain_suite 규칙입니다. toolchain/BUILD 파일에서 빈 파일 그룹을 다음으로 바꿉니다.

    cc_toolchain_suite(
    name = "clang_suite",
    toolchains = {
        "k8": ":k8_toolchain",
    },
)

    toolchains 속성은 자동으로 --cpu를 매핑합니다 (또한 지정된 경우 --compiler) 값을 cc_toolchain로 변환합니다. 아직 cc_toolchain 대상을 정의했다면 Bazel은 이에 대해 불평합니다. 감사합니다.

  4. 빌드를 다시 실행합니다. Bazel에서 다음 오류가 발생합니다.

    Rule '//toolchain:k8_toolchain' does not exist

    이제 cc_toolchain cc_toolchain_suite.toolchains 속성 다음을 추가합니다. toolchain/BUILD 파일:

    filegroup(name = "empty")

cc_toolchain(
    name = "k8_toolchain",
    toolchain_identifier = "k8-toolchain",
    toolchain_config = ":k8_toolchain_config",
    all_files = ":empty",
    compiler_files = ":empty",
    dwp_files = ":empty",
    linker_files = ":empty",
    objcopy_files = ":empty",
    strip_files = ":empty",
    supports_param_files = 0,
)

  5. 빌드를 다시 실행합니다. Bazel에서 다음 오류가 발생합니다.

    Rule '//toolchain:k8_toolchain_config' does not exist

    다음으로 ':k8_Tools_config'를 추가합니다. toolchain/BUILD 파일에 타겟팅합니다.

    filegroup(name = "k8_toolchain_config")

  6. 빌드를 다시 실행합니다. Bazel에서 다음 오류가 발생합니다.

    '//toolchain:k8_toolchain_config' does not have mandatory providers:
'CcToolchainConfigInfo'

    CcToolchainConfigInfo는 구성하는 데 사용하는 제공업체입니다. 이해하는 데 도움이 되었습니다. 이 오류를 수정하려면 Starlark 규칙을 만드세요. 를 생성하여 Bazel에 CcToolchainConfigInfo를 제공하는 toolchain/cc_toolchain_config.bzl 파일을 포함합니다.

    def _impl(ctx):
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "k8-toolchain",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
    )

cc_toolchain_config = rule(
    implementation = _impl,
    attrs = {},
    provides = [CcToolchainConfigInfo],
)

    cc_common.create_cc_toolchain_config_info()는 필요한 제공자 생성 CcToolchainConfigInfo입니다. cc_toolchain_config 규칙을 사용하려면 로드를 추가하세요. 문을 toolchains/BUILD에 추가합니다.

    load(":cc_toolchain_config.bzl", "cc_toolchain_config")

    그런 다음 'k8_tooltip_config'를 바꿉니다. 파일 그룹에 규칙 cc_toolchain_config개:

    cc_toolchain_config(name = "k8_toolchain_config")

  7. 빌드를 다시 실행합니다. Bazel에서 다음 오류가 발생합니다.

    .../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1)
src/main/tools/linux-sandbox-pid1.cc:421:
"execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory
Target //:hello-world failed to build`

    이 시점에서 Bazel은 코드 빌드를 시도하기에 충분한 정보를 가지고 있지만 필요한 빌드를 완료하는 데 어떤 도구를 사용해야 하는지 아직 모릅니다. 있습니다. Starlark 규칙 구현을 수정하여 Bazel에게 무엇을 알리겠습니다. 사용할 수 있습니다. 이를 위해서는 @bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl:

    # toolchain/cc_toolchain_config.bzl:
# NEW
load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path")

def _impl(ctx):
    tool_paths = [ # NEW
        tool_path(
            name = "gcc",
            path = "/usr/bin/clang",
        ),
        tool_path(
            name = "ld",
            path = "/usr/bin/ld",
        ),
        tool_path(
            name = "ar",
            path = "/usr/bin/ar",
        ),
        tool_path(
            name = "cpp",
            path = "/bin/false",
        ),
        tool_path(
            name = "gcov",
            path = "/bin/false",
        ),
        tool_path(
            name = "nm",
            path = "/bin/false",
        ),
        tool_path(
            name = "objdump",
            path = "/bin/false",
        ),
        tool_path(
            name = "strip",
            path = "/bin/false",
        ),
    ]
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "local",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
        tool_paths = tool_paths, # NEW
    )

    /usr/bin/clang 및 /usr/bin/ld가 올바른 경로인지 확인합니다. 지정할 수 있습니다

  8. 빌드를 다시 실행합니다. Bazel에서 다음 오류가 발생합니다.

     ..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world':
 this rule is missing dependency declarations for the following files included by 'main/hello-world.cc':
 '/usr/include/c++/9/ctime'
 '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h'
 '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h'
 ....

    Bazel은 포함된 헤더를 검색할 위치를 알아야 합니다. 현재 includes 속성을 사용하여 이 문제를 해결하는 여러 가지 방법 cc_binary이지만 여기서는 도구 모음 수준에서 cxx_builtin_include_directories cc_common.create_cc_toolchain_config_info의 매개변수입니다. 주의할 점은 다른 버전의 clang를 사용하는 경우 포함 경로는 다릅니다. 이러한 경로는 분포에 따라 다를 수도 있습니다.

    toolchain/cc_toolchain_config.bzl의 반환 값을 수정하여 :

     return cc_common.create_cc_toolchain_config_info(
      ctx = ctx,
      cxx_builtin_include_directories = [ # NEW
        "/usr/lib/llvm-9/lib/clang/9.0.1/include",
        "/usr/include",
      ],
      toolchain_identifier = "local",
      host_system_name = "local",
      target_system_name = "local",
      target_cpu = "k8",
      target_libc = "unknown",
      compiler = "clang",
      abi_version = "unknown",
      abi_libc_version = "unknown",
      tool_paths = tool_paths,
 )

  9. 빌드 명령어를 다시 실행하면 다음과 같은 오류가 표시됩니다.

    /usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()':
hello-world.cc:(.text+0x68): undefined reference to `std::cout'

    링커에 C++ 표준이 누락되었기 때문입니다. 기호를 찾을 수 없습니다. 이 문제를 해결하는 방법에는 여러 가지가 있지만 (예: cc_binary의 linkopts 속성 사용) 여기서는 툴체인을 사용하는 모든 대상이 이 플래그입니다.

    다음 코드를 cc_toolchain_config.bzl에 복사합니다.

      # NEW
  load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES")
  # NEW
  load(
      "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl",
      "feature",
      "flag_group",
      "flag_set",
      "tool_path",
  )

  all_link_actions = [ # NEW
      ACTION_NAMES.cpp_link_executable,
      ACTION_NAMES.cpp_link_dynamic_library,
      ACTION_NAMES.cpp_link_nodeps_dynamic_library,
  ]

  def _impl(ctx):
      tool_paths = [
          tool_path(
              name = "gcc",
              path = "/usr/bin/clang",
          ),
          tool_path(
              name = "ld",
              path = "/usr/bin/ld",
          ),
          tool_path(
              name = "ar",
              path = "/bin/false",
          ),
          tool_path(
              name = "cpp",
              path = "/bin/false",
          ),
          tool_path(
              name = "gcov",
              path = "/bin/false",
          ),
          tool_path(
              name = "nm",
              path = "/bin/false",
          ),
          tool_path(
              name = "objdump",
              path = "/bin/false",
          ),
          tool_path(
              name = "strip",
              path = "/bin/false",
          ),
      ]

      features = [ # NEW
          feature(
              name = "default_linker_flags",
              enabled = True,
              flag_sets = [
                  flag_set(
                      actions = all_link_actions,
                      flag_groups = ([
                          flag_group(
                              flags = [
                                  "-lstdc++",
                              ],
                          ),
                      ]),
                  ),
              ],
          ),
      ]

      return cc_common.create_cc_toolchain_config_info(
          ctx = ctx,
          features = features, # NEW
          cxx_builtin_include_directories = [
              "/usr/lib/llvm-9/lib/clang/9.0.1/include",
              "/usr/include",
          ],
          toolchain_identifier = "local",
          host_system_name = "local",
          target_system_name = "local",
          target_cpu = "k8",
          target_libc = "unknown",
          compiler = "clang",
          abi_version = "unknown",
          abi_libc_version = "unknown",
          tool_paths = tool_paths,
      )

  cc_toolchain_config = rule(
      implementation = _impl,
      attrs = {},
      provides = [CcToolchainConfigInfo],
  )

  10. bazel build --config=clang_config //main:hello-world를 실행하면 있습니다.

작업 검토

이 튜토리얼에서는 기본 C++ 도구 모음을 구성하는 방법을 배웠지만 도구 모음이 이 간단한 예시보다 더 강력합니다.

핵심 내용은 다음과 같습니다. - 명령줄에서 --crosstool_top 플래그를 지정해야 합니다. cc_toolchain_suite을 가리킵니다. - .bazelrc를 사용하여 특정 구성의 바로가기를 만들 수 있습니다. 파일 - cc_툴체인 모음은 서로 다른 CPU에 대해 cc_toolchains를 나열하고 컴파일러입니다. --cpu와 같은 명령줄 플래그를 사용하여 구별할 수 있습니다. - 도구의 위치를 도구 모음에 알려야 합니다. 이 튜토리얼의 내용 시스템에서 도구에 액세스하는 단순화된 버전이 있습니다. 만약 독립 실행형 접근방식에 관심이 있다면 작업공간은 여기를 참조하세요. 도구는 다양한 소스에서 그들의 파일을 사용할 수 있도록 해야 할 수도 있습니다. 다음과 같은 속성의 타겟 종속 항목이 있는 cc_toolchain compiler_files입니다. tool_paths도 변경해야 합니다. - 특성을 생성하여 어떤 플래그를 연결 또는 다른 유형의 액션일 수 있습니다.

추가 자료

자세한 내용은 C++ 도구 모음 구성