将 Android 原生开发套件与 Bazel 搭配使用

报告问题 查看源代码 每夜 build · 8.0 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

如果您刚开始接触 Bazel，请先参阅使用 Bazel 构建 Android 教程。

概览

Bazel 可以在许多不同的构建配置中运行，包括使用 Android 原生开发套件 (NDK) 工具链的几种配置。这意味着，您可以直接在 Bazel 中为 Android 编译常规的 cc_library 和 cc_binary 规则。Bazel 使用 android_ndk_repository 仓库规则来实现此目的。

前提条件

请确保您已安装 Android SDK 和 NDK。

如需设置 SDK 和 NDK，请将以下代码段添加到 WORKSPACE：

android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

如需详细了解 android_ndk_repository 规则，请参阅build 百科全书条目。

如果您使用的是较新版本的 Android NDK（r22 及更高版本），请使用 android_ndk_repository 的 Starlark 实现。请按照其自述文件中的说明操作。

快速入门

如需构建适用于 Android 的 C++ 代码，只需将 cc_library 依赖项添加到 android_binary 或 android_library 规则即可。

例如，假设某个 Android 应用具有以下 BUILD 文件：

# In <project>/app/src/main/BUILD.bazel

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

此 BUILD 文件会生成以下目标图：

示例结果

图 1. 包含 cc_library 依赖项的 Android 项目的 build 图。

如需构建应用，只需运行以下命令即可：

bazel build //app/src/main:app

bazel build 命令会编译 Java 文件、Android 资源文件和 cc_library 规则，并将所有内容打包到 APK 中：

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel 会将所有 cc_library 编译到单个共享对象 (.so) 文件中，默认以 armeabi-v7a ABI 为目标平台。如需更改此设置或同时针对多个 ABI 进行构建，请参阅配置目标 ABI 部分。

示例设置

此示例可在 Bazel 示例代码库中找到。

在 BUILD.bazel 文件中，使用 android_binary、android_library 和 cc_library 规则定义了三个目标。

android_binary 顶级目标会构建 APK。

cc_library 目标包含一个包含 JNI 函数实现的 C++ 源文件：

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

android_library 目标指定 Java 源代码、资源文件以及对 cc_library 目标的依赖项。在此示例中，MainActivity.java 会加载共享对象文件 libapp.so，并定义 JNI 函数的方法签名：

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

配置目标 ABI

如需配置目标 ABI，请使用 --android_platforms 标志，如下所示：

bazel build //:app --android_platforms=comma-separated list of platforms

与 --platforms 标志一样，传递给 --android_platforms 的值是 platform 目标的标签，使用标准约束条件值来描述您的设备。

例如，对于搭载 64 位 ARM 处理器的 Android 设备，您可以按如下方式定义平台：

platform(
    name = "android_arm64",
    constraint_values = [
        "@platforms//os:android",
        "@platforms//cpu:arm64",
    ],
)

每个 Android platform 都应使用 @platforms//os:android 操作系统约束条件。如需迁移 CPU 限制，请查看此图表：

CPU 值 平台
armeabi-v7a @platforms//cpu:armv7
arm64-v8a @platforms//cpu:arm64
x86 @platforms//cpu:x86_32
x86_64 @platforms//cpu:x86_64

当然，对于多架构 APK，您可以传递多个标签，例如 --android_platforms=//:arm64,//:x86_64（假设您已在顶级 BUILD.bazel 文件中定义了这些标签）。

Bazel 无法选择默认 Android 平台，因此必须使用 --android_platforms 定义并指定一个默认平台。

可用的 ABI 取决于 NDK 修订版和 Android API 级别：

NDK 修订版 ABI
16 及更低 armeabi、armeabi-v7a、arm64-v8a、mips、mips64、x86、x86_64
17 周岁及以上 armeabi-v7a、arm64-v8a、x86、x86_64

如需详细了解这些 ABI，请参阅 NDK 文档。

不建议将多 ABI 胖 APK 用于发布 build，因为它们会增加 APK 的大小，但对于开发 build 和质量检查 build 而言，它们可能很有用。

选择 C++ 标准

使用以下标志可根据 C++ 标准进行构建：

C++ 标准 标志
C++98 默认，无需标志
C++11 --cxxopt=-std=c++11
C++14 --cxxopt=-std=c++14
C++17 --cxxopt=-std=c++17

例如：

bazel build //:app --cxxopt=-std=c++11

如需详细了解如何使用 --cxxopt、--copt 和 --linkopt 传递编译器和链接器标志，请参阅用户手册。

您还可以使用 copts 和 linkopts 在 cc_library 中将编译器和链接器标志指定为属性。例如：

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

在不使用 android_binary 的情况下为 Android 构建 cc_library

如需在不使用 android_binary 的情况下为 Android 构建独立的 cc_binary 或 cc_library，请使用 --platforms 标志。

例如，假设您在 my/platforms/BUILD 中定义了 Android 平台：

bazel build //my/cc/jni:target \
      --platforms=//my/platforms:x86_64

采用这种方法时，整个 build 树都会受到影响。

这些标志可放入 project/.bazelrc 中的 bazelrc 配置（每个 ABI 一个）中：

common:android_x86 --platforms=//my/platforms:x86

common:android_armeabi-v7a --platforms=//my/platforms:armeabi-v7a

# In general
common:android_<abi> --platforms=//my/platforms:<abi>

然后，如需为 x86 构建 cc_library，请运行以下命令：

bazel build //my/cc/jni:target --config=android_x86

通常，对于低级目标（例如 cc_library）或您确切知道要构建的内容时，请使用此方法；对于您预计要构建许多不受控制的目标的高级目标，请依赖 android_binary 中的自动配置转换。