BazelCon 2024 註冊現已開放！

本頁面由 Cloud Translation API 翻譯而成。

最佳化效能

回報問題查看原始碼 Nightly · 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

編寫規則時，最常見的效能問題是周遊或複製所累積的資料如果從整個資料中匯總資料建構，這些作業可以輕鬆採用 O(N^2) 時間或空間。為避免這種情況，請務必瞭解如何有效使用 depset。

這可能很難正確處理，因此 Bazel 也提供了記憶體分析器幫助您找到可能出錯的地方警告：要寫出效率低落的規則成本，可能要等到以及應用層面

使用解碼器

每當您從應該使用的規則依附性取得資訊時 depsets。請只使用純文字清單或字典，在目前規則的本機發布資訊。

depset 會以巢狀圖表的形式呈現資訊，方便分享。

請參考下列圖表：

C -> B -> A
D ---^

每個節點都會發布一個字串。使用 depset 後，資料會如下所示：

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

請注意，每個項目只會出現一次。建立清單的好處如下：

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

請注意，在本例中 'a' 被提及了四次！大型圖表問題只會越來越嚴重

以下舉例說明規則實作的正確用法以及發布遞移資訊請注意，您可以發布規則-本機資訊，因為這不是 O(N^2)。

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

詳情請參閱 depset 總覽頁面。

避免撥打 `depset.to_list()`

您可以使用 to_list()，但這麼做通常會產生 O(N^2) 這項功能會將不常存取的資料移至「較冷」的儲存空間級別來減少費用請盡可能避免除偵錯之外的任何依附元件分割用途。

常見的誤解是，如果只用到，就能自由壓平依附元件頂層目標，例如 <xx>_binary 規則，因為這樣就不必每個等級的累計值不過，當您建構一組具有重疊依附元件的目標時，這仍是 O(N^2)。這會發生在建構測試 //foo/tests/... 或匯入 IDE 專案時。

減少對 `depset` 的呼叫次數

在迴圈中呼叫 depset 通常是錯誤。這可能會導致巢狀結構非常深的 depset，導致效能不佳。例如：

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

這個程式碼可以輕鬆替換。首先，收集遞移依附元件一次合併所有內容：

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

有時可以使用清單函式來減少這類運算：

x = depset(transitive = [i.deps for i in inputs])

針對指令列使用 ctx.actions.args()

建構指令列時，應使用 ctx.actions.args()。這會將任何偏移值延後到執行階段。

除了速度明顯提升之外，這項做法還能減少規則的記憶體用量，有時甚至可減少 90% 以上。

以下提供一些訣竅：

請直接將 depset 和清單做為引數傳遞，不要自行展開。系統會為你延長 ctx.actions.args()。如果您需要對解碼器內容進行任何轉換，請參閱 ctx.actions.args#add 查看是否有任何項目符合帳單。
您要傳遞 File#path 做為引數嗎？不需要。任何檔案都會自動轉換為路徑，並延後至擴充時間。
請勿透過連接字串來建構字串。最佳字串引數是常數，因為這個引數會在所有例項都一樣
如果 args 太長，指令列無法處理，您可以使用 ctx.actions.args#use_param_file 將 ctx.actions.args() 物件有條件或無條件地寫入參數檔案。這項作業會在執行動作時在幕後完成。如果您需要明確控制參數檔案，可以使用 ctx.actions.write 手動編寫。

範例：

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "--foo=<file path>" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # It will however pass ["--foo", <file path>] to the action command line,
  # instead of ["--foo=<file_path>"]
  args.add("--foo", file)

  # Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each="-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

遞移動作輸入內容應為解碼器

使用 ctx.actions.run 建構動作時，請注意 inputs 欄位會接受 depset。只要從依附元件收集輸入內容，就請使用這個方法。

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

懸掛式

如果 Bazel 顯示為無回應，即可按下 Ctrl-\ 鍵或傳送 Bazel 會傳送 SIGQUIT 信號 (kill -3 $(bazel info server_pid))，以取得執行緒轉儲 $(bazel info output_base)/server/jvm.out 檔案中的傾印

由於 bazel 停止運作，您可能無法執行 bazel info， output_base 目錄通常是 bazel-<workspace> 的父項。

效能分析

JSON 追蹤設定檔有助於快速瞭解 Bazel 在叫用期間花費的時間。

記憶體分析

Bazel 內建記憶體分析器，可協助您檢查規則的記憶體用量。如果發生問題，您可以傾印記憶體快照來找出造成問題的確切程式碼行。

啟用記憶體追蹤

您必須將這兩個啟動標記傳送到「每個」Bazel 叫用：

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.0.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

這些指令會以記憶體追蹤模式啟動伺服器。萬一你忘記這些伺服器就會重新啟動一次 Bazel 叫用，這時必須重新開始。

使用記憶體追蹤程式

舉例來說，請查看目標 foo 並瞭解其功用。如要只執行分析，而不執行建構執行階段，請新增 --nobuild 標記。

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

接著，查看整個 Bazel 例項的記憶體用量：

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

使用 bazel dump --rules 依規則類別細分：

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

使用 bazel dump --skylark_memory 產生 pprof 檔案，查看記憶體的去向：

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

使用 pprof 工具調查堆積。建議您一開始使用 pprof -flame $HOME/prof.gz 取得火焰圖。

從 https://github.com/google/pprof 取得 pprof。

取得熱門通話網站的文字傾印檔，並加上下列幾行註解：

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)