此页面由 Cloud Translation API 翻译。

使用 Bazel 实现代码覆盖率

报告问题查看源代码

Bazel 包含一个 coverage 子命令，可针对可以使用 bazel coverage 测试的代码库生成代码覆盖率报告。由于各种语言生态系统的特性，为给定项目完成这项工作有时并非易事。

本页面介绍了创建和查看覆盖率报告的一般流程，还针对配置众所周知的语言提供了一些针对特定语言的备注。您最好先阅读“常规”部分，然后阅读特定语言的相关要求。另请注意远程执行部分，这部分需要一些额外的注意事项。

虽然可以进行大量自定义设置，但本文档重点介绍如何生成和使用 lcov 报告，这是目前支持最广泛的途径。

创建覆盖率报告

准备

创建覆盖率报告的基本工作流程要求如下：

包含测试目标的基本代码库
安装了特定语言的代码覆盖率工具的工具链
正确的“插桩”配置

前两种方式因语言而异，大体相当简单，但后一种方式对于复杂的项目而言可能更困难。

这里的“插桩”是指用于特定目标的覆盖率工具。Bazel 允许使用 --instrumentation_filter 标志为特定的文件子集启用此功能，此标志为在启用插桩的情况下测试的目标指定了过滤条件。如需为测试启用插桩，需要 --instrument_test_targets 标志。

默认情况下，bazel 会尝试匹配目标软件包，并将相关过滤条件输出为 INFO 消息。

跑步覆盖率

如需生成覆盖率报告，请使用 bazel coverage --combined_report=lcov [target]。此操作会针对目标运行测试，并为每个文件生成 lcov 格式的覆盖率报告。

完成后，bazel 会运行一项操作来收集所有生成的覆盖率文件，并将它们合并为一个操作，然后最终在 $(bazel info output_path)/_coverage/_coverage_report.dat 下创建该文件。

如果测试失败，系统也会生成覆盖率报告，但请注意，这并不扩展到失败的测试，只有通过的测试才会报告。

查看覆盖率

覆盖率报告仅以不直观的 lcov 格式输出。由此，我们可以使用 genhtml 实用程序（lcov 项目的一部分）生成可在网络浏览器中查看的报告：

genhtml --output genhtml "$(bazel info output_path)/_coverage/_coverage_report.dat"

请注意，genhtml 也会读取源代码，以为这些文件中缺失的覆盖率添加注解。为此，应在 bazel 项目的根目录中执行 genhtml。

如需查看结果，只需在任意网络浏览器中打开 genhtml 目录中生成的 index.html 文件即可。

如需有关 genhtml 工具或 lcov 覆盖率格式的进一步帮助和信息，请参阅 lcov 项目。

远程执行

目前，使用远程测试执行运行有几点注意事项：

目前无法远程运行此报告组合操作。这是因为 Bazel 未将覆盖率输出文件视为其图表的一部分（请参阅此问题），因此无法将它们正确视为组合操作的输入。如需解决此问题，请使用 --strategy=CoverageReport=local。
- 注意：如果 Bazel 设置为试用 local,remote，由于 Bazel 解析策略的方式，则可能需要指定类似 --strategy=CoverageReport=local,remote 的内容。
--remote_download_minimal 和类似标志也不能作为前者的结果。
如果之前已缓存测试，则 Bazel 目前将无法创建覆盖率信息。为了解决此问题，可以专门为覆盖率运行设置 --nocache_test_results。当然，在测试时间方面，这当然会产生高昂的成本。
--experimental_split_coverage_postprocessing 和 --experimental_fetch_all_coverage_outputs
- 覆盖率通常是作为测试操作的一部分运行，因此默认情况下，我们不会将所有覆盖率返回为远程执行的输出。这些标志会替换默认值并获取覆盖率数据。如需了解详情，请参阅此问题。

特定于语言的配置

Java

Java 应该可以在默认配置下开箱即用。bazel 工具链包含远程执行所需的所有内容，包括 JUnit。

Python

前提条件

使用 Python 运行覆盖率需满足一些前提条件：

一个包含 b01c859（应为版本高于 3.0 的 Bazel）的 bazel 二进制文件。
Coverage.py 的修改版本。

使用修改后的覆盖率.py

一种方法是通过 rules_python，它提供了使用 requirements.txt 文件的功能，然后使用 pip_install 代码库规则将文件中列出的要求创建为 bazel 目标。

requirements.txt 应包含以下条目：

git+https://github.com/ulfjack/coveragepy.git@lcov-support

然后，应在 WORKSPACE 文件中将 rules_python、pip_install 和 requirements.txt 文件用作：

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "rules_python",
    url = "https://github.com/bazelbuild/rules_python/releases/download/0.5.0/rules_python-0.5.0.tar.gz",
    sha256 = "cd6730ed53a002c56ce4e2f396ba3b3be262fd7cb68339f0377a45e8227fe332",
)

load("@rules_python//python:pip.bzl", "pip_install")

pip_install(
   name = "python_deps",
   requirements = "//:requirements.txt",
)

然后，通过在 BUILD 文件中设置以下内容，测试目标便可以使用 reach.py 要求：

load("@python_deps//:requirements.bzl", "entry_point")

alias(
    name = "python_coverage_tools",
    actual = entry_point("coverage"),
)

py_test(
    name = "test",
    srcs = ["test.py"],
    env = {
        "PYTHON_COVERAGE": "$(location :python_coverage_tools)",
    },
    deps = [
        ":main",
        ":python_coverage_tools",
    ],
)

如果您使用的是封闭的 Python 工具链，则可以向工具链配置添加覆盖率工具，而不是为每个 py_test 目标添加覆盖率依赖项。

由于 pip_install 规则依赖于 Python 工具链，因此不能用于提取 coverage 模块。而是添加您的 WORKSPACE，例如

http_archive(
    name = "coverage_linux_x86_64"",
    build_file_content = """
py_library(
    name = "coverage",
    srcs = ["coverage/__main__.py"],
    data = glob(["coverage/*", "coverage/**/*.py"]),
    visibility = ["//visibility:public"],
)
""",
    sha256 = "84631e81dd053e8a0d4967cedab6db94345f1c36107c71698f746cb2636c63e3",
    type = "zip",
    urls = [
        "https://files.pythonhosted.org/packages/74/0d/0f3c522312fd27c32e1abe2fb5c323b583a5c108daf2c26d6e8dfdd5a105/coverage-6.4.1-cp39-cp39-manylinux_2_5_x86_64.manylinux1_x86_64.manylinux_2_17_x86_64.manylinux2014_x86_64.whl",
    ],
)

然后配置您的 Python 工具链，例如

py_runtime(
    name = "py3_runtime_linux_x86_64",
    coverage_tool = "@coverage_linux_x86_64//:coverage",
    files = ["@python3_9_x86_64-unknown-linux-gnu//:files"],
    interpreter = "@python3_9_x86_64-unknown-linux-gnu//:bin/python3",
    python_version = "PY3",
)

py_runtime_pair(
    name = "python_runtimes_linux_x86_64",
    py2_runtime = None,
    py3_runtime = ":py3_runtime_linux_x86_64",
)

toolchain(
    name = "python_toolchain_linux_x86_64",
    exec_compatible_with = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
    ],
    toolchain = ":python_runtimes_linux_x86_64",
    toolchain_type = "@bazel_tools//tools/python:toolchain_type",
)