กรณีการใช้งานทั่วไปของ C++ เกี่ยวกับการสร้าง

Nightly · 8.4 · 8.3 · 8.2 · 8.1 · 8.0 · 7.6

ในส่วนนี้ คุณจะเห็นกรณีการใช้งานที่พบบ่อยที่สุดบางส่วนสำหรับการสร้างโปรเจ็กต์ C++ ด้วย Bazel หากยังไม่ได้ทำ ให้เริ่มต้นสร้างโปรเจ็กต์ C++ ด้วย Bazel โดยทำตามบทแนะนำข้อมูลเบื้องต้นเกี่ยวกับ Bazel: สร้างโปรเจ็กต์ C++

ดูข้อมูลเกี่ยวกับไฟล์ส่วนหัว cc_library และ hdrs ได้ที่ cc_library

การรวมไฟล์หลายไฟล์ไว้ในเป้าหมาย

คุณรวมไฟล์หลายไฟล์ไว้ในเป้าหมายเดียวได้ด้วย glob เช่น

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

เมื่อใช้เป้าหมายนี้ Bazel จะสร้างไฟล์ .cc และ .h ทั้งหมดที่พบในไดเรกทอรีเดียวกับไฟล์ BUILD ที่มีเป้าหมายนี้ (ไม่รวมไดเรกทอรีย่อย)

การใช้การรวมแบบทรานซิทีฟ

หากไฟล์มีส่วนหัว กฎใดก็ตามที่มีไฟล์นั้นเป็นแหล่งที่มา (กล่าวคือ มีไฟล์นั้นในแอตทริบิวต์ srcs, hdrs หรือ textual_hdrs) ควรขึ้นอยู่กับกฎไลบรารีของส่วนหัวที่รวมไว้ ในทางกลับกัน คุณต้องระบุเฉพาะ การอ้างอิงโดยตรงเป็นการอ้างอิง เช่น สมมติว่า sandwich.h มี bread.h และ bread.h มี flour.h sandwich.h ไม่มี flour.h (ใครจะอยากใส่แป้งในแซนวิชกัน) ดังนั้นBUILD ไฟล์จะมีลักษณะดังนี้

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

ในที่นี้ sandwich ขึ้นต่อกันกับไลบรารี bread ซึ่งขึ้นต่อกันกับไลบรารี flour

การเพิ่มเส้นทางรวม

บางครั้งคุณไม่สามารถ (หรือไม่อยาก) รูทเส้นทางรวมที่รูทของพื้นที่ทำงาน ไลบรารีที่มีอยู่อาจมีไดเรกทอรีรวมที่ไม่ตรงกับเส้นทางในพื้นที่ทำงาน ตัวอย่างเช่น สมมติว่าคุณมีโครงสร้างไดเรกทอรีต่อไปนี้ 

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel จะคาดหวังให้รวม some_lib.h เป็น legacy/some_lib/include/some_lib.h แต่สมมติว่า some_lib.cc มี "some_lib.h" หากต้องการทำให้เส้นทางรวมนั้นถูกต้อง legacy/some_lib/BUILD จะต้องระบุว่าไดเรกทอรี some_lib/include เป็นไดเรกทอรีรวม

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

ซึ่งจะเป็นประโยชน์อย่างยิ่งสำหรับทรัพยากรภายนอก เนื่องจากไฟล์ส่วนหัวของทรัพยากรเหล่านั้น ต้องรวมไว้กับคำนำหน้า /

รวมถึงไลบรารีภายนอก

สมมติว่าคุณใช้ Google Test คุณใช้ฟังก์ชันที่เก็บอย่างใดอย่างหนึ่งในไฟล์ WORKSPACE เพื่อ ดาวน์โหลด Google Test และทำให้พร้อมใช้งานในที่เก็บได้

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

จากนั้นสร้าง gtest.BUILD ซึ่งเป็นไฟล์ BUILD ที่ใช้ในการคอมไพล์ Google Test Google Test มีข้อกำหนด "พิเศษ" หลายอย่างที่ทำให้cc_libraryกฎ มีความซับซ้อนมากขึ้น

  • googletest-release-1.10.0/src/gtest-all.cc #includeไฟล์อื่นๆ ทั้งหมดใน googletest-release-1.10.0/src/: ยกเว้นไฟล์นี้จากการ คอมไพล์เพื่อป้องกันข้อผิดพลาดของลิงก์สำหรับสัญลักษณ์ที่ซ้ำกัน

  • โดยจะใช้ไฟล์ส่วนหัวที่สัมพันธ์กับไดเรกทอรี googletest-release-1.10.0/include/ ("gtest/gtest.h") ดังนั้นคุณต้อง เพิ่มไดเรกทอรีดังกล่าวลงในเส้นทางการรวม

  • โดยต้องลิงก์ใน pthread ดังนั้นให้เพิ่มเป็น linkopt

ดังนั้น กฎสุดท้ายจึงมีลักษณะดังนี้

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/src/*.cc"],
        exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/include/**/*.h",
        "googletest-release-1.10.0/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/include",
        "-Iexternal/gtest/googletest-release-1.10.0"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

ซึ่งค่อนข้างจะยุ่งเหยิงเนื่องจากทุกอย่างมีคำนำหน้าเป็น googletest-release-1.10.0 ซึ่งเป็นผลพลอยได้จากโครงสร้างของที่เก็บถาวร คุณสามารถhttp_archiveนำ คำนำหน้านี้ออกได้โดยการเพิ่มแอตทริบิวต์ strip_prefix

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

จากนั้น gtest.BUILD จะมีลักษณะดังนี้

cc_library(
    name = "main",
    srcs = glob(
        ["src/*.cc"],
        exclude = ["src/gtest-all.cc"]
    ),
    hdrs = glob([
        "include/**/*.h",
        "src/*.h"
    ]),
    copts = ["-Iexternal/gtest/include"],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

ตอนนี้cc_กฎจะขึ้นอยู่กับ@gtest//:mainได้แล้ว

การเขียนและการเรียกใช้การทดสอบ C++

เช่น คุณอาจสร้างแบบทดสอบ ./test/hello-test.cc เช่น

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

จากนั้นสร้างไฟล์ ./test/BUILD สำหรับการทดสอบ

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = ["-Iexternal/gtest/include"],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

หากต้องการให้ hello-greet แสดงต่อ hello-test คุณต้องเพิ่ม "//test:__pkg__", ลงในแอตทริบิวต์ visibility ใน ./main/BUILD

ตอนนี้คุณใช้ bazel test เพื่อเรียกใช้การทดสอบได้แล้ว

bazel test test:hello-test

ซึ่งจะสร้างเอาต์พุตต่อไปนี้

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

การเพิ่มทรัพยากร Dependency ในไลบรารีที่คอมไพล์ล่วงหน้า

หากต้องการใช้ไลบรารีที่คุณมีเฉพาะเวอร์ชันที่คอมไพล์แล้ว (เช่น ส่วนหัวและไฟล์ .so) ให้รวมไว้ในกฎ cc_library ดังนี้

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

ด้วยวิธีนี้ เป้าหมาย C++ อื่นๆ ในพื้นที่ทำงานจะขึ้นอยู่กับกฎนี้ได้