การสร้างมาโคร

รายงานปัญหา ดูแหล่งที่มา รุ่น Nightly · 7.4 7.3 · 7.2 · 7.1 · 7.0 · 6.5

สมมติว่าคุณต้องเรียกใช้เครื่องมือเป็นส่วนหนึ่งของการสร้าง เช่น คุณอาจต้องการสร้างหรือประมวลผลไฟล์ต้นฉบับล่วงหน้า หรือบีบอัดไบนารี ในบทแนะนำนี้ คุณจะสร้างมาโครที่ปรับขนาดรูปภาพ

มาโครเหมาะสำหรับงานง่ายๆ หากต้องการทําอะไรที่ซับซ้อนขึ้น เช่น เพิ่มการรองรับภาษาโปรแกรมใหม่ ให้ลองสร้างกฎ กฎช่วยให้คุณควบคุมและมีความยืดหยุ่นมากขึ้น

วิธีที่ง่ายที่สุดในการสร้างมาโครที่ปรับขนาดรูปภาพคือการใช้ genrule

genrule(
    name = "logo_miniature",
    srcs = ["logo.png"],
    outs = ["small_logo.png"],
    cmd = "convert $< -resize 100x100 $@",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)

หากต้องการปรับขนาดรูปภาพเพิ่มเติม คุณอาจต้องนำรหัสดังกล่าวมาใช้ซ้ำ ซึ่งทำได้โดยกำหนดฟังก์ชันในไฟล์ .bzl แยกต่างหากและเรียกไฟล์ miniature.bzl ดังนี้

def miniature(name, src, size="100x100", **kwargs):
  """Create a miniature of the src image.

  The generated file is prefixed with 'small_'.
  """
  native.genrule(
    name = name,
    srcs = [src],
    outs = ["small_" + src],
    cmd = "convert $< -resize " + size + " $@",
    **kwargs
  )

หมายเหตุบางประการมีดังนี้

• ตามปกติแล้ว มาโครมีอาร์กิวเมนต์ name เหมือนกับกฎ

• หากต้องการบันทึกลักษณะการทํางานของมาโคร ให้ใช้ docstring เช่นเดียวกับใน Python

• หากต้องการเรียกใช้ genrule หรือกฎเนทีฟอื่นๆ ให้ใช้ native.

• ใช้ **kwargs เพื่อส่งต่ออาร์กิวเมนต์เพิ่มเติมไปยัง genrule ที่อยู่เบื้องหลัง (ทำงานเหมือนกับใน Python) ซึ่งจะเป็นประโยชน์เพื่อให้ผู้ใช้ใช้แอตทริบิวต์มาตรฐานได้ เช่น visibility หรือ tags

ตอนนี้ให้ใช้มาโครจากไฟล์ BUILD โดยทำดังนี้

load("//path/to:miniature.bzl", "miniature")

miniature(
    name = "logo_miniature",
    src = "image.png",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)