總覽
Bazel 需要一些有關編譯器內部的知識,例如包含目錄和重要標記,才能用正確的選項叫用編譯器。換句話說,Bazel 需要簡化的編譯器模型,才能瞭解其工作。
Bazel 必須知道下列資訊:
- 編譯器是否支援 thinLTO、模組、動態連結或 PIC (位置獨立程式碼)。
- 必要工具的路徑,例如 gcc、ld、ar、objcopy 等。
- 內建系統包含目錄。Bazel 需要這些資訊才能驗證來源檔案中包含的所有標頭是否已在
BUILD
檔案中正確宣告。 - 預設的 sysroot。
- 用於編譯、連結和封存的旗標。
- 支援編譯模式 (opt、dbg、Fastbuild) 使用的標記。
- 建立編譯器特別需要的變數。
如果編譯器支援多種架構,Bazel 必須個別設定。
CcToolchainConfigInfo
是可提供設定 Bazel C++ 規則行為的必要精細程度的提供者。根據預設,Bazel 會自動設定建構作業的 CcToolchainConfigInfo
,但您可以選擇手動設定。為此,您需要提供 CcToolchainConfigInfo
的 Starlark 規則,而且您必須將 cc_toolchain
的 toolchain_config
屬性指向規則。您可以呼叫 cc_common.create_cc_toolchain_config_info()
來建立 CcToolchainConfigInfo
。您可以在 @rules_cc//cc:cc_toolchain_config_lib.bzl
中,找到所有必要結構的 Starlark 建構函式。
當 C++ 目標進入分析階段時,Bazel 會根據 BUILD
檔案選取適當的 cc_toolchain
目標,並從 cc_toolchain.toolchain_config
屬性中指定的目標取得 CcToolchainConfigInfo
提供者。cc_toolchain
目標會透過 CcToolchainProvider
將這項資訊傳遞至 C++ 目標。
例如,使用 cc_binary
或 cc_library
等規則例項化的編譯或連結動作需要以下資訊:
- 要使用的編譯器或連結器
- 編譯器/連結器的指令列標記
- 透過
--copt/--linkopt
選項傳遞的設定旗標 - 環境變數
- 執行動作的沙箱中所需的構件
除了沙箱中所需的構件以外,上述所有資訊都會在 cc_toolchain
指向的 Starlark 目標中指定。
要運送至沙箱的構件會在 cc_toolchain
目標中宣告。舉例來說,使用 cc_toolchain.linker_files
屬性時,您可以指定要傳送至沙箱的連結器二進位檔和工具鍊程式庫。
工具鍊選項
工具鍊選取邏輯的運作方式如下:
使用者在
BUILD
檔案中指定cc_toolchain_suite
目標,並使用--crosstool_top
選項將 Bazel 指向目標。cc_toolchain_suite
目標參照多個工具鍊。--cpu
和--compiler
旗標的值可藉由僅根據--cpu
旗標值或彙整--cpu | --compiler
值,決定選取哪些工具鍊。選取程序如下:如果指定了
--compiler
選項,Bazel 會從cc_toolchain_suite.toolchains
屬性中選取--cpu | --compiler
對應的項目。如果 Bazel 找不到對應的項目,就會擲回錯誤。如果未指定
--compiler
選項,Bazel 會從cc_toolchain_suite.toolchains
屬性中選取--cpu
的對應項目。如未指定任何標記,Bazel 會檢查主機系統,並根據發現項目選擇
--cpu
值。請參閱檢查機製程式碼。
選取工具鍊後,Starlark 規則中的對應 feature
和 action_config
物件就會控管建構作業的設定 (也就是稍後說明的項目)。這些訊息允許在 Bazel 中實作完整的 C++ 功能,而不需修改 Bazel 二進位檔。C++ 規則支援多個不重複動作,詳細內容請參閱 Bazel 原始碼。
功能
功能是一種需要指令列標記、動作、執行環境限製或依附元件變更的實體。功能可以很簡單,例如允許 BUILD
檔案選取 treat_warnings_as_errors
等旗標設定,或與 C++ 規則互動,並在編譯中加入新的編譯動作和輸入內容,例如 header_modules
或 thin_lto
。
在理想情況下,CcToolchainConfigInfo
包含功能清單,其中每個功能都含有一或多個標記群組,每個群組都會定義適用於特定 Bazel 動作的標記清單。
功能是以名稱指定,可讓 Starlark 規則設定與 Bazel 版本完全分離。也就是說,Bazel 版本不會影響 CcToolchainConfigInfo
設定的行為,前提是這些設定不需要使用新功能。
功能的啟用方式如下:
- 地圖項目的
enabled
欄位已設為true
。 - Bazel 或規則擁有者明確啟用該規則。
- 使用者可以透過
--feature
Bazel 選項或features
規則屬性啟用 API。
功能可能會有相互依附,具體取決於指令列旗標、BUILD
檔案設定和其他變數。
特徵關係
依附元件通常是由 Bazel 直接管理,而 Bazel 只會強制執行要求,並管理建構作業中定義特徵的本質衝突。工具鍊規格可設定更精細的限制,以便直接用於控管功能支援和擴展的 Starlark 規則。包括:
限制 | 說明 |
requires = [ feature_set (features = [ 'feature-name-1', 'feature-name-2' ]), ] |
特徵層級:只有在指定的必要功能已啟用時,系統才會支援這項功能。舉例來說,如果功能僅支援特定建構模式 (opt 、dbg 或 fastbuild )。如果「requires」包含多個「feature_set」,則只要符合任一「feature_set」屬性,系統就會支援這項功能 (前提是所有指定功能都已啟用)。
|
implies = ['feature'] |
特徵層級:這項功能會隱含指定的地圖項目。 啟用某項功能也會間接啟用其隱含的所有功能 (也就是以遞迴方式運作)。 也能從一組功能中分解常見的功能子集,例如消毒液中的常見部分。隱含的功能無法停用。 |
provides = ['feature'] |
特徵層級:表示這項功能是數個互斥的其他功能之一。舉例來說,所有掃毒程式都能指定 如果使用者一次要求兩項以上的互斥功能,這可以列出替代做法,藉此改善錯誤處理機制。 |
with_features = [ with_feature_set( features = ['feature-1'], not_features = ['feature-2'], ), ] |
旗標設定層級。一個功能可以指定多個標記集。如果指定 with_features ,則只有在至少一個 with_feature_set 已啟用指定 features 組合中的所有功能,且 not_features 集中指定的所有功能都停用時,標記集才會展開為建構指令。如未指定 with_features ,則所有指定的動作都會無條件套用此標記。 |
動作
動作可讓您彈性修改動作執行的條件,而不會假設動作執行的方式。action_config
會指定動作叫用的工具二進位檔,feature
則指定設定 (旗標),決定該工具叫用動作時的行為。
由於動作可能會修改 Bazel 動作圖,因此「功能」會參照動作,指出影響哪些 Bazel 動作。CcToolchainConfigInfo
提供者包含具有旗標和相關聯工具的動作,例如 c++-compile
。系統會將旗標與地圖項目建立關聯
以指派給每個動作
每個動作名稱都代表 Bazel 執行的一種動作,例如編譯或連結。不過,動作和 Bazel 動作類型之間存在多對一關係,其中 Bazel 動作類型是指實作動作的 Java 類別 (例如 CppCompileAction
)。具體而言,下表中的「組合器動作」和「編譯器動作」是 CppCompileAction
,而連結動作則為 CppLinkAction
。
組合動作
動作 | 說明 |
preprocess-assemble
|
組合預先處理。通常用於 .S 檔案。 |
assemble
|
組合而不預先處理。通常用於 .s 檔案。 |
編譯器動作
動作 | 說明 |
cc-flags-make-variable
|
將 CC_FLAGS 傳播至 Genrules。 |
c-compile
|
編譯為 C。 |
c++-compile
|
編譯為 C++。 |
c++-header-parsing
|
在標頭檔案上執行編譯器的剖析器,確保標頭獨立存在,否則會產生編譯錯誤。僅適用於支援模組的工具鍊。 |
連結動作
動作 | 說明 |
c++-link-dynamic-library
|
連結內含所有依附元件的共用資料庫。 |
c++-link-nodeps-dynamic-library
|
連結只包含 cc_library 來源的共用資料庫。
|
c++-link-executable
|
連結可立即執行的最終程式庫。 |
AR 動作
AR 動作會透過 ar
將物件檔案組合成封存程式庫 (.a
檔案),並將部分語意編碼為名稱。
動作 | 說明 |
c++-link-static-library
|
建立靜態資料庫 (封存)。 |
LTO 動作
動作 | 說明 |
lto-backend
|
ThinLTO 動作會將位元碼編譯為原生物件。 |
lto-index
|
產生全域索引的 ThinLTO 動作。 |
使用 action_config
action_config
是 Starlark 結構,用於說明 Bazel 動作,方法是指定在動作期間以及由功能定義的標記組合中叫用的工具 (二進位檔)。這些旗標會將限制套用至動作的執行作業。
action_config()
建構函式包含下列參數:
屬性 | 說明 |
action_name
|
與這個動作對應的 Bazel 動作。 Bazel 會使用這項屬性來探索個別動作工具和執行需求。 |
tools
|
要叫用的執行檔。套用至動作的工具是清單中的第一個工具,具有與功能設定相符的功能集。必須提供預設值。 |
flag_sets
|
適用於一組動作的旗標清單。與地圖項目相同。 |
env_sets
|
適用於一組動作的環境限制清單。與地圖項目相同。 |
action_config
可以需要並暗示其他功能和 action_config
,如同前述的功能關係所決定。這個行為與特徵類似。
後兩個屬性與特徵的對應屬性不同,因此會包含這些屬性,因為部分 Bazel 動作需要特定標記或環境變數,目標是避免不必要的 action_config
+feature
配對。一般而言,建議在多個 action_config
之間共用單一功能。
您無法在相同的工具鍊中使用同一個 action_name
定義多個 action_config
。這可避免工具路徑出現模稜兩可的情況,並強制執行 action_config
背後的意圖,也就是在工具鍊中的單一位置清楚說明動作屬性。
使用工具建構函式
action_config
可以透過 tools
參數指定一組工具。tool()
建構函式會採用下列參數:
欄位 | 說明 |
tool_path
|
相關工具的路徑 (相對於目前位置)。 |
with_features
|
特徵集清單,其中至少要滿足一項特徵,這項工具才能套用。 |
針對指定的 action_config
,只有一個 tool
會將工具路徑和執行要求套用至 Bazel 動作。您需要透過 action_config
上的 tools
屬性疊代選取工具,直到找到與功能設定相符的 with_feature
組合為止 (詳情請參閱本頁前述的特徵關係)。建議您在工具清單結束時,使用對應至空白功能設定的預設工具。
應用實例
您可使用各項功能和動作,以各種跨平台語意實作 Bazel 動作。舉例來說,在 macOS 上產生偵錯符號時,必須在編譯動作中產生符號,然後在連結動作期間叫用特殊化工具來建立壓縮的 dsym 封存,然後解壓縮該封存檔以產生應用程式套件和 Xcode 可使用的 .plist
檔案。
使用 Bazel 時,這個程序可以改按以下方式實作,但 unbundle-debuginfo
可能是 Bazel 動作:
load("@rules_cc//cc:defs.bzl", "ACTION_NAMES")
action_configs = [
action_config (
config_name = ACTION_NAMES.cpp_link_executable,
action_name = ACTION_NAMES.cpp_link_executable,
tools = [
tool(
with_features = [
with_feature(features=["generate-debug-symbols"]),
],
tool_path = "toolchain/mac/ld-with-dsym-packaging",
),
tool (tool_path = "toolchain/mac/ld"),
],
),
]
features = [
feature(
name = "generate-debug-symbols",
flag_sets = [
flag_set (
actions = [
ACTION_NAMES.c_compile,
ACTION_NAMES.cpp_compile
],
flag_groups = [
flag_group(
flags = ["-g"],
),
],
)
],
implies = ["unbundle-debuginfo"],
),
]
Linux (使用 fission
) 或 Windows 可以產生 .pdb
檔案,而這項功能可以完全以不同方式實作這項功能。舉例來說,以 fission
為基礎的偵錯符號產生方式可能如下所示:
load("@rules_cc//cc:defs.bzl", "ACTION_NAMES")
action_configs = [
action_config (
name = ACTION_NAMES.cpp_compile,
tools = [
tool(
tool_path = "toolchain/bin/gcc",
),
],
),
]
features = [
feature (
name = "generate-debug-symbols",
requires = [with_feature_set(features = ["dbg"])],
flag_sets = [
flag_set(
actions = [ACTION_NAMES.cpp_compile],
flag_groups = [
flag_group(
flags = ["-gsplit-dwarf"],
),
],
),
flag_set(
actions = [ACTION_NAMES.cpp_link_executable],
flag_groups = [
flag_group(
flags = ["-Wl", "--gdb-index"],
),
],
),
],
),
]
標記群組
CcToolchainConfigInfo
可讓您將標記分為有特定用途的群組。您可以在標記值中使用預先定義的變數來指定標記,編譯器會在將標記加入建構指令時展開。例如:
flag_group (
flags = ["%{output_file_path}"],
)
在這種情況下,標記的內容會替換成該動作的輸出檔案路徑。
標記群組會按照建構指令的順序展開為建構指令,順序為由上到下和由左至右。
對於在加入建構指令時,需要以不同的值重複的標記,標記群組可以疊代類型 list
的變數。例如,類型 list
的變數 include_path
:
flag_group (
iterate_over = "include_paths",
flags = ["-I%{include_paths}"],
)
include_paths
清單中的每個路徑元素會展開為 -I<path>
。標記群組宣告主體中的所有標記 (或 flag_group
) 都會展開為一個單位。例如:
flag_group (
iterate_over = "include_paths",
flags = ["-I", "%{include_paths}"],
)
include_paths
清單中的每個路徑元素會展開為 -I <path>
。
變數可以多次重複。例如:
flag_group (
iterate_over = "include_paths",
flags = ["-iprefix=%{include_paths}", "-isystem=%{include_paths}"],
)
會展開為:
-iprefix=<inc0> -isystem=<inc0> -iprefix=<inc1> -isystem=<inc1>
變數可以對應到使用點號標記法存取的結構。舉例來說:
flag_group (
flags = ["-l%{libraries_to_link.name}"],
)
結構可以是巢狀結構,也可以包含序列。為了防止名稱衝突並明確地呈現,您必須在所有欄位內指定完整路徑。舉例來說:
flag_group (
iterate_over = "libraries_to_link",
flag_groups = [
flag_group (
iterate_over = "libraries_to_link.shared_libraries",
flags = ["-l%{libraries_to_link.shared_libraries.name}"],
),
],
)
條件式展開
標記群組支援根據是否有特定變數或其欄位使用 expand_if_available
、expand_if_not_available
、expand_if_true
、expand_if_false
或 expand_if_equal
屬性,支援條件式展開。例如:
flag_group (
iterate_over = "libraries_to_link",
flag_groups = [
flag_group (
iterate_over = "libraries_to_link.shared_libraries",
flag_groups = [
flag_group (
expand_if_available = "libraries_to_link.shared_libraries.is_whole_archive",
flags = ["--whole_archive"],
),
flag_group (
flags = ["-l%{libraries_to_link.shared_libraries.name}"],
),
flag_group (
expand_if_available = "libraries_to_link.shared_libraries.is_whole_archive",
flags = ["--no_whole_archive"],
),
],
),
],
)
CcToolchainConfigInfo 參考資料
本節提供建構變數、功能和其他資訊的參考資料,以成功設定 C++ 規則。
CcToolchainConfigInfo 建構變數
以下是 CcToolchainConfigInfo
建構變數的參照。
變數 | 動作 | 說明 |
source_file
|
compile | 要編譯的來源檔案。 |
input_file
|
長條 | 要去除的構件。 |
output_file
|
compile | 編譯輸出。 |
output_assembly_file
|
compile | 輸出的組合檔案。僅適用於 compile 動作發出組合文字的情況,通常是使用 --save_temps 標記時。內容與 output_file 相同。 |
output_preprocess_file
|
compile | 預先處理的輸出內容。僅適用於預先處理來源檔案的編譯動作,通常是使用 --save_temps 標記時。內容與 output_file 相同。 |
includes
|
compile | 編譯器必須無條件納入已編譯來源中的檔案序列。 |
include_paths
|
compile | 序列目錄,其中編譯器會使用 #include<foo.h> 和 #include "foo.h" 搜尋包含的標頭。 |
quote_include_paths
|
compile | -iquote 序列包含 - 編譯器會使用 #include "foo.h" 搜尋包含的標頭。 |
system_include_paths
|
compile | -isystem 序列包含 - 編譯器會使用 #include <foo.h> 搜尋包含的標頭。 |
dependency_file
|
compile | 編譯器產生的 .d 依附元件檔案。 |
preprocessor_defines
|
compile | defines 的序列,例如 --DDEBUG 。 |
pic
|
compile | 將輸出內容編譯為無關程式碼。 |
gcov_gcno_file
|
compile | gcov 涵蓋率檔案。 |
per_object_debug_info_file
|
compile | 個別物件的偵錯資訊 (.dwp ) 檔案。 |
stripotps
|
長條 | stripopts 的序列。 |
legacy_compile_flags
|
compile | 舊版 CROSSTOOL 欄位 (例如 compiler_flag 、optional_compiler_flag 、cxx_flag 和 optional_cxx_flag ) 的標記序列。 |
user_compile_flags
|
compile | copt 規則屬性或 --copt 、--cxxopt 和 --conlyopt 旗標的標記序列。 |
unfiltered_compile_flags
|
compile | unfiltered_cxx_flag 舊版 CROSSTOOL 欄位或 unfiltered_compile_flags 功能的標記序列。這些物件不會以 nocopts 規則屬性篩選。 |
sysroot
|
sysroot 。 |
|
runtime_library_search_directories
|
連結 | 連結器執行階段搜尋路徑中的項目 (通常以 -rpath 旗標設定)。 |
library_search_directories
|
連結 | 連結器搜尋路徑中的項目 (通常以 -L 旗標設定)。 |
libraries_to_link
|
連結 | 提供檔案連結做為連結器叫用中輸入內容的旗標, |
def_file_path
|
連結 | 在具有 MSVC 的 Windows 上使用防禦檔案的位置。 |
linker_param_file
|
連結 | bazel 建立的連結器參數檔案的位置,以超過指令列長度限制。 |
output_execpath
|
連結 | 連結器輸出內容的執行路徑。 |
generate_interface_library
|
連結 | "yes" 或 "no" ,視是否應產生介面程式庫而定。 |
interface_library_builder_path
|
連結 | 介面程式庫建構工具工具的路徑。 |
interface_library_input_path
|
連結 | 介面程式庫 ifso 建構工具的輸入內容。 |
interface_library_output_path
|
連結 | 使用 ifso 建構工具產生介面程式庫的路徑。 |
legacy_link_flags
|
連結 | 來自舊版 CROSSTOOL 欄位的連結器標記。 |
user_link_flags
|
連結 | 來自 --linkopt 或 linkopts 屬性的連結器標記。 |
symbol_counts_output
|
連結 | 寫入符號計數的路徑。 |
linkstamp_paths
|
連結 | 提供連結 tamp 路徑的建構變數。 |
force_pic
|
連結 | 若有此變數,則表示應產生 PIC/PIE 程式碼 (已傳遞 Bazel 選項「--force_pic」)。 |
strip_debug_symbols
|
連結 | 如出現這個變數,則表示應移除偵錯符號。 |
is_cc_test
|
連結 | 如果目前動作是 cc_test 連結動作,事實上是有效的,否則傳回 false。 |
is_using_fission
|
compile, link | 如出現這個變數,就表示啟用 (個別物件偵錯資訊) 已啟用。偵錯資訊會顯示在 .dwo 檔案中,而非 .o 檔案,且編譯器和連接器需要知道這一點。 |
fdo_instrument_path
|
compile, link | 儲存 FDO 檢測設定檔的目錄路徑。 |
fdo_profile_path
|
compile | FDO 設定檔的路徑。 |
fdo_prefetch_hints_path
|
compile | 快取預先擷取設定檔的路徑。 |
csfdo_instrument_path
|
compile, link | 儲存情境機密 FDO 檢測設定檔的目錄路徑。 |
知名功能
以下為各項功能及其啟用條件的參考資料。
功能 | 說明文件 |
opt | dbg | fastbuild
|
預設依據編譯模式啟用。 |
static_linking_mode | dynamic_linking_mode
|
系統會根據連結模式預設啟用。 |
per_object_debug_info
|
如果已指定並啟用 supports_fission 功能,且 --fission 旗標中指定目前的編譯模式,就會啟用這個模式。
|
supports_start_end_lib
|
如果啟用且已設定 --start_end_lib 選項,Bazel 不會連結至靜態資料庫,而是使用 --start-lib/--end-lib 連結器選項直接連結至物件。由於 Bazel 不必建構靜態資料庫,因此能加快建構速度。 |
supports_interface_shared_libraries
|
如果啟用 (且已設定 --interface_shared_objects 選項),Bazel 會將 linkstatic 設為 False (預設為 cc_test ) 的目標連結至介面共用資料庫。進而加快漸進式重新連結的速度。
|
supports_dynamic_linker
|
啟用後,C++ 規則知道工具鍊可以產生共用程式庫。 |
static_link_cpp_runtimes
|
如果啟用,Bazel 會在靜態連結模式下以靜態方式連結 C++ 執行階段,並以動態方式在動態連結模式中進行。您在 cc_toolchain.static_runtime_lib 或 cc_toolchain.dynamic_runtime_lib 屬性中指定的構件 (視連結模式而定) 會新增至連結動作。
|
supports_pic
|
啟用後,工具鍊就會知道將 PIC 物件用於動態程式庫。需要 PIC 編譯時,都會存在 `pic` 變數。如未預設啟用並傳遞「--force_pic」,則 Bazel 會要求「supports_pic」並驗證這項功能是否已啟用。如果這項功能缺少或無法啟用,就無法使用「--force_pic」。 |
static_linking_mode | dynamic_linking_mode
|
預設根據連結模式啟用。 |
no_legacy_features
|
可防止 Bazel 在 C++ 設定中將舊版功能新增至 C++ 設定。如需完整功能清單,請參閱下方。 |
舊版功能修補邏輯
Bazel 會將下列變更套用至工具鍊的功能,以提供回溯相容性:
- 將
legacy_compile_flags
功能移至工具鍊頂端 - 將
default_compile_flags
功能移至工具鍊頂端 - 在工具鍊頂端新增
dependency_file
(如果尚未顯示) 功能 - 在工具鍊頂端新增
pic
(如果尚未顯示) 功能 - 在工具鍊頂端新增
per_object_debug_info
(如果尚未顯示) 功能 - 在工具鍊頂端新增
preprocessor_defines
(如果尚未顯示) 功能 - 在工具鍊頂端新增
includes
(如果尚未顯示) 功能 - 在工具鍊頂端新增
include_paths
(如果尚未顯示) 功能 - 在工具鍊頂端新增
fdo_instrument
(如果尚未顯示) 功能 - 在工具鍊頂端新增
fdo_optimize
(如果尚未顯示) 功能 - 在工具鍊頂端新增
cs_fdo_instrument
(如果尚未顯示) 功能 - 在工具鍊頂端新增
cs_fdo_optimize
(如果尚未顯示) 功能 - 在工具鍊頂端新增
fdo_prefetch_hints
(如果尚未顯示) 功能 - 在工具鍊頂端新增
autofdo
(如果尚未顯示) 功能 - 在工具鍊頂端新增
build_interface_libraries
(如果尚未顯示) 功能 - 在工具鍊頂端新增
dynamic_library_linker_tool
(如果尚未顯示) 功能 - 在工具鍊頂端新增
symbol_counts
(如果尚未顯示) 功能 - 在工具鍊頂端新增
shared_flag
(如果尚未顯示) 功能 - 在工具鍊頂端新增
linkstamps
(如果尚未顯示) 功能 - 在工具鍊頂端新增
output_execpath_flags
(如果尚未顯示) 功能 - 在工具鍊頂端新增
runtime_library_search_directories
(如果尚未顯示) 功能 - 在工具鍊頂端新增
library_search_directories
(如果尚未顯示) 功能 - 在工具鍊頂端新增
archiver_flags
(如果尚未顯示) 功能 - 在工具鍊頂端新增
libraries_to_link
(如果尚未顯示) 功能 - 在工具鍊頂端新增
force_pic_flags
(如果尚未顯示) 功能 - 在工具鍊頂端新增
user_link_flags
(如果尚未顯示) 功能 - 在工具鍊頂端新增
legacy_link_flags
(如果尚未顯示) 功能 - 在工具鍊頂端新增
static_libgcc
(如果尚未顯示) 功能 - 在工具鍊頂端新增
fission_support
(如果尚未顯示) 功能 - 在工具鍊頂端新增
strip_debug_symbols
(如果尚未顯示) 功能 - 在工具鍊頂端新增
coverage
(如果尚未顯示) 功能 - 在工具鍊頂端新增
llvm_coverage_map_format
(如果尚未顯示) 功能 - 在工具鍊頂端新增
gcc_coverage_map_format
(如果尚未顯示) 功能 - 在工具鍊底部新增
fully_static_link
(如未顯示) 功能 - 在工具鍊底部新增
user_compile_flags
(如未顯示) 功能 - 在工具鍊底部新增
sysroot
(如未顯示) 功能 - 在工具鍊底部新增
unfiltered_compile_flags
(如未顯示) 功能 - 在工具鍊底部新增
linker_param_file
(如未顯示) 功能 - 在工具鍊底部新增
compiler_input_flags
(如未顯示) 功能 - 在工具鍊底部新增
compiler_output_flags
(如未顯示) 功能
這份功能很長。我們計劃在 Starlark 中的 Crosstool 完成後,再予以刪除。有好奇的讀取者請參閱 CppActionConfigs 中的實作,對於實際工作環境工具鍊,請考慮新增 no_legacy_features
,讓工具鍊更加獨立。