Macros heredadas

Informar un problema Ver fuente Nightly · 8.0 . 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

Las macros heredadas son funciones no estructuradas que se llaman desde archivos BUILD que pueden crear destinos. Al final de la fase de carga, las macros heredadas ya no existen, y Bazel solo ve el conjunto concreto de reglas con instancias.

Por qué no debes usar macros heredadas (y por qué debes usar macros simbólicas)

Siempre que sea posible, debes usar macros simbólicas.

Macros simbólicas

Evita acciones a distancia
Permite ocultar los detalles de la implementación a través de una visibilidad detallada
Toma los atributos escritos, lo que, a su vez, significa etiqueta automática y selecciona la conversión.
Son más legibles.
Pronto tendrá evaluación diferida.

Uso

El caso de uso típico de una macro es cuando quieres volver a usar una regla.

Por ejemplo, genrule en un archivo BUILD genera un archivo con //:generator con un argumento some_arg codificado en el comando:

genrule(
    name = "file",
    outs = ["file.txt"],
    cmd = "$(location //:generator) some_arg > $@",
    tools = ["//:generator"],
)

Si deseas generar más archivos con diferentes argumentos, te recomendamos que extraigas este código a una función de macro. Para crear una macro llamada file_generator, que tiene parámetros name y arg, podemos reemplazar genrule por lo siguiente:

load("//path:generator.bzl", "file_generator")

file_generator(
    name = "file",
    arg = "some_arg",
)

file_generator(
    name = "file-two",
    arg = "some_arg_two",
)

file_generator(
    name = "file-three",
    arg = "some_arg_three",
)

Aquí, cargas el símbolo file_generator desde un archivo .bzl ubicado en el paquete //path. Si colocas las definiciones de funciones de macro en un archivo .bzl independiente, mantienes tus archivos BUILD limpios y declarativos. El archivo .bzl se puede cargar desde cualquier paquete del espacio de trabajo.

Por último, en path/generator.bzl, escribe la definición de la macro para encapsular y parametrizar la definición original de genrule:

def file_generator(name, arg, visibility=None):
  native.genrule(
    name = name,
    outs = [name + ".txt"],
    cmd = "$(location //:generator) %s > $@" % arg,
    tools = ["//:generator"],
    visibility = visibility,
  )

También puedes usar macros para encadenar reglas. En este ejemplo, se muestran genrules encadenadas, en las que una genrule usa los resultados de una genrule anterior como entradas:

def chained_genrules(name, visibility=None):
  native.genrule(
    name = name + "-one",
    outs = [name + ".one"],
    cmd = "$(location :tool-one) $@",
    tools = [":tool-one"],
    visibility = ["//visibility:private"],
  )

  native.genrule(
    name = name + "-two",
    srcs = [name + ".one"],
    outs = [name + ".two"],
    cmd = "$(location :tool-two) $< $@",
    tools = [":tool-two"],
    visibility = visibility,
  )

En el ejemplo, solo se asigna un valor de visibilidad a la segunda genrule. Esto permite que los autores de macros oculten los resultados de las reglas intermedias para que otros destinos del espacio de trabajo no dependan de ellos.

Cómo expandir macros

Cuando quieras investigar qué hace una macro, usa el comando query con --output=build para ver el formato expandido:

$ bazel query --output=build :file
# /absolute/path/test/ext.bzl:42:3
genrule(
  name = "file",
  tools = ["//:generator"],
  outs = ["//test:file.txt"],
  cmd = "$(location //:generator) some_arg > $@",
)

Cómo crear instancias de reglas nativas

Las reglas nativas (reglas que no necesitan una sentencia load()) se pueden crear instancias desde el módulo native:

def my_macro(name, visibility=None):
  native.cc_library(
    name = name,
    srcs = ["main.cc"],
    visibility = visibility,
  )

Si necesitas conocer el nombre del paquete (por ejemplo, qué archivo BUILD llama a la macro), usa la función native.package_name(). Ten en cuenta que native solo se puede usar en archivos .bzl, no en archivos BUILD.

Resolución de etiquetas en macros

Dado que las macros heredadas se evalúan en la fase de carga, las cadenas de etiquetas como "//foo:bar" que se producen en una macro heredada se interpretan en relación con el archivo BUILD en el que se usa la macro, en lugar de hacerlo en relación con el archivo .bzl en el que se define. Por lo general, este comportamiento no es deseable para las macros que se usan en otros repositorios, por ejemplo, porque forman parte de un conjunto de reglas de Starlark publicado.

Para obtener el mismo comportamiento que en las reglas de Starlark, une las cadenas de etiquetas con el constructor Label:

# @my_ruleset//rules:defs.bzl
def my_cc_wrapper(name, deps = [], **kwargs):
  native.cc_library(
    name = name,
    deps = deps + select({
      # Due to the use of Label, this label is resolved within @my_ruleset,
      # regardless of its site of use.
      Label("//config:needs_foo"): [
        # Due to the use of Label, this label will resolve to the correct target
        # even if the canonical name of @dep_of_my_ruleset should be different
        # in the main repo, such as due to repo mappings.
        Label("@dep_of_my_ruleset//tools:foo"),
      ],
      "//conditions:default": [],
    }),
    **kwargs,
  )

Depuración

bazel query --output=build //my/path:all te mostrará cómo se ve el archivo BUILD después de la evaluación. Se expanden todas las macros, globs y bucles heredados. Limitación conocida: Las expresiones select no se muestran en el resultado.
Puedes filtrar el resultado según generator_function (qué función generó las reglas) o generator_name (el atributo de nombre de la macro):bash $ bazel query --output=build 'attr(generator_function, my_macro, //my/path:all)'
Para saber dónde se genera exactamente la regla foo en un archivo BUILD, puedes probar el siguiente truco. Inserta esta línea cerca de la parte superior del archivo BUILD: cc_library(name = "foo"). Ejecuta Bazel. Recibirás una excepción cuando se cree la regla foo (debido a un conflicto de nombres), que te mostrará el seguimiento de pila completo.
También puedes usar print para depurar. Muestra el mensaje como una línea de registro DEBUG durante la fase de carga. Excepto en casos excepcionales, quita las llamadas a print o haz que sean condicionales con un parámetro debugging que se establezca de forma predeterminada en False antes de enviar el código al depósito.

Errores

Si quieres generar un error, usa la función fail. Explícale al usuario de forma clara qué salió mal y cómo corregir su archivo BUILD. No es posible detectar un error.

def my_macro(name, deps, visibility=None):
  if len(deps) < 2:
    fail("Expected at least two values in deps")
  # ...

Convenciones

Todas las funciones públicas (funciones que no comienzan con un guion bajo) que crean instancias de reglas deben tener un argumento name. Este argumento no debe ser opcional (no proporciones un valor predeterminado).
Las funciones públicas deben usar una docstring que siga las convenciones de Python.
En los archivos BUILD, el argumento name de las macros debe ser un argumento de palabra clave (no un argumento posicional).
El atributo name de las reglas que genera una macro debe incluir el argumento de nombre como prefijo. Por ejemplo, macro(name = "foo") puede generar un foo cc_library y un foo_gen genrule.
En la mayoría de los casos, los parámetros opcionales deben tener un valor predeterminado de None. None se puede pasar directamente a las reglas nativas, que lo tratan de la misma manera que si no hubieras pasado ningún argumento. Por lo tanto, no es necesario reemplazarlo por 0, False o [] para este fin. En su lugar, la macro debe aplazarse a las reglas que crea, ya que sus valores predeterminados pueden ser complejos o pueden cambiar con el tiempo. Además, un parámetro que se establece explícitamente en su valor predeterminado se ve diferente de uno que nunca se establece (o se establece en None) cuando se accede a él a través del lenguaje de consulta o las funciones internas del sistema de compilación.
Las macros deben tener un argumento visibility opcional.