नियम लिखते समय, डिपेंडेंसी से इकट्ठा किए गए डेटा को ट्रैवर्स या कॉपी करना, परफ़ॉर्मेंस से जुड़ी सबसे सामान्य गड़बड़ी होती है. पूरे बिल्ड को एक साथ दिखाने पर, ये कार्रवाइयां आसानी से O(N^2) समय या जगह ले सकती हैं. इससे बचने के लिए, यह समझना ज़रूरी है कि डिसेट का असरदार ढंग से इस्तेमाल कैसे किया जाए.
इस बात को सही करना मुश्किल हो सकता है, इसलिए Bazel एक मेमोरी प्रोफ़ाइलर भी देता है, जो आपको ऐसी जगह ढूंढने में मदद करता है जहां शायद आपसे गलती हो. ध्यान रखें: लागू न होने वाले नियम को लिखने की कीमत तब तक साफ़ नहीं दिखती, जब तक उसका बड़े पैमाने पर इस्तेमाल न किया जाए.
डिसेट का इस्तेमाल करें
जब भी आप नियम डिपेंडेंसी से जानकारी रोल अप कर रहे हों, तो आपको depsets का इस्तेमाल करना चाहिए. मौजूदा नियम के हिसाब से जानकारी पब्लिश करने के लिए, सिर्फ़ सामान्य सूचियों या लिखवाने की सुविधा का इस्तेमाल करें.
डिपसेट, जानकारी को नेस्ट किए गए ग्राफ़ के रूप में दिखाता है, जो शेयर करने की सुविधा चालू करता है.
नीचे दिया गया ग्राफ़ देखें:
C -> B -> A
D ---^
हर नोड एक स्ट्रिंग पब्लिश करता है. डिसेट के साथ डेटा ऐसा दिखता है:
a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])
ध्यान दें कि हर आइटम का उल्लेख सिर्फ़ एक बार किया गया है. सूचियों के साथ आपको यह मिलेगा:
a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']
ध्यान दें, इस मामले में 'a'
का उल्लेख चार बार किया गया है! बड़े ग्राफ़ के साथ,
यह समस्या और भी बदतर हो जाएगी.
यहां नियम लागू करने का एक उदाहरण दिया गया है, जो ट्रांज़िटिव जानकारी पब्लिश करने के लिए सही तरीके से डिसेट का इस्तेमाल करता है. ध्यान दें, अगर आप चाहें, तो सूचियों का इस्तेमाल करके नियम-स्थानीय जानकारी को पब्लिश किया जा सकता है, क्योंकि यह O(N^2) नहीं है.
MyProvider = provider()
def _impl(ctx):
my_things = ctx.attr.things
all_things = depset(
direct=my_things,
transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
)
...
return [MyProvider(
my_things=my_things, # OK, a flat list of rule-local things only
all_things=all_things, # OK, a depset containing dependencies
)]
ज़्यादा जानकारी के लिए, डिपसेट की खास जानकारी वाला पेज देखें.
depset.to_list()
को कॉल करने से बचें
to_list()
का इस्तेमाल करके, किसी डिप्सेट को फ़्लैट सूची में रखा जा सकता है. हालांकि, आम तौर पर ऐसा करने से O(N^2) लागत आती है. अगर हो सके, तो डीबग करने के मकसद को छोड़कर, डिप्सेट को बराबर करने से बचें.
एक आम ग़लतफ़हमी यह है कि अगर <xx>_binary
नियम जैसे टॉप लेवल के टारगेट पर ही ऐसा किया जाता है, तो डिप्सेट को आसानी से
फ़्लैट किया जा सकता है. ऐसा करने पर, बिल्ड ग्राफ़ के हर लेवल पर लागत
इकट्ठा नहीं होती. हालांकि, जब ओवरलैप होने वाली डिपेंडेंसी के साथ टारगेट का सेट बनाया जाता है, तब यह अब भी O(N^2) है. ऐसा, टेस्ट //foo/tests/...
बनाते समय या आईडीई प्रोजेक्ट इंपोर्ट करते समय होता है.
कॉल की संख्या घटाकर depset
करें
depset
को लूप में कॉल करना अक्सर गलती से हो जाता है. इससे गहराई तक गहरी घोंसला बना
जा सकता है, जो खराब परफ़ॉर्म करता है. उदाहरण के लिए:
x = depset()
for i in inputs:
# Do not do that.
x = depset(transitive = [x, i.deps])
इस कोड को आसानी से बदला जा सकता है. सबसे पहले, ट्रांज़िटिव डिसेट इकट्ठा करें और उन सभी को एक साथ मर्ज करें:
transitive = []
for i in inputs:
transitive.append(i.deps)
x = depset(transitive = transitive)
सूची समझने की सुविधा का इस्तेमाल करके, इसे कभी-कभी कम किया जा सकता है:
x = depset(transitive = [i.deps for i in inputs])
कमांड लाइन के लिए, ctx.actions.तुलना() का इस्तेमाल करें
कमांड लाइन बनाते समय, आपको ctx.actions.args() का इस्तेमाल करना चाहिए. इससे, किसी भी डिसेट का एक्सपैंशन, एक्ज़ीक्यूशन फ़ेज़ में हो जाता है.
पूरी तरह से तेज़ होने के अलावा, यह आपके नियमों की मेमोरी इस्तेमाल को कम कर देगा -- कभी-कभी 90% या उससे ज़्यादा तक.
यहां कुछ तरकीबें दी गई हैं:
डिसेट और सूचियों को खुद फ़्लैट करने के बजाय, सीधे तर्क के रूप में पास करें. इन्हें
ctx.actions.args()
तक बड़ा कर दिया जाएगा. अगर आपको डिपसेट कॉन्टेंट में कोई बदलाव करने की ज़रूरत है, तो ctx.actions.args#add पर देखें कि ज़रूरत के हिसाब से क्या सही है.क्या
File#path
को आर्ग्युमेंट के तौर पर पास किया जा रहा है? कोई ज़रूरत नहीं. कोई भी फ़ाइल अपने-आप इसके पाथ में बदल जाती है. इसे बड़ा करने के समय को आगे बढ़ाया जाता है.स्ट्रिंग बनाने से बचें. इसके लिए, उन्हें एक साथ जोड़ें. सबसे अच्छा स्ट्रिंग आर्ग्युमेंट एक कॉन्सटेंट होता है, क्योंकि इसकी मेमोरी आपके नियम के सभी इंस्टेंस के बीच शेयर की जाएगी.
अगर कमांड लाइन के लिए तर्क बहुत लंबे हैं, तो
ctx.actions.args()
ऑब्जेक्ट कोctx.actions.args#use_param_file
का इस्तेमाल करके, पैरामीटर फ़ाइल में शर्त के साथ या बिना शर्त के लिखा जा सकता है. यह काम, पर्दे के पीछे किया जाता है. अगर आपको पैरामीटर फ़ाइल को साफ़ तौर पर कंट्रोल करना है, तो इसेctx.actions.write
का इस्तेमाल करके मैन्युअल तरीके से लिखा जा सकता है.
उदाहरण:
def _impl(ctx):
...
args = ctx.actions.args()
file = ctx.declare_file(...)
files = depset(...)
# Bad, constructs a full string "--foo=<file path>" for each rule instance
args.add("--foo=" + file.path)
# Good, shares "--foo" among all rule instances, and defers file.path to later
# It will however pass ["--foo", <file path>] to the action command line,
# instead of ["--foo=<file_path>"]
args.add("--foo", file)
# Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
args.add(format="--foo=%s", value=file)
# Bad, makes a giant string of a whole depset
args.add(" ".join(["-I%s" % file.short_path for file in files])
# Good, only stores a reference to the depset
args.add_all(files, format_each="-I%s", map_each=_to_short_path)
# Function passed to map_each above
def _to_short_path(f):
return f.short_path
ट्रांज़िटिव ऐक्शन के इनपुट डिसेट होने चाहिए
ctx.actions.run का इस्तेमाल करके कोई कार्रवाई बनाते समय, यह न भूलें कि inputs
फ़ील्ड डिपसेट स्वीकार करता है. डिपेंडेंसी से इनपुट इकट्ठा करने पर, इसका इस्तेमाल
तब ही करें.
inputs = depset(...)
ctx.actions.run(
inputs = inputs, # Do *not* turn inputs into a list
...
)
हैंगिंग
अगर बैजल को हैंग किया गया है, तो फ़ाइल $(bazel info output_base)/server/jvm.out
में थ्रेड डंप पाने के लिए, Ctrl-\ दबाएं या Bazel को SIGQUIT
सिग्नल (kill -3 $(bazel info server_pid)
) भेजें.
अगर बैजल हैंग हो गया है, तो हो सकता है कि आप bazel info
न चला पाएं. इसलिए,
output_base
डायरेक्ट्री आम तौर पर आपकी फ़ाइल फ़ोल्डर डायरेक्ट्री में bazel-<workspace>
सिमलिंक की पैरंट होती है.
परफ़ॉर्मेंस की प्रोफ़ाइल बनाना
JSON ट्रेस प्रोफ़ाइल की मदद से तुरंत यह पता लगाया जा सकता है कि बातचीत करने के दौरान, बेज़ेल ने किस चीज़ पर समय बिताया.
--experimental_command_profile
फ़्लैग का इस्तेमाल, Java फ़्लाइट रिकॉर्डर की अलग-अलग तरह की प्रोफ़ाइलों को कैप्चर करने के लिए किया जा सकता है. जैसे, सीपीयू टाइम, वॉल टाइम, मेमोरी का बंटवारा, और लॉक का विवाद.
--starlark_cpu_profile
फ़्लैग का इस्तेमाल सभी Starlark थ्रेड में सीपीयू के इस्तेमाल की एक pprof प्रोफ़ाइल बनाने के लिए किया जा सकता है.
मेमोरी के इस्तेमाल की प्रोफ़ाइल बनाई जा रही है
Bazel के साथ एक मेमोरी प्रोफ़ाइलर पहले से मौजूद होता है. यह आपको यह देखने में मदद करता है कि आपके नियम में मेमोरी का इस्तेमाल हुआ है या नहीं. अगर कोई समस्या होती है, तो हीप को डंप करके कोड की उस लाइन का पता लगाया जा सकता है जिसकी वजह से समस्या हो रही है.
मेमोरी की ट्रैकिंग चालू की जा रही है
आपको हर Bazel को शुरू करने के लिए, इन दो स्टार्टअप फ़्लैग को पास करना होगा:
STARTUP_FLAGS=\
--host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.0.jar> \
--host_jvm_args=-DRULE_MEMORY_TRACKER=1
ये सर्वर को मेमोरी ट्रैकिंग मोड में शुरू करते हैं. अगर आप इन्हें एक भी Bazel के लिए भूल जाते हैं, तो सर्वर रीस्टार्ट हो जाएगा और आपको फिर से शुरू करना होगा.
मेमोरी ट्रैकर का इस्तेमाल करना
उदाहरण के लिए, टारगेट foo
देखें और देखें कि यह क्या करता है. --nobuild
फ़्लैग जोड़ें, ताकि सिर्फ़ विश्लेषण किया जा सके और बिल्ड एक्ज़ीक्यूट करने के चरण को न चलाया जा सके.
$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo
इसके बाद, देखें कि पूरा Bazel इंस्टेंस कितनी मेमोरी का इस्तेमाल करता है:
$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB
bazel dump --rules
का इस्तेमाल करके इसे नियम श्रेणी के अनुसार विभाजित करें:
$ bazel $(STARTUP_FLAGS) dump --rules
>
RULE COUNT ACTIONS BYTES EACH
genrule 33,762 33,801 291,538,824 8,635
config_setting 25,374 0 24,897,336 981
filegroup 25,369 25,369 97,496,272 3,843
cc_library 5,372 73,235 182,214,456 33,919
proto_library 4,140 110,409 186,776,864 45,115
android_library 2,621 36,921 218,504,848 83,366
java_library 2,371 12,459 38,841,000 16,381
_gen_source 719 2,157 9,195,312 12,789
_check_proto_library_deps 719 668 1,835,288 2,552
... (more output)
bazel dump --skylark_memory
का इस्तेमाल करके pprof
फ़ाइल बनाकर देखें कि मेमोरी में क्या चल रहा है:
$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz
हीप की जांच करने के लिए, pprof
टूल का इस्तेमाल करें. शुरुआत करने के लिए, pprof -flame $HOME/prof.gz
का इस्तेमाल करके फ़्लेम ग्राफ़ बनाएं.
https://github.com/google/pprof से pprof
पाएं.
लाइनों के साथ एनोटेट की गई लोकप्रिय कॉल साइटों का टेक्स्ट डंप पाएं:
$ pprof -text -lines $HOME/prof.gz
>
flat flat% sum% cum cum%
146.11MB 19.64% 19.64% 146.11MB 19.64% android_library <native>:-1
113.02MB 15.19% 34.83% 113.02MB 15.19% genrule <native>:-1
74.11MB 9.96% 44.80% 74.11MB 9.96% glob <native>:-1
55.98MB 7.53% 52.32% 55.98MB 7.53% filegroup <native>:-1
53.44MB 7.18% 59.51% 53.44MB 7.18% sh_test <native>:-1
26.55MB 3.57% 63.07% 26.55MB 3.57% _generate_foo_files /foo/tc/tc.bzl:491
26.01MB 3.50% 66.57% 26.01MB 3.50% _build_foo_impl /foo/build_test.bzl:78
22.01MB 2.96% 69.53% 22.01MB 2.96% _build_foo_impl /foo/build_test.bzl:73
... (more output)