假設您需要在建構過程中執行工具,例如,您可以產生或預先處理來源檔案,或壓縮二進位檔。在本教學課程中,您將建立一個會調整圖片大小的巨集。
巨集適合用來執行簡單的工作。如果您想進行更複雜的工作,例如新增對新程式設計語言的支援,請考慮建立規則。規則可讓您擁有更大的掌控權和彈性。
如要建立巨集來調整大小,最簡單的方法是使用 genrule
:
genrule(
name = "logo_miniature",
srcs = ["logo.png"],
outs = ["small_logo.png"],
cmd = "convert $< -resize 100x100 $@",
)
cc_binary(
name = "my_app",
srcs = ["my_app.cc"],
data = [":logo_miniature"],
)
如果您需要調整更多圖片的大小,請重複使用程式碼。為此,請在單獨的 .bzl
檔案中定義函式,然後呼叫 miniature.bzl
檔案:
def miniature(name, src, size="100x100", **kwargs):
"""Create a miniature of the src image.
The generated file is prefixed with 'small_'.
"""
native.genrule(
name = name,
srcs = [src],
outs = ["small_" + src],
cmd = "convert $< -resize " + size + " $@",
**kwargs
)
幾個重點:
根據慣例,巨集含有
name
引數,就像規則一樣。如要記錄巨集的行為,請使用 Python 的 docstring。
如要呼叫
genrule
或任何其他原生規則,請使用native.
。使用
**kwargs
將額外引數轉送至基礎genrule
(運作方式與 Python 相同)。這很實用,因此使用者可以使用visibility
或tags
等標準屬性。
接著,使用 BUILD
檔案中的巨集:
load("//path/to:miniature.bzl", "miniature")
miniature(
name = "logo_miniature",
src = "image.png",
)
cc_binary(
name = "my_app",
srcs = ["my_app.cc"],
data = [":logo_miniature"],
)