Mức độ sử dụng mã với Bazel

Báo cáo vấn đề Xem nguồn Nightly · 8.0 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

Bazel có một lệnh phụ coverage để tạo báo cáo mức độ sử dụng mã trên các kho lưu trữ có thể được kiểm thử bằng bazel coverage. Do đặc thù của nhiều hệ sinh thái ngôn ngữ, việc làm cho tính năng này hoạt động cho một dự án cụ thể không phải lúc nào cũng đơn giản.

Trang này ghi lại quy trình chung để tạo và xem báo cáo mức độ sử dụng, đồng thời cung cấp một số ghi chú dành riêng cho ngôn ngữ đối với những ngôn ngữ có cấu hình phổ biến. Tốt nhất là bạn nên đọc phần chung trước, sau đó đọc về các yêu cầu đối với một ngôn ngữ cụ thể. Ngoài ra, hãy lưu ý đến phần thực thi từ xa, phần này cần cân nhắc thêm một số yếu tố.

Mặc dù có thể tuỳ chỉnh nhiều, nhưng tài liệu này tập trung vào việc tạo và sử dụng báo cáo lcov, đây là tuyến đường được hỗ trợ tốt nhất hiện nay.

Tạo báo cáo phạm vi

Chuẩn bị

Quy trình làm việc cơ bản để tạo báo cáo phạm vi yêu cầu những điều sau:

Kho lưu trữ cơ bản có mục tiêu kiểm thử
Chuỗi công cụ đã cài đặt các công cụ đo lường mức độ sử dụng mã theo ngôn ngữ
Cấu hình "thiết bị đo lường" chính xác

Hai phương thức trước là dành riêng cho ngôn ngữ và chủ yếu là đơn giản, tuy nhiên phương thức sau có thể khó hơn đối với các dự án phức tạp.

"Đo lường" trong trường hợp này đề cập đến các công cụ đo lường phạm vi được sử dụng cho một mục tiêu cụ thể. Bazel cho phép bật tính năng này cho một nhóm tệp cụ thể bằng cách sử dụng cờ --instrumentation_filter. Cờ này chỉ định bộ lọc cho các mục tiêu được kiểm thử khi bật tính năng đo lường. Để bật tính năng đo lường cho các chương trình kiểm thử, bạn cần có cờ --instrument_test_targets.

Theo mặc định, bazel sẽ cố gắng so khớp(các) gói mục tiêu và in bộ lọc có liên quan dưới dạng thông báo INFO.

Mức độ bao phủ khi chạy

Để tạo báo cáo phạm vi lập chỉ mục, hãy sử dụng bazel coverage --combined_report=lcov [target]. Thao tác này sẽ chạy các chương trình kiểm thử cho mục tiêu, tạo báo cáo mức độ sử dụng mã nguồn ở định dạng lcov cho mỗi tệp.

Sau khi hoàn tất, bazel sẽ chạy một thao tác thu thập tất cả các tệp mức độ sử dụng được tạo và hợp nhất các tệp đó thành một tệp, sau đó tệp này sẽ được tạo trong $(bazel info output_path)/_coverage/_coverage_report.dat.

Báo cáo mức độ sử dụng cũng được tạo nếu kiểm thử không đạt, mặc dù lưu ý rằng điều này không áp dụng cho các kiểm thử không đạt – chỉ các kiểm thử đạt mới được báo cáo.

Xem phạm vi bảo hiểm

Báo cáo mức độ sử dụng chỉ xuất ra ở định dạng lcov không thể đọc được. Từ đó, chúng ta có thể sử dụng tiện ích genhtml (một phần của dự án lcov) để tạo báo cáo có thể xem trong trình duyệt web:

genhtml --output genhtml "$(bazel info output_path)/_coverage/_coverage_report.dat"

Xin lưu ý rằng genhtml cũng đọc mã nguồn để chú thích mức độ sử dụng thiếu trong các tệp này. Để tính năng này hoạt động, dự kiến genhtml sẽ được thực thi trong thư mục gốc của dự án bazel.

Để xem kết quả, bạn chỉ cần mở tệp index.html được tạo trong thư mục genhtml trong bất kỳ trình duyệt web nào.

Để được trợ giúp và thông tin thêm về công cụ genhtml hoặc định dạng mức độ sử dụng lcov, hãy xem dự án lcov.

Thực thi từ xa

Việc chạy bằng tính năng thực thi kiểm thử từ xa hiện có một số lưu ý:

Bạn chưa thể chạy hành động kết hợp báo cáo từ xa. Lý do là Bazel không coi các tệp đầu ra về mức độ sử dụng là một phần của biểu đồ (xem vấn đề này), do đó, không thể coi các tệp này là dữ liệu đầu vào chính xác cho thao tác kết hợp. Để giải quyết vấn đề này, hãy sử dụng --strategy=CoverageReport=local.
- Lưu ý: Bạn có thể cần chỉ định một giá trị như --strategy=CoverageReport=local,remote, nếu Bazel được thiết lập để thử local,remote, do cách Bazel phân giải các chiến lược.
--remote_download_minimal và các cờ tương tự cũng không thể được sử dụng do cờ trước đó.
Bazel hiện sẽ không tạo được thông tin về mức độ sử dụng nếu các chương trình kiểm thử đã được lưu vào bộ nhớ đệm trước đó. Để giải quyết vấn đề này, bạn có thể đặt --nocache_test_results dành riêng cho các lần chạy kiểm thử mức độ sử dụng mã, mặc dù điều này tất nhiên sẽ gây tốn kém về thời gian kiểm thử.
--experimental_split_coverage_postprocessing và --experimental_fetch_all_coverage_outputs
- Thông thường, mức độ sử dụng được chạy như một phần của hành động kiểm thử, vì vậy, theo mặc định, chúng ta không nhận được tất cả mức độ sử dụng dưới dạng đầu ra của quá trình thực thi từ xa. Các cờ này sẽ ghi đè cờ mặc định và lấy dữ liệu phạm vi. Hãy xem vấn đề này để biết thêm thông tin chi tiết.

Cấu hình theo ngôn ngữ cụ thể

Java

Java sẽ hoạt động ngay lập tức với cấu hình mặc định. Chuỗi công cụ bazel chứa mọi thứ cần thiết để thực thi từ xa, bao gồm cả JUnit.

Python

Điều kiện tiên quyết

Việc chạy mức độ sử dụng bằng python có một số điều kiện tiên quyết:

Tệp nhị phân bazel bao gồm b01c859, phải là bất kỳ Bazel nào >3.0.
Phiên bản sửa đổi của coverage.py.

Sử dụng coverage.py đã sửa đổi

Một cách để thực hiện việc này là thông qua rules_python, cách này cho phép sử dụng tệp requirements.txt, sau đó các yêu cầu được liệt kê trong tệp sẽ được tạo dưới dạng mục tiêu bazel bằng cách sử dụng quy tắc kho lưu trữ pip_install.

requirements.txt phải có mục nhập sau:

git+https://github.com/ulfjack/coveragepy.git@lcov-support

Sau đó, bạn nên sử dụng tệp rules_python, pip_install và requirements.txt trong tệp WORKSPACE như sau:

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "rules_python",
    url = "https://github.com/bazelbuild/rules_python/releases/download/0.5.0/rules_python-0.5.0.tar.gz",
    sha256 = "cd6730ed53a002c56ce4e2f396ba3b3be262fd7cb68339f0377a45e8227fe332",
)

load("@rules_python//python:pip.bzl", "pip_install")

pip_install(
   name = "python_deps",
   requirements = "//:requirements.txt",
)

Sau đó, các mục tiêu kiểm thử có thể sử dụng yêu cầu coverage.py bằng cách đặt nội dung sau trong tệp BUILD:

load("@python_deps//:requirements.bzl", "entry_point")

alias(
    name = "python_coverage_tools",
    actual = entry_point("coverage"),
)

py_test(
    name = "test",
    srcs = ["test.py"],
    env = {
        "PYTHON_COVERAGE": "$(location :python_coverage_tools)",
    },
    deps = [
        ":main",
        ":python_coverage_tools",
    ],
)

Nếu đang sử dụng chuỗi công cụ Python kín, thay vì thêm phần phụ thuộc mức độ sử dụng vào mọi mục tiêu py_test, bạn có thể thêm công cụ mức độ sử dụng vào cấu hình chuỗi công cụ.

Vì quy tắc pip_install phụ thuộc vào chuỗi công cụ Python, nên bạn không thể dùng quy tắc này để tìm nạp mô-đun coverage. Thay vào đó, hãy thêm WORKSPACE, ví dụ:

http_archive(
    name = "coverage_linux_x86_64"",
    build_file_content = """
py_library(
    name = "coverage",
    srcs = ["coverage/__main__.py"],
    data = glob(["coverage/*", "coverage/**/*.py"]),
    visibility = ["//visibility:public"],
)
""",
    sha256 = "84631e81dd053e8a0d4967cedab6db94345f1c36107c71698f746cb2636c63e3",
    type = "zip",
    urls = [
        "https://files.pythonhosted.org/packages/74/0d/0f3c522312fd27c32e1abe2fb5c323b583a5c108daf2c26d6e8dfdd5a105/coverage-6.4.1-cp39-cp39-manylinux_2_5_x86_64.manylinux1_x86_64.manylinux_2_17_x86_64.manylinux2014_x86_64.whl",
    ],
)

Sau đó, hãy định cấu hình chuỗi công cụ python như ví dụ sau:

py_runtime(
    name = "py3_runtime_linux_x86_64",
    coverage_tool = "@coverage_linux_x86_64//:coverage",
    files = ["@python3_9_x86_64-unknown-linux-gnu//:files"],
    interpreter = "@python3_9_x86_64-unknown-linux-gnu//:bin/python3",
    python_version = "PY3",
)

py_runtime_pair(
    name = "python_runtimes_linux_x86_64",
    py2_runtime = None,
    py3_runtime = ":py3_runtime_linux_x86_64",
)

toolchain(
    name = "python_toolchain_linux_x86_64",
    exec_compatible_with = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
    ],
    toolchain = ":python_runtimes_linux_x86_64",
    toolchain_type = "@bazel_tools//tools/python:toolchain_type",
)