您可以在這裡找到一些最常見的用途，瞭解如何使用 Bazel 建構 C++ 專案。如果您尚未完成「Bazel 簡介：建構 C++ 專案」教學課程，請先完成該課程，瞭解如何使用 Bazel 建構 C++ 專案。
如要瞭解 cc_library 和 hdrs 標頭檔案，請參閱 cc_library。
在目標中加入多個檔案
您可以使用 glob 在單一目標中納入多個檔案。 例如：
cc_library(
name = "build-all-the-files",
srcs = glob(["*.cc"]),
hdrs = glob(["*.h"]),
)
有了這個目標，Bazel 會建構與包含此目標的 BUILD 檔案位於相同目錄中的所有 .cc 和 .h 檔案 (不含子目錄)。
使用轉換包含
如果檔案包含標頭，則以該檔案做為來源的任何規則 (也就是在 srcs、hdrs 或 textual_hdrs 屬性中包含該檔案) 都應依附於所含標頭的程式庫規則。反之，只有直接依附元件需要指定為依附元件。舉例來說，假設 sandwich.h 包含 bread.h，而 bread.h 包含 flour.h。sandwich.h
不含 flour.h (誰想在三明治裡加麵粉？)，因此 BUILD
檔案會如下所示：
cc_library(
name = "sandwich",
srcs = ["sandwich.cc"],
hdrs = ["sandwich.h"],
deps = [":bread"],
)
cc_library(
name = "bread",
srcs = ["bread.cc"],
hdrs = ["bread.h"],
deps = [":flour"],
)
cc_library(
name = "flour",
srcs = ["flour.cc"],
hdrs = ["flour.h"],
)
在這裡，sandwich 程式庫依附於 bread 程式庫，而 bread 程式庫則依附於 flour 程式庫。
新增包含路徑
有時候，您無法 (或不想) 在工作區根目錄中加入根目錄路徑。現有程式庫可能已有 include 目錄，但與工作區中的路徑不符。舉例來說，假設您有下列目錄結構：
└── my-project
├── legacy
│ └── some_lib
│ ├── BUILD
│ ├── include
│ │ └── some_lib.h
│ └── some_lib.cc
└── WORKSPACE
Bazel 會預期 some_lib.h 包含 legacy/some_lib/include/some_lib.h，但假設 some_lib.cc 包含 "some_lib.h"。如要讓該包含路徑有效，legacy/some_lib/BUILD需要指定 some_lib/include 目錄為包含目錄：
cc_library(
name = "some_lib",
srcs = ["some_lib.cc"],
hdrs = ["include/some_lib.h"],
copts = ["-Ilegacy/some_lib/include"],
)
這對外部依附元件特別有用，因為否則必須使用 / 前置字元納入標頭檔。
包括外部程式庫
假設您使用 Google 測試。
您可以在 WORKSPACE 檔案中使用其中一個存放區函式，下載 Google 測試並在存放區中提供：
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
http_archive(
name = "gtest",
url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
build_file = "@//:gtest.BUILD",
)
接著，建立用於編譯 Google 測試的 gtest.BUILD BUILD 檔案。Google 測試有幾項「特殊」規定，導致其 cc_library 規則較為複雜：
googletest-release-1.10.0/src/gtest-all.cc#includes 所有其他檔案：將其從編譯中排除，避免重複符號發生連結錯誤。googletest-release-1.10.0/src/它使用的標頭檔案與
googletest-release-1.10.0/include/目錄 ("gtest/gtest.h") 相關，因此您必須將該目錄新增至 include 路徑。它需要連結至
pthread，因此請將其新增為linkopt。
因此，最終規則如下所示：
cc_library(
name = "main",
srcs = glob(
["googletest-release-1.10.0/src/*.cc"],
exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
),
hdrs = glob([
"googletest-release-1.10.0/include/**/*.h",
"googletest-release-1.10.0/src/*.h"
]),
copts = [
"-Iexternal/gtest/googletest-release-1.10.0/include",
"-Iexternal/gtest/googletest-release-1.10.0"
],
linkopts = ["-pthread"],
visibility = ["//visibility:public"],
)
這有點混亂：所有內容都以 googletest-release-1.10.0 為前置字元，這是封存結構的副產品。如要讓 http_archive 移除這個前置字元，請新增 strip_prefix 屬性：
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
http_archive(
name = "gtest",
url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
build_file = "@//:gtest.BUILD",
strip_prefix = "googletest-release-1.10.0",
)
gtest.BUILD 看起來會像這樣：
cc_library(
name = "main",
srcs = glob(
["src/*.cc"],
exclude = ["src/gtest-all.cc"]
),
hdrs = glob([
"include/**/*.h",
"src/*.h"
]),
copts = ["-Iexternal/gtest/include"],
linkopts = ["-pthread"],
visibility = ["//visibility:public"],
)
現在 cc_ 規則可以依附於 @gtest//:main。
編寫及執行 C++ 測試
舉例來說，您可以建立測試 ./test/hello-test.cc，例如：
#include "gtest/gtest.h"
#include "main/hello-greet.h"
TEST(HelloTest, GetGreet) {
EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}
接著，為測試建立 ./test/BUILD 檔案：
cc_test(
name = "hello-test",
srcs = ["hello-test.cc"],
copts = ["-Iexternal/gtest/include"],
deps = [
"@gtest//:main",
"//main:hello-greet",
],
)
如要讓 hello-greet 對 hello-test 可見，您必須在 ./main/BUILD 的 visibility 屬性中加入 "//test:__pkg__",。
現在可以使用 bazel test 執行測試。
bazel test test:hello-test
這會產生下列輸出內容：
INFO: Found 1 test target...
Target //test:hello-test up-to-date:
bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s
Executed 1 out of 1 tests: 1 test passes.
新增預先編譯程式庫的依附元件
如要使用只有已編譯版本的程式庫 (例如標頭和 .so 檔案)，請將其包裝在 cc_library 規則中：
cc_library(
name = "mylib",
srcs = ["mylib.so"],
hdrs = ["mylib.h"],
)
這樣一來，工作區中的其他 C++ 目標就能依據這項規則。