Pendaftaran BazelCon 2024 sudah dibuka!

Halaman ini diterjemahkan oleh Cloud Translation API.

Mengoptimalkan Performa

Laporkan masalah Lihat sumber Nightly · 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

Saat menulis aturan, masalah performa yang paling umum adalah menjelajahi atau menyalin data yang diakumulasikan dari dependensi. Jika digabungkan di seluruh build, operasi ini dapat dengan mudah menghabiskan waktu atau ruang O(N^2). Untuk menghindari hal ini, Anda harus memahami cara menggunakan depset secara efektif.

Hal ini mungkin sulit dilakukan dengan benar, sehingga Bazel juga menyediakan profiler memori yang membantu Anda menemukan tempat Anda mungkin melakukan kesalahan. Perhatikan: Biaya penulisan aturan yang tidak efisien mungkin tidak terlihat sampai aturan tersebut digunakan secara luas.

Menggunakan depset

Setiap kali Anda meluncurkan informasi dari dependensi aturan, Anda harus menggunakan depset. Hanya gunakan daftar atau dikte biasa untuk memublikasikan informasi yang bersifat lokal pada aturan saat ini.

Depset merepresentasikan informasi sebagai grafik bertingkat yang memungkinkan berbagi.

Perhatikan grafik berikut:

C -> B -> A
D ---^

Setiap node memublikasikan satu string. Dengan depset, data akan terlihat seperti ini:

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

Perhatikan bahwa setiap item hanya disebutkan satu kali. Dengan daftar, Anda akan mendapatkan ini:

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

Perhatikan bahwa dalam hal ini 'a' disebutkan empat kali. Dengan grafik yang lebih besar, masalah ini hanya akan menjadi lebih buruk.

Berikut adalah contoh penerapan aturan yang menggunakan depset dengan benar untuk memublikasikan informasi transitif. Perhatikan bahwa Anda dapat memublikasikan informasi lokal aturan menggunakan daftar jika mau karena ini bukan O(N^2).

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

Lihat halaman ringkasan depset untuk mengetahui informasi selengkapnya.

Hindari memanggil `depset.to_list()`

Anda dapat memaksa depset ke daftar datar menggunakan to_list(), tetapi melakukannya biasanya menghasilkan biaya O(N^2). Jika memungkinkan, hindari penyederhanaan depset kecuali untuk tujuan proses debug.

Kesalahpahaman umum adalah Anda dapat meratakan depset secara bebas jika hanya melakukannya di target tingkat atas, seperti aturan <xx>_binary, karena biaya tidak diakumulasikan di setiap tingkat grafik build. Namun, ini masih O(N^2) saat Anda mem-build sekumpulan target dengan dependensi yang tumpang-tindih. Hal ini terjadi saat mem-build //foo/tests/... pengujian, atau saat mengimpor project IDE.

Mengurangi jumlah panggilan ke `depset`

Memanggil depset di dalam loop sering kali merupakan kesalahan. Hal ini dapat menyebabkan depset dengan nesting yang sangat dalam, yang berperforma buruk. Contoh:

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

Kode ini dapat diganti dengan mudah. Pertama, kumpulkan depset transitif dan gabungkan semuanya sekaligus:

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

Hal ini terkadang dapat dikurangi menggunakan pemahaman daftar:

x = depset(transitive = [i.deps for i in inputs])

Menggunakan ctx.actions.args() untuk command line

Saat mem-build command line, Anda harus menggunakan ctx.actions.args(). Tindakan ini menunda perluasan depset ke fase eksekusi.

Selain lebih cepat, hal ini akan mengurangi konsumsi memori aturan Anda -- terkadang hingga 90% atau lebih.

Berikut beberapa trik:

Meneruskan depset dan daftar secara langsung sebagai argumen, bukan meratakannya sendiri. Nilai ini akan diperluas oleh ctx.actions.args() untuk Anda. Jika Anda memerlukan transformasi pada konten depset, lihat ctx.actions.args#add untuk melihat apakah ada yang sesuai dengan kebutuhan.
Apakah Anda meneruskan File#path sebagai argumen? Tidak perlu. Semua File otomatis diubah menjadi jalur-nya, bergantung pada waktu perluasan.
Hindari membuat string dengan menggabungkannya. Argumen string terbaik adalah konstanta karena memorinya akan dibagikan di antara semua instance aturan Anda.
Jika argumen terlalu panjang untuk command line, objek ctx.actions.args() dapat ditulis secara bersyarat atau tanpa syarat ke file parameter menggunakan ctx.actions.args#use_param_file. Tindakan ini dilakukan di balik layar saat tindakan dijalankan. Jika perlu mengontrol file params secara eksplisit, Anda dapat menulisnya secara manual menggunakan ctx.actions.write.

Contoh:

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "--foo=<file path>" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # It will however pass ["--foo", <file path>] to the action command line,
  # instead of ["--foo=<file_path>"]
  args.add("--foo", file)

  # Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each="-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

Input tindakan transitif harus depset

Saat membuat tindakan menggunakan ctx.actions.run, jangan lupa bahwa kolom inputs menerima depset. Gunakan ini setiap kali input dikumpulkan dari dependensi secara transitif.

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

Gantung

Jika Bazel tampaknya sedang hang, Anda dapat menekan Ctrl-\ atau mengirim sinyal SIGQUIT (kill -3 $(bazel info server_pid)) kepada Bazel untuk mendapatkan thread dump dalam file $(bazel info output_base)/server/jvm.out.

Karena Anda mungkin tidak dapat menjalankan bazel info jika bazel digantung, direktori output_base biasanya merupakan induk dari symlink bazel-<workspace> di direktori ruang kerja Anda.

Profiling performa

Profil rekaman aktivitas JSON dapat sangat berguna untuk memahami dengan cepat hal yang menghabiskan waktu Bazel selama pemanggilan.

Flag --experimental_command_profile dapat digunakan untuk mengambil berbagai jenis profil Java Flight Recorder (waktu CPU, waktu wall, alokasi memori, dan pertentangan kunci).

Flag --starlark_cpu_profile dapat digunakan untuk menulis profil pprof penggunaan CPU oleh semua thread Starlark.

Profiling memori

Bazel dilengkapi dengan memory profiler bawaan yang dapat membantu Anda memeriksa penggunaan memori aturan. Jika ada masalah, Anda dapat membuang heap untuk menemukan baris kode yang tepat yang menyebabkan masalah.

Mengaktifkan pelacakan memori

Anda harus meneruskan dua tanda startup ini ke setiap panggilan Bazel:

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.0.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

Tindakan ini akan memulai server dalam mode pelacakan memori. Jika Anda lupa untuk satu pemanggilan Bazel, server akan dimulai ulang dan Anda harus memulai dari awal.

Menggunakan Pelacak Memori

Sebagai contoh, lihat target foo dan lihat fungsinya. Untuk menjalankan analisis saja dan tidak menjalankan fase eksekusi build, tambahkan flag --nobuild.

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

Selanjutnya, lihat banyaknya memori yang digunakan oleh seluruh instance Bazel:

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

Pisahkan menurut class aturan menggunakan bazel dump --rules:

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

Lihat tujuan memori dengan menghasilkan file pprof menggunakan bazel dump --skylark_memory:

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

Gunakan alat pprof untuk menyelidiki heap. Titik awal yang baik adalah mendapatkan grafik flame dengan menggunakan pprof -flame $HOME/prof.gz.

Dapatkan pprof dari https://github.com/google/pprof.

Dapatkan dump teks dari situs panggilan terpanas yang dianotasi dengan baris:

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)