Bazel チュートリアル: Java プロジェクトをビルドする

このチュートリアルでは、Bazel を使用して Java アプリケーションをビルドする基本について説明します。ワークスペースを設定し、ターゲットや BUILD ファイルなど、Bazel の主なコンセプトを示すシンプルな Java プロジェクトを構築します。

所要時間: 30 分

学習内容

このチュートリアルでは、次の方法について学びます。

• ターゲットをビルドする
• プロジェクトの依存関係を可視化する
• プロジェクトを複数のターゲットとパッケージに分割する
• パッケージ全体でターゲットの公開設定を制御する
• ラベルでターゲットを参照する
• ターゲットをデプロイする

始める前に

Bazel をインストールする

チュートリアルの準備として、まだインストールしていない場合はまず Bazel をインストールします。

JDK をインストールする

1. Java JDK をインストールします（推奨バージョンは 11 ですが、バージョン 8 ～ 15 がサポートされています）。

2. JDK を指すように JAVA_HOME 環境変数を設定します。

   • Linux / macOS の場合:

     export JAVA_HOME="$(dirname $(dirname $(realpath $(which javac))))"
     

   • Windows の場合:

     1. コントロール パネルを開きます。
     2. [システムとセキュリティ] > [システム] > [システムの詳細設定] > [詳細設定] タブ > [環境変数...] に移動します。.
     3. [ユーザー変数] リスト（上部にあるリスト）で、[新規...] をクリックします。
     4. [変数名] フィールドに「JAVA_HOME」と入力します。
     5. [Browse Directory...] をクリックします。
     6. JDK ディレクトリ（C:\Program Files\Java\jdk1.8.0_152 など）に移動します。
     7. すべてのダイアログ ウィンドウで [OK] をクリックします。

サンプル プロジェクトを取得する

Bazel の GitHub リポジトリからサンプル プロジェクトを取得します。

git clone https://github.com/bazelbuild/examples

このチュートリアルのサンプル プロジェクトは examples/java-tutorial ディレクトリにあり、次のように構成されています。

java-tutorial
├── BUILD
├── src
│   └── main
│       └── java
│           └── com
│               └── example
│                   ├── cmdline
│                   │   ├── BUILD
│                   │   └── Runner.java
│                   ├── Greeting.java
│                   └── ProjectRunner.java
└── WORKSPACE

Bazel を使用したビルド

ワークスペースを設定する

プロジェクトをビルドする前に、ワークスペースを設定する必要があります。ワークスペースは、プロジェクトのソースファイルと Bazel のビルド出力を保持するディレクトリです。また、Bazel が特殊なファイルとして認識しているファイルも含まれています。

• WORKSPACE ファイル。ディレクトリとその内容を Bazel ワークスペースとして識別し、プロジェクトのディレクトリ構造のルートに存在します。

• 1 つ以上の BUILD ファイル。プロジェクトのさまざまな部分をビルドする方法を Bazel に指示します。（BUILD ファイルを含むワークスペース内のディレクトリはパッケージです。パッケージについては、このチュートリアルの後半で説明します）。

ディレクトリを Bazel ワークスペースとして指定するには、そのディレクトリに WORKSPACE という名前の空のファイルを作成します。

Bazel がプロジェクトをビルドする場合、すべての入力と依存関係が同じワークスペースに存在する必要があります。異なるワークスペースに存在するファイルは、リンクされていない限り互いに独立しています。リンクについては、このチュートリアルの範囲外です。

BUILD ファイルを理解する

BUILD ファイルには、Bazel 用のさまざまなタイプの命令が含まれています。最も重要なタイプはビルドルールです。これは、実行可能バイナリやライブラリなどの目的の出力をビルドする方法を Bazel に指示します。BUILD ファイル内のビルドルールの各インスタンスはターゲットと呼ばれ、ソースファイルと依存関係の特定のセットを参照します。ターゲットは他のターゲットを指すこともできます。

java-tutorial/BUILD ファイルを確認します。

java_binary(
    name = "ProjectRunner",
    srcs = glob(["src/main/java/com/example/*.java"]),
)

この例では、ProjectRunner ターゲットが Bazel の組み込み java_binary ルールをインスタンス化しています。このルールは、.jar ファイルとラッパー シェル スクリプト（どちらもターゲットにちなんで名付けられたもの）をビルドするよう Bazel に指示します。

ターゲットの属性は、依存関係とオプションを明示的に記述します。name 属性は必須ですが、多くは省略可能です。たとえば、ProjectRunner ルール ターゲットでは、name はターゲットの名前、srcs は Bazel がターゲットのビルドに使用するソースファイルを指定し、main_class はメインメソッドを含むクラスを指定します。（この例では、glob を使用して、ソースファイルを 1 つずつ列挙するのではなく、一連のソースファイルを Bazel に渡しています）。

プロジェクトをビルドする

サンプル プロジェクトをビルドするには、java-tutorial ディレクトリに移動して次のコマンドを実行します。

bazel build //:ProjectRunner

ターゲット ラベルの // 部分は、ワークスペースのルート（この場合はルート自体）を基準とした BUILD ファイルの場所であり、ProjectRunner は BUILD ファイル内のターゲット名です。（ターゲット ラベルについては、このチュートリアルの最後に詳しく説明します）。

Bazel は次のような出力を生成します。

   INFO: Found 1 target...
   Target //:ProjectRunner up-to-date:
      bazel-bin/ProjectRunner.jar
      bazel-bin/ProjectRunner
   INFO: Elapsed time: 1.021s, Critical Path: 0.83s

これで、最初の Bazel ターゲットがビルドされました。Bazel は、ビルドの出力をワークスペースのルートの bazel-bin ディレクトリに配置します。内容を参照して、Bazel の出力構造を把握します。

新しくビルドしたバイナリをテストします。

bazel-bin/ProjectRunner

依存関係グラフを確認する

Bazel では、ビルド依存関係を BUILD ファイルで明示的に宣言する必要があります。Bazel では、これらのステートメントを使用してプロジェクトの依存関係グラフが作成され、正確な増分ビルドが可能になります。

サンプル プロジェクトの依存関係を可視化するには、ワークスペースのルートで次のコマンドを実行して、依存関係グラフのテキスト表現を生成します。

bazel query  --notool_deps --noimplicit_deps "deps(//:ProjectRunner)" --output graph

上記のコマンドは、ターゲット //:ProjectRunner のすべての依存関係（ホストと暗黙的な依存関係を除く）を検索し、出力をグラフとしてフォーマットするように Bazel に指示します。

次に、テキストを GraphViz に貼り付けます。

ご覧のとおり、このプロジェクトには、追加の依存関係なしで 2 つのソースファイルをビルドする単一のターゲットがあります。

ワークスペースを設定し、プロジェクトをビルドして依存関係を確認したら、複雑さを追加できます。

Bazel ビルドの改良

小規模なプロジェクトでは 1 つのターゲットで十分ですが、大規模なプロジェクトは複数のターゲットとパッケージに分割して、高速な増分ビルド（変更された部分のみを再ビルド）を可能にし、プロジェクトの複数の部分を一度にビルドしてビルドを高速化することをおすすめします。

複数のビルド ターゲットを指定する

サンプル プロジェクトのビルドは、2 つのターゲットに分割できます。java-tutorial/BUILD ファイルの内容を次のように置き換えます。

java_binary(
    name = "ProjectRunner",
    srcs = ["src/main/java/com/example/ProjectRunner.java"],
    main_class = "com.example.ProjectRunner",
    deps = [":greeter"],
)

java_library(
    name = "greeter",
    srcs = ["src/main/java/com/example/Greeting.java"],
)

この構成では、Bazel はまず greeter ライブラリをビルドし、次に ProjectRunner バイナリをビルドします。java_binary の deps 属性は、ProjectRunner バイナリのビルドに greeter ライブラリが必要であることを Bazel に伝えます。

プロジェクトの新しいバージョンをビルドするには、次のコマンドを実行します。

bazel build //:ProjectRunner

Bazel は次のような出力を生成します。

INFO: Found 1 target...
Target //:ProjectRunner up-to-date:
  bazel-bin/ProjectRunner.jar
  bazel-bin/ProjectRunner
INFO: Elapsed time: 2.454s, Critical Path: 1.58s

新しくビルドされたバイナリをテストします。

bazel-bin/ProjectRunner

ProjectRunner.java を変更してプロジェクトを再ビルドすると、Bazel はそのファイルのみを再コンパイルします。

依存関係グラフを見ると、ProjectRunner は以前と同じ入力に依存していますが、ビルドの構造は異なります。

これで、2 つのターゲットを持つプロジェクトがビルドされました。ProjectRunner ターゲットは 2 つのソースファイルをビルドし、他の 1 つのターゲット（:greeter）に依存します。このターゲットは、追加のソースファイルを 1 つビルドします。

複数のパッケージを使用する

プロジェクトを複数のパッケージに分割しましょう。src/main/java/com/example/cmdline ディレクトリを見ると、BUILD ファイルとソースファイルも含まれていることがわかります。したがって、Bazel では、ワークスペースに //src/main/java/com/example/cmdline と // の 2 つのパッケージが含まれるようになりました（ワークスペースのルートに BUILD ファイルがあるため）。

src/main/java/com/example/cmdline/BUILD ファイルを確認します。

java_binary(
    name = "runner",
    srcs = ["Runner.java"],
    main_class = "com.example.cmdline.Runner",
    deps = ["//:greeter"],
)

runner ターゲットは、// パッケージの greeter ターゲット（ターゲットラベル //:greeter）に依存しています。これは、Bazel が deps 属性を通じて認識します。依存関係グラフを確認します。

ただし、ビルドを成功させるには、visibility 属性を使用して、//src/main/java/com/example/cmdline/BUILD の runner ターゲットを //BUILD のターゲットに公開することを明示的に指定する必要があります。これは、デフォルトではターゲットは同じ BUILD ファイル内の他のターゲットにのみ表示されるためです。（Bazel は、ターゲットの公開設定を使用して、実装の詳細を含むライブラリが公開 API に漏洩するなどの問題を防ぎます）。

これを行うには、以下に示すように visibility 属性を java-tutorial/BUILD の greeter ターゲットに追加します。

java_library(
    name = "greeter",
    srcs = ["src/main/java/com/example/Greeting.java"],
    visibility = ["//src/main/java/com/example/cmdline:__pkg__"],
)

これで、ワークスペースのルートで次のコマンドを実行して新しいパッケージをビルドできます。

bazel build //src/main/java/com/example/cmdline:runner

Bazel は、次のような出力を生成します。

INFO: Found 1 target...
Target //src/main/java/com/example/cmdline:runner up-to-date:
  bazel-bin/src/main/java/com/example/cmdline/runner.jar
  bazel-bin/src/main/java/com/example/cmdline/runner
  INFO: Elapsed time: 1.576s, Critical Path: 0.81s

新しくビルドされたバイナリをテストします。

./bazel-bin/src/main/java/com/example/cmdline/runner

これで、それぞれ 1 つのターゲットを含む 2 つのパッケージとしてビルドするようにプロジェクトを変更し、それらの間の依存関係を把握できました。

ラベルを使用してターゲットを参照する

BUILD ファイルとコマンドラインでは、Bazel はターゲット ラベルを使用してターゲット（//:ProjectRunner や //src/main/java/com/example/cmdline:runner など）を参照します。構文は次のとおりです。

//path/to/package:target-name

ターゲットがルール ターゲットの場合、path/to/package は BUILD ファイルを含むディレクトリのパスです。target-name は、BUILD ファイル（name 属性）でターゲットに付けた名前です。ターゲットがファイル ターゲットの場合、path/to/package はパッケージのルートへのパス、target-name はフルパスを含むターゲット ファイルの名前です。

リポジトリのルートでターゲットを参照する場合、パッケージパスは空になります。//:target-name を使用します。同じ BUILD ファイル内でターゲットを参照する場合は、// ワークスペースのルート識別子をスキップして、:target-name のみを使用することもできます。

たとえば、java-tutorial/BUILD ファイル内のターゲットの場合、ワークスペースのルート自体がパッケージ（//）であり、2 つのターゲットラベルが単純に //:ProjectRunner と //:greeter であるため、パッケージパスを指定する必要はありませんでした。

ただし、//src/main/java/com/example/cmdline/BUILD ファイル内のターゲットの場合は、//src/main/java/com/example/cmdline のフルパッケージパスを指定し、ターゲットラベルは //src/main/java/com/example/cmdline:runner でした。

デプロイ用に Java ターゲットをパッケージ化する

次に、すべてのランタイム依存関係を使用してバイナリをビルドし、デプロイ用に Java ターゲットをパッケージ化しましょう。これにより、バイナリを開発環境の外部で実行できます。

すでに説明したように、java_binary ビルドルールは .jar とラッパー シェル スクリプトを生成します。次のコマンドを使用して、runner.jar の内容を確認します。

jar tf bazel-bin/src/main/java/com/example/cmdline/runner.jar

内容は次のとおりです。

META-INF/
META-INF/MANIFEST.MF
com/
com/example/
com/example/cmdline/
com/example/cmdline/Runner.class

ご覧のように、runner.jar には Runner.class が含まれていますが、依存関係 Greeting.class は含まれていません。Bazel が生成した runner スクリプトは、greeter.jar をクラスパスに追加します。このままにしておくと、ローカルで実行されますが、別のマシンでスタンドアロンで実行されません。幸いなことに、java_binary ルールを使用すると、自己完結型でデプロイ可能なバイナリをビルドできます。ビルドするには、ターゲット名に _deploy.jar を追加します。

bazel build //src/main/java/com/example/cmdline:runner_deploy.jar

Bazel は、次のような出力を生成します。

INFO: Found 1 target...
Target //src/main/java/com/example/cmdline:runner_deploy.jar up-to-date:
  bazel-bin/src/main/java/com/example/cmdline/runner_deploy.jar
INFO: Elapsed time: 1.700s, Critical Path: 0.23s

ビルドした runner_deploy.jar には、必要なランタイム依存関係が含まれているため、開発環境からスタンドアロンで実行できます。前と同じコマンドを使用して、このスタンドアロン JAR の内容を確認します。

jar tf bazel-bin/src/main/java/com/example/cmdline/runner_deploy.jar

内容には、実行に必要なすべてのクラスが含まれています。

META-INF/
META-INF/MANIFEST.MF
build-data.properties
com/
com/example/
com/example/cmdline/
com/example/cmdline/Runner.class
com/example/Greeting.class

関連情報

詳しくは以下をご覧ください。

• rules_jvm_external: 伝播 Maven 依存関係を管理するルール。

• 外部依存関係: ローカル リポジトリとリモート リポジトリの操作の詳細を確認する。

• Bazel の詳細に関するその他のルール。

• C++ ビルド チュートリアル。Bazel で C++ プロジェクトのビルドを始める方法について説明しています。

• Bazel を使用した Android および iOS 向けモバイル アプリケーションのビルドを開始するための、Android アプリケーションのチュートリアルと iOS アプリケーションのチュートリアル。

ご利用をお待ちしております。