函数

报告问题 查看源代码 每夜 build · 8.0 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

目录

• 软件包
• package_group
• exports_files
• glob
• select
• 子软件包

包裹

package(default_deprecation, default_package_metadata, default_testonly, default_visibility, features)

此函数声明适用于软件包中的每个规则的元数据。在软件包 (BUILD 文件) 中最多使用一次。

对于声明适用于整个代码库中的每个规则的元数据的对应项，请使用代码库根目录下的 REPO.bazel 文件中的 repo() 函数。repo() 函数所采用的参数与 package() 完全相同。

应在文件顶部的所有 load() 语句之后、任何规则之前调用 package() 函数。

参数

属性	说明
default_applicable_licenses	default_package_metadata 的别名。
default_visibility	标签列表；默认值为 [] 此软件包中顶级规则目标和符号宏的默认可见性，即本身未在符号宏中声明的目标和符号宏。如果目标或宏指定了 visibility 值，系统会忽略此属性。 如需详细了解此属性的语法，请参阅 公开范围文档。软件包默认可见性不适用于默认处于公开状态的 exports_files。
default_deprecation	字符串；默认值为 "" 为此软件包中的所有规则设置默认的 deprecation 消息。
default_package_metadata	标签列表；默认值为 [] 设置适用于软件包中所有其他目标的默认元数据目标列表。 这些通常是与 OSS 软件包和许可声明相关的目标。 如需查看示例，请参阅 rules_license。
default_testonly	布尔值；默认值为 False，除非另有说明 为此软件包中的所有规则设置默认的 testonly 属性。 在 javatests 下的软件包中，默认值为 True。
features	列表字符串；默认值为 [] 设置影响此 BUILD 文件语义的各种标志。 此功能主要供构建系统的工作人员使用，用于标记需要某种特殊处理的软件包。除非构建系统的工作人员明确要求，否则请勿使用此选项。

示例

以下声明声明了此软件包中的规则仅对软件包组 //foo:target 的成员可见。规则上的各个公开声明（如果有）会覆盖此规范。

package(default_visibility = ["//foo:target"])

package_group

package_group(name, packages, includes)

此函数定义一组软件包，并将标签与该组相关联。您可以在 visibility 属性中引用该标签。

软件包组主要用于控制可见性。源代码树中的每个软件包都可以引用公开可见的目标。私有可见的目标只能在其自己的软件包（而非子软件包）中引用。在这两种极端情况之间，目标可能会允许访问其自己的软件包以及一个或多个软件包组描述的任何软件包。如需详细了解公开范围系统，请参阅公开范围属性。

如果给定软件包与 packages 属性匹配，或者已包含在 includes 属性中提及的其他软件包组中，则该软件包会被视为属于该组。

从技术层面来看，软件包组是目标，但不是由规则创建的，并且本身没有任何公开范围保护。

参数

属性	说明
name	名称；必需 此目标的唯一名称。
packages	字符串列表；默认值为 [] 零个或多个软件包规范的列表。 每个软件包规范字符串可以采用以下任一形式： 软件包的完整名称（不含代码库），以双斜杠开头。例如，//foo/bar 用于指定具有该名称且与软件包组位于同一代码库中的软件包。 同上，但带有尾随 /...。例如， //foo/... 指定了 //foo 及其所有子软件包的集合。//... 指定当前代码库中的所有软件包。 字符串 public 或 private，分别指定每个软件包或不指定任何软件包。（此表单需要设置标志 --incompatible_package_group_has_public_syntax。） 此外，前两种软件包规范还可以加上 - 前缀，以指明它们是被否定的。 软件包组包含与其至少一个正规格匹配且与其任何负规格都不匹配的任何软件包。例如，值 [//foo/..., -//foo/tests/...] 包含 //foo 的所有子软件包，但不包含 //foo/tests 的子软件包。（//foo 本身包含在内，而 //foo/tests 本身不包含在内。） 除了公开可见性之外，没有任何方法可以直接指定当前代码库之外的软件包。 如果缺少此属性，则等同于将其设置为空列表，这也等同于将其设置为仅包含 private 的列表。 注意：在 Bazel 6.0 之前，规范 //... 的旧版行为与 public 相同。启用 --incompatible_fix_package_group_reporoot_syntax（这是 Bazel 6.0 之后的默认设置）后，此行为会得到修正。 注意：在 Bazel 6.0 之前，如果此属性作为 bazel query --output=proto（或 --output=xml）的一部分进行序列化，则会省略前导斜线。例如，//pkg/foo/... 将输出为 \"pkg/foo/...\"。启用 --incompatible_package_group_includes_double_slash（这是 Bazel 6.0 之后的默认设置）后，此行为会得到修正。
includes	标签列表；默认值为 [] 此软件包组中包含的其他软件包组。 此属性中的标签必须引用其他软件包组。 引用的软件包组中的软件包会被视为此软件包组的一部分。这种关系是传递性的：如果软件包组 a 包含软件包组 b，而 b 包含软件包组 c，则 c 中的每个软件包也将是 a 的成员。 与否定软件包规范搭配使用时，请注意，系统会先独立计算每个组的软件包集，然后将结果联接在一起。这意味着，一个组中的否定规范不会影响另一个组中的规范。

示例

以下 package_group 声明指定了一个名为“tropical”的软件包组，其中包含热带水果。

package_group(
    name = "tropical",
    packages = [
        "//fruits/mango",
        "//fruits/orange",
        "//fruits/papaya/...",
    ],
)

以下声明指定了虚构应用的软件包组：

package_group(
    name = "fooapp",
    includes = [
        ":controller",
        ":model",
        ":view",
    ],
)

package_group(
    name = "model",
    packages = ["//fooapp/database"],
)

package_group(
    name = "view",
    packages = [
        "//fooapp/swingui",
        "//fooapp/webui",
    ],
)

package_group(
    name = "controller",
    packages = ["//fooapp/algorithm"],
)

exports_files

exports_files([label, ...], visibility, licenses)

exports_files() 指定要导出到其他软件包的此软件包所属的文件列表。

软件包的 BUILD 文件只能直接引用属于其他软件包的源文件，前提是这些源文件已通过 exports_files() 语句明确导出。详细了解文件的公开范围。

作为旧版行为，在 --incompatible_no_implicit_file_export 标志被翻转之前，系统还会以默认可见性导出作为规则输入提及的文件。不过，不应依赖此行为，并应积极迁移。

参数

该参数是当前软件包中的文件名称列表。还可以指定可见性声明；在这种情况下，文件将对指定的目标可见。如果未指定可见性，则文件将对每个软件包可见，即使在 package 函数中指定了软件包默认可见性也是如此。您还可以指定许可。

示例

以下示例会从 test_data 软件包中导出 golden.txt（一个文本文件），以便其他软件包可以使用它，例如在测试的 data 属性中使用。

# from //test_data/BUILD

exports_files(["golden.txt"])

glob

glob(include, exclude=[], exclude_directories=1, allow_empty=True)

Glob 是一个辅助函数，用于查找与特定路径模式匹配的所有文件，并返回一个可变的、排序的路径新列表。Glob 仅搜索其自身软件包中的文件，并且只会查找源文件（而非生成的文件或其他目标）。

如果源文件的软件包相对路径与任何 include 模式匹配，但与任何 exclude 模式都不匹配，则结果中会包含该源文件的标签。

include 和 exclude 列表包含相对于当前软件包的路径模式。每个模式都可能由一个或多个路径片段组成。与 Unix 路径一样，这些片段由 / 分隔。系统会将模式中的路径段与路径的路径段进行匹配。路径段可以包含 * 通配符：此通配符可匹配路径段中的任何子字符串（包括空子字符串），但不包括目录分隔符 /。此通配符可以在一个路径段中多次使用。此外，** 通配符可以与零个或多个完整路径段匹配，但必须声明为独立路径段。

示例：

• foo/bar.txt 与此软件包中的 foo/bar.txt 文件完全匹配（除非 foo/ 是子软件包）
• 如果文件以 .txt 结尾，foo/*.txt 会匹配 foo/ 目录中的每个文件（除非 foo/ 是子软件包）
• foo/a*.htm* 匹配 foo/ 目录中以 a 开头、然后包含任意字符串（可以为空）、然后包含 .htm，并以另一个任意字符串结尾的每个文件（除非 foo/ 是子软件包）；例如 foo/axx.htm 和 foo/a.html 或 foo/axxx.html
• foo/* 会与 foo/ 目录中的每个文件匹配（除非 foo/ 是子软件包）；即使 exclude_directories 设为 0，它也不会与 foo 目录本身匹配
• foo/** 会匹配软件包第一级子目录 foo/ 下的每个非子软件包子目录中的每个文件；如果 exclude_directories 设为 0，foo 目录本身也会与该模式匹配；在这种情况下，** 会被视为与零个路径片段匹配
• **/a.txt 会匹配此软件包目录以及非子软件包子目录中的 a.txt 文件。
• 如果生成的路径中的至少一个目录名为 bar（例如 xxx/bar/yyy/zzz/a.txt 或 bar/a.txt；请注意，** 也与零个路径片段匹配），则 **/bar/**/*.txt 会与此软件包的每个非子软件包子目录中的每个 .txt 文件匹配bar/zzz/a.txt
• ** 匹配此软件包的每个非子软件包子目录中的每个文件
• foo**/a.txt 是一个无效的模式，因为 ** 必须作为一个片段独立存在
• foo/ 是一个无效的模式，因为在 / 后面定义的第二个路段为空字符串

如果启用了 exclude_directories 参数（设置为 1），则结果中将省略目录类型的文件（默认值为 1）。

如果 allow_empty 参数设置为 False，则如果结果本来是空列表，glob 函数将出错。

以下是一些重要的限制和注意事项：

1. 由于 glob() 在 BUILD 文件评估期间运行，因此 glob() 仅与源代码树中的文件匹配，绝不会与生成的文件匹配。如果您要构建的目标同时需要源文件和生成的文件，则必须将生成的文件的显式列表附加到正则表达式中。请参阅下面使用 :mylib 和 :gen_java_srcs 的示例。

2. 如果规则的名称与匹配的源文件相同，则该规则将“掩盖”该文件。

   为此，请记住 glob() 会返回路径列表，因此在其他规则的属性（例如 srcs = glob(["*.cc"])）中使用 glob() 与明确列出匹配的路径具有相同的效果。例如，如果 glob() 生成 ["Foo.java", "bar/Baz.java"]，但软件包中还有一个名为“Foo.java”的规则（允许这样，但 Bazel 会发出警告），则 glob() 的使用方将使用“Foo.java”规则（其输出）而非“Foo.java”文件。如需了解详情，请参阅 GitHub 问题 #10395。

3. 通配符可以与子目录中的文件匹配。子目录名称可以使用通配符。不过…

4. 标签不得跨软件包边界，并且通配符不匹配子软件包中的文件。

   例如，如果 x/y 作为软件包（作为 x/y/BUILD 或在软件包路径的其他位置）存在，则软件包 x 中的全局正则表达式 **/*.cc 不包含 x/y/z.cc。这意味着，正则表达式的结果实际上取决于 BUILD 文件的存在性，也就是说，如果不存在名为 x/y 的软件包，或者该软件包已使用 --deleted_packages 标志标记为已删除，则相同的正则表达式将包含 x/y/z.cc。

5. 上述限制适用于所有全局通配表达式，无论它们使用哪种通配符。
6. 文件名以 . 开头的隐藏文件与 ** 和 * 通配符完全匹配。如果您想使用复合模式匹配隐藏文件，则模式需要以 . 开头。例如，* 和 .*.txt 将与 .foo.txt 匹配，但 *.txt 则不会。 系统也会以相同的方式匹配隐藏目录。隐藏目录可能包含不需要用作输入的文件，并且可能会增加不必要的 glob 文件数量和内存用量。如需排除隐藏目录，请将其添加到“exclude”列表参数中。
7. “**”通配符有一个极端情况：模式 "**" 与软件包的目录路径不匹配。也就是说，glob(["**"], exclude_directories = False) 会严格地递归匹配当前软件包目录下的所有文件和目录（但当然不会进入子软件包的目录 - 请参阅上文中的相关说明）。

通常，您应尝试提供适当的扩展名（例如 *.html），而不是使用裸“*”作为全局通配模式。更明确的名称既能自文档化，又能确保您不会意外匹配备份文件或 emacs/vi/... 自动保存文件。

编写 build 规则时，您可以枚举正则表达式的元素。这样，您就可以为每个输入生成单独的规则。请参阅下面的展开的正则表达式示例部分。

Glob 示例

创建一个 Java 库，该库由此目录中的所有 Java 文件以及 :gen_java_srcs 规则生成的所有文件构建而成。

java_library(
    name = "mylib",
    srcs = glob(["*.java"]) + [":gen_java_srcs"],
    deps = "...",
)

genrule(
    name = "gen_java_srcs",
    outs = [
        "Foo.java",
        "Bar.java",
    ],
    ...
)

将目录 testdata 中的所有 txt 文件（experimental.txt 除外）包含在内。 请注意，testdata 的子目录中的文件不会包含在内。如果您想包含这些文件，请使用递归正则表达式 (**)。

sh_test(
    name = "mytest",
    srcs = ["mytest.sh"],
    data = glob(
        ["testdata/*.txt"],
        exclude = ["testdata/experimental.txt"],
    ),
)

递归 glob 示例

使测试依赖于 testdata 目录及其任何子目录（以及其子目录等）中的所有 txt 文件。 系统会忽略包含 BUILD 文件的子目录。（请参阅上文中的限制和注意事项。）

sh_test(
    name = "mytest",
    srcs = ["mytest.sh"],
    data = glob(["testdata/**/*.txt"]),
)

创建一个库，该库由此目录和所有子目录中的所有 Java 文件构建而成，但路径中包含名为 testing 的目录的文件除外。应尽可能避免这种模式，因为它可能会降低构建增量，从而增加构建时间。

java_library(
    name = "mylib",
    srcs = glob(
        ["**/*.java"],
        exclude = ["**/testing/**"],
    ),
)

展开的 Glob 示例

在当前目录中为 *_test.cc 创建一个单独的 genrule，用于统计文件中的行数。

# Conveniently, the build language supports list comprehensions.
[genrule(
    name = "count_lines_" + f[:-3],  # strip ".cc"
    srcs = [f],
    outs = ["%s-linecount.txt" % f[:-3]],
    cmd = "wc -l $< >$@",
 ) for f in glob(["*_test.cc"])]

如果上述 BUILD 文件位于软件包 //foo 中，并且该软件包包含三个匹配的文件（a_test.cc、b_test.cc 和 c_test.cc），那么运行 bazel query '//foo:all' 将列出生成的所有规则：

$ bazel query '//foo:all' | sort
//foo:count_lines_a_test
//foo:count_lines_b_test
//foo:count_lines_c_test

选择

select(
    {conditionA: valuesA, conditionB: valuesB, ...},
    no_match_error = "custom message"
)

select() 是一个辅助函数，用于使规则属性可配置。它可以替换几乎所有属性赋值的右侧，因此其值取决于命令行 Bazel 标志。例如，您可以使用此方法定义平台专用依赖项，或根据规则是在“开发者”模式还是“发布”模式下构建来嵌入不同的资源。

基本用法如下：

sh_binary(
    name = "mytarget",
    srcs = select({
        ":conditionA": ["mytarget_a.sh"],
        ":conditionB": ["mytarget_b.sh"],
        "//conditions:default": ["mytarget_default.sh"]
    })
)

这样，通过将 sh_binary 的正常标签列表赋值替换为将配置条件映射到匹配值的 select 调用，即可使 sh_binary 的 srcs 属性可配置。每个条件都是对 config_setting 或 constraint_value 的标签引用，如果目标的配置与预期的一组值匹配，则为“匹配”。然后，mytarget#srcs 的值将变为与当前调用匹配的标签列表。

注意：

• 在任何调用中，系统只会选择一个条件。
• 如果多个条件匹配，并且其中一个是其他条件的专精领域，则专精领域优先。如果条件 B 与条件 A 具有完全相同的标志和约束条件值，以及一些额外的标志或约束条件值，则条件 B 被视为条件 A 的特殊化。这也意味着，专精解析并非旨在创建排序，如以下示例 2 所示。
• 如果多个条件匹配，并且其中一个条件不是所有其他条件的特殊化，则 Bazel 会失败并显示错误，除非所有条件都解析为相同的值。
• 如果没有其他条件匹配，系统会将特殊的伪标签 //conditions:default 视为匹配。如果省略此条件，则必须匹配某些其他规则，以免出现错误。
• select 可以嵌入到更大的属性赋值中。因此，srcs = ["common.sh"] + select({ ":conditionA": ["myrule_a.sh"], ...}) 和 srcs = select({ ":conditionA": ["a.sh"]}) + select({ ":conditionB": ["b.sh"]}) 是有效的表达式。
• select 适用于大多数（但不是全部）属性。不兼容的属性在文档中会标记为 nonconfigurable。

  子软件包

  subpackages(include, exclude=[], allow_empty=True)

  subpackages() 是一个辅助函数，类似于 glob()，用于列出子软件包（而非文件和目录）。它使用与 glob() 相同的路径模式，并且可以与当前正在加载的 BUILD 文件的直接子孙级子软件包匹配。如需详细了解包含和排除模式以及相关示例，请参阅 glob。

  返回的子软件包列表按排序顺序排列，其中包含与 include 中的给定模式（而非 exclude 中的模式）匹配的相对当前加载软件包的路径。

  示例

  以下示例列出了软件包 foo/BUILD 的所有直接子软件包

  # The following BUILD files exist:
  # foo/BUILD
  # foo/bar/baz/BUILD
  # foo/bar/but/bad/BUILD
  # foo/sub/BUILD
  # foo/sub/deeper/BUILD
  #
  # In foo/BUILD a call to
  subs1 = subpackages(include = ["**"])
  
  # results in subs1 == ["sub", "bar/baz", "bar/but/bad"]
  #
  # 'sub/deeper' is not included because it is a subpackage of 'foo/sub' not of
  # 'foo'
  
  subs2 = subpackages(include = ["bar/*"])
  # results in subs2 = ["bar/baz"]
  #
  # Since 'bar' is not a subpackage itself, this looks for any subpackages under
  # all first level subdirectories of 'bar'.
  
  subs3 = subpackages(include = ["bar/**"])
  # results in subs3 = ["bar/baz", "bar/but/bad"]
  #
  # Since bar is not a subpackage itself, this looks for any subpackages which are
  # (1) under all subdirectories of 'bar' which can be at any level, (2) not a
  # subpackage of another subpackages.
  
  subs4 = subpackages(include = ["sub"])
  subs5 = subpackages(include = ["sub/*"])
  subs6 = subpackages(include = ["sub/**"])
  # results in subs4 and subs6 being ["sub"]
  # results in subs5 = [].
  #
  # In subs4, expression "sub" checks whether 'foo/sub' is a package (i.e. is a
  # subpackage of 'foo').
  # In subs5, "sub/*" looks for subpackages under directory 'foo/sub'. Since
  # 'foo/sub' is already a subpackage itself, the subdirectories will not be
  # traversed anymore.
  # In subs6, 'foo/sub' is a subpackage itself and matches pattern "sub/**", so it
  # is returned. But the subdirectories of 'foo/sub' will not be traversed
  # anymore.
  

  一般来说，用户最好使用 skylib 的“subpackages”模块，而不是直接调用此函数。