이 가이드에서는 예시 시나리오를 사용하여 프로젝트의 C++ 도구 모음을 구성하는 방법을 설명합니다. 이 앱은 clang을 사용하여 오류 없이 빌드하는 C++ 프로젝트 예시를 기반으로 합니다.
학습할 내용
이 튜토리얼에서는 다음 방법을 알아봅니다.
- 빌드 환경 설정
- C++ 도구 모음 구성
- Bazel이
clang로 애플리케이션을 빌드할 수 있도록cc_toolchain에 추가 구성을 제공하는 Starlark 규칙 만들기 - Linux 머신에서
bazel build --config=clang_config //main:hello-world를 실행하여 예상 결과를 확인합니다. - C++ 애플리케이션 빌드
시작하기 전에
빌드 환경 설정
이 튜토리얼에서는 사용자가 Linux를 사용하고 있으며 C++ 애플리케이션을 빌드하고 적절한 도구 및 라이브러리를 설치했다고 가정합니다.
이 가이드에서는 시스템에 설치할 수 있는 clang version 9.0.1를 사용합니다.
다음과 같이 빌드 환경을 설정합니다.
아직 수행하지 않았다면 Bazel 0.23 이상을 다운로드하여 설치합니다.
GitHub에서 예시 C++ 프로젝트를 다운로드하여 로컬 머신의 빈 디렉터리에 배치합니다.
main/BUILD파일에 다음cc_binary타겟을 추가합니다.cc_binary( name = "hello-world", srcs = ["hello-world.cc"], )--config플래그 사용을 사용 설정하려면 워크스페이스 디렉터리의 루트에 다음 콘텐츠가 포함된.bazelrc파일을 만듭니다.# Use our custom-configured c++ toolchain. build:clang_config --crosstool_top=//toolchain:clang_suite # Use --cpu as a differentiator. build:clang_config --cpu=k8 # Use the default Bazel C++ toolchain to build the tools used during the # build. build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain
항목 build:{config_name} --flag=value의 경우 명령줄 플래그 --config={config_name}가 해당 플래그와 연결됩니다. 사용된 플래그(crosstool_top, cpu, host_crosstool_top)에 관한 문서를 참고하세요.
bazel build --config=clang_config //main:hello-world로 타겟을 빌드하면 Bazel은 cc_toolchain_suite//toolchain:clang_suite의 맞춤 도구 모음을 사용합니다. 이 도구 모음은 CPU에 따라 다른 도구 모음을 나열할 수 있으므로 --cpu=k8 플래그와 다릅니다.
Bazel은 빌드 중에 process-wrapper와 같이 C++로 작성된 많은 내부 도구를 사용하므로 이러한 도구가 이 튜토리얼에서 만든 도구 대신 해당 도구 모음을 사용하여 빌드되도록 호스트 플랫폼에 기존 기본 C++ 도구 모음이 지정됩니다.
C++ 도구 모음 구성
C++ 도구 모음을 구성하려면 아래에 설명된 대로 애플리케이션을 반복적으로 빌드하고 각 오류를 하나씩 제거합니다.
다음 명령어를 사용하여 빌드를 실행합니다.
bazel build --config=clang_config //main:hello-world.bazelrc파일에서--crosstool_top=//toolchain:clang_suite를 지정했으므로 Bazel에서 다음과 같은 오류가 발생합니다.No such package `toolchain`: BUILD file not found on package path.작업공간 디렉터리에서 패키지의
toolchain디렉터리와toolchain디렉터리 내에 빈BUILD파일을 만듭니다.빌드를 다시 실행합니다.
toolchain패키지에서 아직clang_suite타겟을 정의하지 않았으므로 Bazel에서 다음 오류가 발생합니다.No such target '//toolchain:clang_suite': target 'clang_suite' not declared in package 'toolchain' defined by .../toolchain/BUILDtoolchain/BUILD파일에서 다음과 같이 빈 파일 그룹을 정의합니다.package(default_visibility = ["//visibility:public"]) filegroup(name = "clang_suite")빌드를 다시 실행합니다. Bazel에서 다음 오류가 발생합니다.
'//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'Bazel은
--crosstool_top플래그가 필요한ToolchainInfo제공자를 제공하지 않는 규칙을 가리키고 있음을 발견했습니다. 따라서--crosstool_top를ToolchainInfo를 제공하는 규칙, 즉cc_toolchain_suite규칙으로 가리켜야 합니다.toolchain/BUILD파일에서 빈 파일 그룹을 다음으로 바꿉니다.cc_toolchain_suite( name = "clang_suite", toolchains = { "k8": ":k8_toolchain", }, )toolchains속성은--cpu값(지정된 경우--compiler값도 포함)을cc_toolchain에 자동으로 매핑합니다. 아직cc_toolchain타겟을 정의하지 않았으며 Bazel에서 곧 이에 대해 불만을 제기할 것입니다.빌드를 다시 실행합니다. Bazel에서 다음 오류가 발생합니다.
Rule '//toolchain:k8_toolchain' does not exist이제
cc_toolchain_suite.toolchains속성의 모든 값에 대해cc_toolchain타겟을 정의해야 합니다.toolchain/BUILD파일에 다음을 추가합니다.filegroup(name = "empty") cc_toolchain( name = "k8_toolchain", toolchain_identifier = "k8-toolchain", toolchain_config = ":k8_toolchain_config", all_files = ":empty", compiler_files = ":empty", dwp_files = ":empty", linker_files = ":empty", objcopy_files = ":empty", strip_files = ":empty", supports_param_files = 0, )빌드를 다시 실행합니다. Bazel에서 다음 오류가 발생합니다.
Rule '//toolchain:k8_toolchain_config' does not exist다음으로
toolchain/BUILD파일에 ':k8_toolchain_config' 타겟을 추가합니다.filegroup(name = "k8_toolchain_config")빌드를 다시 실행합니다. Bazel에서 다음 오류가 발생합니다.
'//toolchain:k8_toolchain_config' does not have mandatory providers: 'CcToolchainConfigInfo'CcToolchainConfigInfo는 C++ 도구 모음을 구성하는 데 사용하는 제공자입니다. 이 오류를 수정하려면 다음 콘텐츠로toolchain/cc_toolchain_config.bzl파일을 만들어 Bazel에CcToolchainConfigInfo를 제공하는 Starlark 규칙을 만듭니다.def _impl(ctx): return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "k8-toolchain", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )cc_common.create_cc_toolchain_config_info()는 필요한 제공자CcToolchainConfigInfo를 만듭니다.cc_toolchain_config규칙을 사용하려면toolchains/BUILD에 로드 문을 추가합니다.load(":cc_toolchain_config.bzl", "cc_toolchain_config")'k8_toolchain_config' 파일 그룹을
cc_toolchain_config규칙 선언으로 바꿉니다.cc_toolchain_config(name = "k8_toolchain_config")빌드를 다시 실행합니다. Bazel에서 다음 오류가 발생합니다.
.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1) src/main/tools/linux-sandbox-pid1.cc:421: "execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory Target //:hello-world failed to build`이 시점에서 Bazel은 코드 빌드를 시도할 수 있는 충분한 정보를 가지고 있지만, 필요한 빌드 작업을 완료하기 위해 어떤 도구를 사용해야 하는지 모릅니다. 사용할 도구를 Bazel에 알리도록 Starlark 규칙 구현을 수정합니다. 이를 위해
@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl의 tool_path() 생성자가 필요합니다.# toolchain/cc_toolchain_config.bzl: # NEW load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path") def _impl(ctx): tool_paths = [ # NEW tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/usr/bin/ar", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, # NEW )/usr/bin/clang및/usr/bin/ld가 시스템의 올바른 경로인지 확인합니다.빌드를 다시 실행합니다. Bazel에서 다음 오류가 발생합니다.
..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world': this rule is missing dependency declarations for the following files included by 'main/hello-world.cc': '/usr/include/c++/9/ctime' '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h' '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h' ....Bazel은 포함된 헤더를 검색할 위치를 알아야 합니다.
cc_binary의includes속성을 사용하는 등 여러 방법으로 이 문제를 해결할 수 있지만 여기서는cc_common.create_cc_toolchain_config_info의cxx_builtin_include_directories매개변수를 사용하여 도구 모음 수준에서 해결됩니다. 다른 버전의clang를 사용하면 포함 경로가 달라진다는 점에 유의하세요. 이러한 경로는 배포에 따라 다를 수도 있습니다.toolchain/cc_toolchain_config.bzl의 반환 값을 다음과 같이 수정합니다.return cc_common.create_cc_toolchain_config_info( ctx = ctx, cxx_builtin_include_directories = [ # NEW "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, )빌드 명령어를 다시 실행하면 다음과 같은 오류가 표시됩니다.
/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()': hello-world.cc:(.text+0x68): undefined reference to `std::cout'그 이유는 링커에 C++ 표준 라이브러리가 누락되어 기호를 찾을 수 없기 때문입니다.
cc_binary의linkopts속성을 사용하는 등 이를 해결하는 방법에는 여러 가지가 있습니다. 여기서는 도구 모음을 사용하는 모든 타겟이 이 플래그를 지정할 필요가 없도록 하여 문제를 해결합니다.다음 코드를
cc_toolchain_config.bzl에 복사합니다.# NEW load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES") # NEW load( "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "feature", "flag_group", "flag_set", "tool_path", ) all_link_actions = [ # NEW ACTION_NAMES.cpp_link_executable, ACTION_NAMES.cpp_link_dynamic_library, ACTION_NAMES.cpp_link_nodeps_dynamic_library, ] def _impl(ctx): tool_paths = [ tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/bin/false", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] features = [ # NEW feature( name = "default_linker_flags", enabled = True, flag_sets = [ flag_set( actions = all_link_actions, flag_groups = ([ flag_group( flags = [ "-lstdc++", ], ), ]), ), ], ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, features = features, # NEW cxx_builtin_include_directories = [ "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )bazel build --config=clang_config //main:hello-world를 실행하면 최종적으로 빌드됩니다.
과제 검토
이 튜토리얼에서는 기본 C++ 도구 모음을 구성하는 방법을 알아봤지만 도구 모음은 이 간단한 예시보다 더 강력합니다.
핵심 사항은 다음과 같습니다.
- 명령줄에서 cc_toolchain_suite를 가리켜야 하는 --crosstool_top 플래그를 지정해야 합니다.
- .bazelrc 파일을 사용하여 특정 구성의 바로가기를 만들 수 있습니다.
- cc_Tools_suite는 다양한 CPU와 컴파일러의 cc_toolchains를 나열할 수 있습니다. --cpu와 같은 명령줄 플래그를 사용하여 구분할 수 있습니다.
- 도구의 위치를 도구 모음에 알려야 합니다. 이 가이드에는 시스템에서 도구에 액세스하는 간소화된 버전이 있습니다. 보다 독립된 접근 방식에 관심이 있다면 여기에서 작업공간에 대해 읽어보세요. 도구가 다른 작업공간에서 제공될 수 있으며, compiler_files과 같은 속성의 타겟 종속 항목과 함께 파일을 cc_toolchain에서 사용할 수 있도록 해야 합니다. tool_paths도 변경해야 합니다.
- 연결이든 다른 유형의 작업이든 다양한 작업에 전달해야 하는 플래그를 맞춤설정하는 기능을 만들 수 있습니다.
추가 자료
자세한 내용은 C++ 도구 모음 구성을 참고하세요.