概要
適切なオプションでコンパイラを呼び出すには、Bazel がコンパイラの内部（インクルード ディレクトリや重要なフラグなど）に関する知識を必要とします。つまり、Bazel はコンパイラの動作を理解するために、コンパイラの簡素化されたモデルを必要とします。
Bazel は次の情報を把握する必要があります。
- コンパイラが thinLTO、モジュール、動的リンク、PIC（位置独立コード）をサポートしているかどうか。
- 必要なツール（gcc、ld、ar、objcopy など）のパス。
- 組み込みのシステム インクルード ディレクトリ。Bazel は、ソースファイルに含まれているすべてのヘッダーが
BUILDファイルで正しく宣言されていることを検証するために、これらを必要とします。 - デフォルトの sysroot。
- コンパイル、リンク、アーカイブに使用するフラグ。
- サポートされているコンパイル モード（opt、dbg、fastbuild）に使用するフラグ。
- コンパイラで特に必要な変数を作成します。
コンパイラが複数のアーキテクチャをサポートしている場合は、Bazel でそれらを個別に構成する必要があります。
CcToolchainConfigInfo は、Bazel の C++ ルールの動作を構成するために必要なレベルの粒度を提供するプロバイダです。デフォルトでは、Bazel はビルドの CcToolchainConfigInfo を自動的に構成しますが、手動で構成することもできます。そのためには、CcToolchainConfigInfo を提供する Starlark ルールが必要で、cc_toolchain の toolchain_config 属性をルールに指す必要があります。CcToolchainConfigInfo は cc_common.create_cc_toolchain_config_info() を呼び出して作成できます。このプロセスで必要となるすべての構造体の Starlark コンストラクタは、@rules_cc//cc:cc_toolchain_config_lib.bzl にあります。
C++ ターゲットが分析フェーズに入ると、Bazel は BUILD ファイルに基づいて適切な cc_toolchain ターゲを選択し、cc_toolchain.toolchain_config 属性で指定されたターゲットから CcToolchainConfigInfo プロバイダを取得します。cc_toolchain ターゲットは、この情報を CcToolchainProvider を介して C++ ターゲットに渡します。
たとえば、cc_binary や cc_library などのルールによってインスタンス化されるコンパイル アクションやリンク アクションには、次の情報が必要です。
- 使用するコンパイラまたはリンカー
- コンパイラ/リンカーのコマンドライン フラグ
--copt/--linkoptオプションを介して渡される構成フラグ- 環境変数
- アクションが実行されるサンドボックスで必要なアーティファクト
サンドボックスで必要なアーティファクトを除く上記のすべての情報は、cc_toolchain が参照する Starlark ターゲットで指定されます。
サンドボックスに送信されるアーティファクトは、cc_toolchain ターゲットで宣言されます。たとえば、cc_toolchain.linker_files 属性を使用して、サンドボックスに送信するリンカー バイナリとツールチェーン ライブラリを指定できます。
ツールチェーンの選択
ツールチェーンの選択ロジックは次のように動作します。
ユーザーは
BUILDファイルでcc_toolchain_suiteターゲットを指定し、--crosstool_topオプションを使用して Bazel をターゲットに指します。cc_toolchain_suiteターゲットは複数のツールチェーンを参照します。--cpuフラグと--compilerフラグの値によって、--cpuフラグの値のみに基づいて、または結合--cpu | --compiler値に基づいて、どのツールチェーンが選択されるかが決まります。選定プロセスは次のとおりです。--compilerオプションが指定されている場合、Bazel は--cpu | --compilerを使用してcc_toolchain_suite.toolchains属性から対応するエントリを選択します。Bazel が対応するエントリを見つけられない場合は、エラーがスローされます。--compilerオプションが指定されていない場合、Bazel は--cpuのみを使用してcc_toolchain_suite.toolchains属性から対応するエントリを選択します。フラグが指定されていない場合、Bazel はホストシステムを検査し、検出結果に基づいて
--cpu値を選択します。検査メカニズムのコードをご覧ください。
ツールチェーンを選択すると、Starlark ルール内の対応する feature オブジェクトと action_config オブジェクトがビルドの構成（後述の項目）を管理します。これらのメッセージを使用すると、Bazel バイナリを変更せずに、Bazel で完全な C++ 機能を実装できます。C++ ルールは、Bazel ソースコードで詳細に説明されている複数の一意のアクションをサポートしています。
機能
機能とは、コマンドライン フラグ、アクション、実行環境の制約、依存関係の変更を必要とするエンティティです。機能は、BUILD ファイルが treat_warnings_as_errors などのフラグの構成を選択できるようにする、C++ ルールを操作して、header_modules や thin_lto などの新しいコンパイル アクションと入力をコンパイルに含めるなど、単純なものにできます。
理想的には、CcToolchainConfigInfo に機能のリストが含まれています。各機能は 1 つ以上のフラググループで構成され、各グループは特定の Bazel アクションに適用されるフラグのリストを定義します。
機能は名前で指定されるため、Starlark ルール構成と Bazel リリースを完全に分離できます。つまり、新しい機能の使用を必要としない限り、Bazel のリリースは CcToolchainConfigInfo 構成の動作に影響しません。
機能は次のいずれかの方法で有効にします。
- 特徴の
enabledフィールドがtrueに設定されている。 - Bazel またはルールのオーナーが明示的に有効にします。
- ユーザーは、
--featureBazel オプションまたはfeaturesルール属性で有効にします。
機能には相互依存関係があり、コマンドライン フラグ、BUILD ファイル設定、その他の変数に依存する場合があります。
特徴の関係
通常、依存関係は Bazel で直接管理されます。Bazel は、要件を適用し、ビルドで定義された機能の性質に固有の競合を管理します。ツールチェーン仕様では、機能のサポートと拡張を管理する Starlark ルール内で直接使用できる、よりきめ細かい制約を指定できます。具体的には、次のとおりです。
| 制約 | 説明 |
requires = [
feature_set (features = [
'feature-name-1',
'feature-name-2'
]),
] |
対象物レベル。この機能は、指定された必須機能が有効になっている場合にのみサポートされます。たとえば、特定のビルドモード（opt、dbg、fastbuild）でのみ機能がサポートされている場合です。requires に複数の feature_set が含まれている場合、feature_set のいずれかが満たされている場合（指定されたすべての機能が有効になっている場合）に、機能がサポートされます。 |
implies = ['feature'] |
対象物レベル。この機能は、指定された機能を意味します。1 つの機能を有効にすると、その機能に暗黙的に含まれるすべての機能も有効になります（つまり、再帰的に機能します）。 また、サニタイザの共通部分など、一連の機能から機能の共通サブセットを分離する機能も提供します。暗黙的な機能は無効にできません。 |
provides = ['feature'] |
対象物レベル。この機能が、互いに排他的な複数の代替機能の 1 つであることを示します。たとえば、すべてのサニタライザーで これにより、ユーザーが相互に排他的な機能を 2 つ以上同時にリクエストした場合に、代替手段を一覧表示することで、エラー処理が改善されます。 |
with_features = [
with_feature_set(
features = ['feature-1'],
not_features = ['feature-2'],
),
] |
フラグセットレベル。1 つの特徴で複数のフラグセットを指定できます。with_features が指定されている場合、フラグセットがビルドコマンドに展開されるのは、指定された features セット内のすべての機能が有効で、not_features セットで指定されたすべての機能が無効になっている with_feature_set が 1 つ以上ある場合のみです。with_features が指定されていない場合、フラグセットは指定されたすべてのアクションに無条件で適用されます。 |
操作
アクションを使用すると、アクションの実行方法を想定することなく、アクションの実行条件を柔軟に変更できます。action_config は、アクションが呼び出すツール バイナリを指定します。一方、feature は、アクションが呼び出されたときにそのツールの動作を決定する構成（フラグ）を指定します。
機能はアクションを参照して、影響を受ける Bazel アクションを通知します。これは、アクションが Bazel アクショングラフを変更できるためです。CcToolchainConfigInfo プロバイダには、c++-compile など、フラグとツールが関連付けられているアクションが含まれています。フラグは、特徴に関連付けることで各アクションに割り当てられます。
各アクション名は、コンパイルやリンクなど、Bazel が実行する単一のアクション タイプを表します。ただし、アクションと Bazel アクション タイプの間には多対一の関係があります。Bazel アクション タイプは、アクションを実装する Java クラス（CppCompileAction など）を指します。特に、下の表の「アセンブラ アクション」と「コンパイラ アクション」は CppCompileAction ですが、リンク アクションは CppLinkAction です。
アセンブラのアクション
| 操作 | 説明 |
preprocess-assemble
|
前処理でアセンブルします。通常は .S ファイルに使用します。 |
assemble
|
前処理なしでアセンブルします。通常は .s ファイルに使用します。 |
コンパイラ アクション
| 操作 | 説明 |
cc-flags-make-variable
|
CC_FLAGS を genrules に伝播します。 |
c-compile
|
C としてコンパイルします。 |
c++-compile
|
C++ としてコンパイルします。 |
c++-header-parsing
|
ヘッダー ファイルでコンパイラのパラサーを実行して、ヘッダーが自己完結していることを確認します。そうしないと、コンパイル エラーが発生します。モジュールをサポートするツールチェーンにのみ適用されます。 |
リンクの操作
| 操作 | 説明 |
c++-link-dynamic-library
|
すべての依存関係を含む共有ライブラリをリンクします。 |
c++-link-nodeps-dynamic-library
|
cc_library ソースのみを含む共有ライブラリをリンクします。 |
c++-link-executable
|
最終的な実行可能なライブラリをリンクします。 |
AR アクション
AR アクションは、ar を介してオブジェクト ファイルをアーカイブ ライブラリ（.a ファイル）にアセンブルし、一部のセマンティクスを名前にエンコードします。
| 操作 | 説明 |
c++-link-static-library
|
静的ライブラリ（アーカイブ）を作成します。 |
LTO アクション
| 操作 | 説明 |
lto-backend
|
ビットコードをネイティブ オブジェクトにコンパイルする ThinLTO アクション。 |
lto-index
|
グローバル インデックスを生成する ThinLTO アクション。 |
action_config の使用
action_config は、アクション中に呼び出すツール（バイナリ）と、機能で定義されたフラグのセットを指定して、Bazel アクションを記述する Starlark 構造体です。これらのフラグは、アクションの実行に制約を適用します。
action_config() コンストラクタには、次のパラメータがあります。
| 属性 | 説明 |
action_name
|
このアクションに対応する Bazel アクション。Bazel は、この属性を使用して、アクションごとのツールと実行要件を検出します。 |
tools
|
呼び出す実行可能ファイル。アクションに適用されるツールは、特徴構成に一致する特徴セットを持つリスト内の最初のツールになります。デフォルト値を指定する必要があります。 |
flag_sets
|
アクションのグループに適用されるフラグのリスト。特徴の場合と同じです。 |
env_sets
|
アクションのグループに適用される環境制約のリスト。特徴の場合と同じです。 |
action_config は、前述の特徴の関係に従って、他の特徴と action_config を必要としたり、暗黙的に指定したりできます。この動作は、特徴の動作に似ています。
最後の 2 つの属性は、特徴の対応する属性と重複しています。一部の Bazel アクションには特定のフラグまたは環境変数が必要であり、不要な action_config+feature ペアを回避することを目的としているため、これらの属性が含まれています。通常、1 つの特徴を複数の action_config で共有することをおすすめします。
同じ toolchain 内で同じ action_name を持つ複数の action_config を定義することはできません。これにより、ツールパスの曖昧さが解消され、action_config の背後にある意図（アクションのプロパティが toolchain の 1 か所で明確に記述されていること）が適用されます。
ツールのコンストラクタを使用する
action_config は、tools パラメータを使用して一連のツールを指定できます。tool() コンストラクタは次のパラメータを取ります。
| フィールド | 説明 |
path
|
対象のツールへのパス（現在の場所を基準とする相対パス）。 |
with_features
|
このツールを適用するには、少なくとも 1 つの特徴セットを満たす必要があります。 |
特定の action_config の場合、ツールパスと実行要件を Bazel アクションに適用するのは 1 つの tool のみです。ツールは、特徴構成に一致する with_feature が設定されたツールが見つかるまで、action_config の tools 属性を反復処理することで選択されます（詳細については、このページの上部にある特徴の関係をご覧ください）。ツールリストの最後に、空の特徴量構成に対応するデフォルト ツールを追加する必要があります。
使用例
特徴とアクションを組み合わせて、さまざまなクロスプラットフォーム セマンティクスで Bazel アクションを実装できます。たとえば、macOS でデバッグ シンボルを生成するには、コンパイル アクションでシンボルを生成し、リンク アクション中に専用のツールを呼び出して圧縮された dsym アーカイブを作成し、そのアーカイブを解凍して Xcode で使用できる App Bundle と .plist ファイルを作成する必要があります。
Bazel では、このプロセスは次のように実装できます。ここで、unbundle-debuginfo は Bazel アクションです。
load("@rules_cc//cc:defs.bzl", "ACTION_NAMES")
action_configs = [
action_config (
action_name = ACTION_NAMES.cpp_link_executable,
tools = [
tool(
with_features = [
with_feature(features=["generate-debug-symbols"]),
],
path = "toolchain/mac/ld-with-dsym-packaging",
),
tool (path = "toolchain/mac/ld"),
],
),
]
features = [
feature(
name = "generate-debug-symbols",
flag_sets = [
flag_set (
actions = [
ACTION_NAMES.c_compile,
ACTION_NAMES.cpp_compile
],
flag_groups = [
flag_group(
flags = ["-g"],
),
],
)
],
implies = ["unbundle-debuginfo"],
),
]
この同じ機能は、fission を使用する Linux と、.pdb ファイルを生成する Windows で、まったく異なる方法で実装できます。たとえば、fission ベースのデバッグ シンボル生成の実装は次のようになります。
load("@rules_cc//cc:defs.bzl", "ACTION_NAMES")
action_configs = [
action_config (
name = ACTION_NAMES.cpp_compile,
tools = [
tool(
path = "toolchain/bin/gcc",
),
],
),
]
features = [
feature (
name = "generate-debug-symbols",
requires = [with_feature_set(features = ["dbg"])],
flag_sets = [
flag_set(
actions = [ACTION_NAMES.cpp_compile],
flag_groups = [
flag_group(
flags = ["-gsplit-dwarf"],
),
],
),
flag_set(
actions = [ACTION_NAMES.cpp_link_executable],
flag_groups = [
flag_group(
flags = ["-Wl", "--gdb-index"],
),
],
),
],
),
]
フラググループ
CcToolchainConfigInfo を使用すると、フラグを特定の目的のグループにバンドルできます。フラグ値内で事前定義された変数を使用してフラグを指定できます。このフラグは、ビルドコマンドにフラグを追加するときにコンパイラによって展開されます。次に例を示します。
flag_group (
flags = ["%{output_execpath}"],
)
この場合、フラグの内容はアクションの出力ファイルパスに置き換えられます。
フラググループは、リストに表示される順序（上から下、左から右）で、ビルドコマンドに展開されます。
ビルドコマンドに追加するときに異なる値で繰り返す必要があるフラグの場合、フラググループは list 型の変数を反復処理できます。たとえば、型が list の変数 include_path は次のようになります。
flag_group (
iterate_over = "include_paths",
flags = ["-I%{include_paths}"],
)
は、include_paths リスト内のパス要素ごとに -I<path> に展開されます。フラググループ宣言の本体にあるすべてのフラグ（または flag_group）は、単位として展開されます。次に例を示します。
flag_group (
iterate_over = "include_paths",
flags = ["-I", "%{include_paths}"],
)
は、include_paths リスト内のパス要素ごとに -I <path> に展開されます。
変数は複数回繰り返すことができます。次に例を示します。
flag_group (
iterate_over = "include_paths",
flags = ["-iprefix=%{include_paths}", "-isystem=%{include_paths}"],
)
は次のように展開されます。
-iprefix=<inc0> -isystem=<inc0> -iprefix=<inc1> -isystem=<inc1>
変数は、ドット表記を使用してアクセスできる構造に対応できます。次に例を示します。
flag_group (
flags = ["-l%{libraries_to_link.name}"],
)
構造体はネスト可能で、シーケンスを含めることもできます。名前の競合を回避し、明示的に指定するには、フィールドの完全パスを指定する必要があります。次に例を示します。
flag_group (
iterate_over = "libraries_to_link",
flag_groups = [
flag_group (
iterate_over = "libraries_to_link.shared_libraries",
flags = ["-l%{libraries_to_link.shared_libraries.name}"],
),
],
)
条件付き拡張
フラググループは、expand_if_available、expand_if_not_available、expand_if_true、expand_if_false、expand_if_equal 属性を使用して、特定の変数またはそのフィールドの存在に基づく条件付き展開をサポートしています。次に例を示します。
flag_group (
iterate_over = "libraries_to_link",
flag_groups = [
flag_group (
iterate_over = "libraries_to_link.shared_libraries",
flag_groups = [
flag_group (
expand_if_available = "libraries_to_link.shared_libraries.is_whole_archive",
flags = ["--whole_archive"],
),
flag_group (
flags = ["-l%{libraries_to_link.shared_libraries.name}"],
),
flag_group (
expand_if_available = "libraries_to_link.shared_libraries.is_whole_archive",
flags = ["--no_whole_archive"],
),
],
),
],
)
CcToolchainConfigInfo リファレンス
このセクションでは、C++ ルールを正常に構成するために必要なビルド変数、機能、その他の情報を紹介します。
CcToolchainConfigInfo ビルド変数
以下は、CcToolchainConfigInfo ビルド変数のリファレンスです。
| 変数 | 操作 | 説明 |
source_file
|
compile | コンパイルするソースファイル。 |
input_file
|
strip | 削除するアーティファクト。 |
output_file
|
compile | コンパイル出力。 |
output_assembly_file
|
compile | 出力されたアセンブリ ファイル。compile アクションがアセンブリ テキストを出力する場合にのみ適用されます（通常は --save_temps フラグを使用している場合）。内容は output_file と同じです。 |
output_preprocess_file
|
compile | 前処理済み出力。ソースファイルを前処理するコンパイル アクションにのみ適用されます（通常は --save_temps フラグを使用）。内容は output_file と同じです。 |
includes
|
compile | コンパイラがコンパイルされたソースに無条件に含める必要があるファイルの順序。 |
include_paths
|
compile | #include<foo.h> と #include "foo.h" を使用してコンパイラがヘッダーを検索するディレクトリを順序付けます。 |
quote_include_paths
|
compile | -iquote のシーケンスには、#include "foo.h" を使用してコンパイラがヘッダーを検索するディレクトリが含まれます。 |
system_include_paths
|
compile | -isystem のシーケンスには、#include <foo.h> を使用してコンパイラがヘッダーを検索するディレクトリが含まれます。 |
dependency_file
|
compile | コンパイラによって生成された .d 依存関係ファイル。 |
preprocessor_defines
|
compile | defines のシーケンス（--DDEBUG など）。 |
pic
|
compile | 出力を位置依存コードとしてコンパイルします。 |
gcov_gcno_file
|
compile | gcov カバレッジ ファイル。 |
per_object_debug_info_file
|
compile | オブジェクトごとのデバッグ情報（.dwp）ファイル。 |
stripotps
|
strip | stripopts のシーケンス。 |
legacy_compile_flags
|
compile | 従来の CROSSTOOL フィールド（compiler_flag、optional_compiler_flag、cxx_flag、optional_cxx_flag など）のフラグのシーケンス。 |
user_compile_flags
|
compile | copt ルール属性または --copt、--cxxopt、--conlyopt フラグのフラグのシーケンス。 |
unfiltered_compile_flags
|
compile | unfiltered_cxx_flag レガシー CROSSTOOL フィールドまたは unfiltered_compile_flags 機能のフラグのシーケンス。これらは nocopts ルール属性でフィルタされません。 |
sysroot
|
sysroot。 |
|
runtime_library_search_directories
|
リンク | リンカー ランタイム検索パス内のエントリ（通常は -rpath フラグで設定）。 |
library_search_directories
|
リンク | リンカー検索パス内のエントリ（通常は -L フラグで設定）。 |
libraries_to_link
|
リンク | リンカー呼び出しで入力としてリンクするファイルを指定するフラグ。 |
def_file_path
|
リンク | MSVC で Windows で使用される def ファイルの場所。 |
linker_param_file
|
リンク | コマンドライン長の制限を克服するために Bazel によって作成されたリンカー パラメータ ファイルの場所。 |
output_execpath
|
リンク | リンカーの出力の実行パス。 |
generate_interface_library
|
リンク | インターフェース ライブラリを生成するかどうかに応じて、"yes" または "no"。 |
interface_library_builder_path
|
リンク | インターフェース ライブラリ ビルダー ツールのパス。 |
interface_library_input_path
|
リンク | インターフェース ライブラリ ifso ビルダー ツールへの入力。 |
interface_library_output_path
|
リンク | ifso ビルダー ツールを使用してインターフェース ライブラリを生成するパス。 |
legacy_link_flags
|
リンク | 以前の CROSSTOOL フィールドから取得されたリンカー フラグ。 |
user_link_flags
|
リンク | --linkopt 属性または linkopts 属性からのリンカー フラグ。 |
linkstamp_paths
|
リンク | リンクスタンプ パスを指定するビルド変数。 |
force_pic
|
リンク | この変数は、PIC/PIE コードを生成する必要があることを示します（Bazel オプション `--force_pic` が渡されました）。 |
strip_debug_symbols
|
リンク | この変数は、デバッグ シンボルを削除する必要があることを示します。 |
is_cc_test
|
リンク | 現在のアクションが cc_test リンク アクションの場合は true、それ以外の場合は false。 |
is_using_fission
|
コンパイル、リンク | この変数が存在する場合、フィッション（オブジェクトごとのデバッグ情報）が有効になっています。デバッグ情報は .o ファイルではなく .dwo ファイルに格納されるため、コンパイラとリンカーはこのことを認識する必要があります。 |
fdo_instrument_path
|
コンパイル、リンク | FDO 計測プロファイルを保存するディレクトリのパス。 |
fdo_profile_path
|
compile | FDO プロファイルのパス。 |
fdo_prefetch_hints_path
|
compile | キャッシュ プリフェッチ プロファイルのパス。 |
csfdo_instrument_path
|
コンパイル、リンク | コンテキスト依存の FDO 計測プロファイルを格納するディレクトリのパス。 |
よく知られた機能
以下に、機能とその有効化条件を示します。
| 機能 | ドキュメント |
opt | dbg | fastbuild
|
コンパイルモードに基づいてデフォルトで有効になっています。 |
static_linking_mode | dynamic_linking_mode
|
リンクモードに基づいてデフォルトで有効になっています。 |
per_object_debug_info
|
supports_fission 機能が指定され、有効になっており、現在のコンパイルモードが --fission フラグで指定されている場合に有効になります。 |
supports_start_end_lib
|
有効にした場合（オプション --start_end_lib が設定されている場合）、Bazel は静的ライブラリに対してリンクせず、代わりに --start-lib/--end-lib リンカー オプションを使用してオブジェクトに直接リンクします。これにより、Bazel が静的ライブラリをビルドする必要がないため、ビルドが高速化されます。 |
supports_interface_shared_libraries
|
有効にした場合（オプション --interface_shared_objects が設定されている場合）、Bazel は、linkstatic が False に設定されているターゲット（デフォルトは cc_test）をインターフェース共有ライブラリにリンクします。これにより、増分再リンクが高速化されます。 |
supports_dynamic_linker
|
有効にすると、C++ ルールは、ツールチェーンが共有ライブラリを生成できることを認識します。 |
static_link_cpp_runtimes
|
有効にすると、Bazel は静的リンク モードで C++ ランタイムを静的にリンクし、動的リンク モードで動的にリンクします。cc_toolchain.static_runtime_lib 属性または cc_toolchain.dynamic_runtime_lib 属性で指定されたアーティファクト（リンクモードに応じて異なる）がリンク アクションに追加されます。 |
supports_pic
|
有効にすると、ツールチェーンは動的ライブラリに PIC オブジェクトを使用することを認識します。PIC コンパイルが必要な場合は、常に「pic」変数が存在します。デフォルトで有効になっていない場合に `--force_pic` が渡されると、Bazel は `supports_pic` をリクエストし、この機能が有効であることを検証します。この機能がない場合や有効にできない場合、`--force_pic` は使用できません。 |
static_linking_mode | dynamic_linking_mode
|
リンクモードに基づいてデフォルトで有効になります。 |
no_legacy_features
|
レガシー機能が存在する場合、Bazel が C++ 構成にレガシー機能を追加しないようにします。機能の詳細なリストについては、以下をご覧ください。 |
レガシー機能のパッチ適用ロジック
Bazel は、下位互換性を確保するために、ツールチェーンの機能に次の変更を適用します。
legacy_compile_flags機能を toolchain の上部に移動default_compile_flags機能を toolchain の上部に移動dependency_file機能（存在しない場合は追加）を toolchain の先頭に追加pic機能（存在しない場合は追加）を toolchain の先頭に追加per_object_debug_info機能（存在しない場合は追加）を toolchain の先頭に追加preprocessor_defines機能（存在しない場合は追加）を toolchain の先頭に追加includes機能（存在しない場合は追加）を toolchain の先頭に追加include_paths機能（存在しない場合は追加）を toolchain の先頭に追加fdo_instrument機能（存在しない場合は追加）を toolchain の先頭に追加fdo_optimize機能（存在しない場合は追加）を toolchain の先頭に追加cs_fdo_instrument機能（存在しない場合は追加）を toolchain の先頭に追加cs_fdo_optimize機能（存在しない場合は追加）を toolchain の先頭に追加fdo_prefetch_hints機能（存在しない場合は追加）を toolchain の先頭に追加autofdo機能（存在しない場合は追加）を toolchain の先頭に追加build_interface_libraries機能（存在しない場合は追加）を toolchain の先頭に追加dynamic_library_linker_tool機能（存在しない場合は追加）を toolchain の先頭に追加shared_flag機能（存在しない場合は追加）を toolchain の先頭に追加linkstamps機能（存在しない場合は追加）を toolchain の先頭に追加output_execpath_flags機能（存在しない場合は追加）を toolchain の先頭に追加runtime_library_search_directories機能（存在しない場合は追加）を toolchain の先頭に追加library_search_directories機能（存在しない場合は追加）を toolchain の先頭に追加archiver_flags機能（存在しない場合は追加）を toolchain の先頭に追加libraries_to_link機能（存在しない場合は追加）を toolchain の先頭に追加force_pic_flags機能（存在しない場合は追加）を toolchain の先頭に追加user_link_flags機能（存在しない場合は追加）を toolchain の先頭に追加legacy_link_flags機能（存在しない場合は追加）を toolchain の先頭に追加static_libgcc機能（存在しない場合は追加）を toolchain の先頭に追加fission_support機能（存在しない場合は追加）を toolchain の先頭に追加strip_debug_symbols機能（存在しない場合は追加）を toolchain の先頭に追加coverage機能（存在しない場合は追加）を toolchain の先頭に追加llvm_coverage_map_format機能（存在しない場合は追加）を toolchain の先頭に追加gcc_coverage_map_format機能（存在しない場合は追加）を toolchain の先頭に追加fully_static_link機能をツールチェーンの一番下に追加（存在しない場合）user_compile_flags機能をツールチェーンの一番下に追加（存在しない場合）sysroot機能をツールチェーンの一番下に追加（存在しない場合）unfiltered_compile_flags機能をツールチェーンの一番下に追加（存在しない場合）linker_param_file機能をツールチェーンの一番下に追加（存在しない場合）compiler_input_flags機能をツールチェーンの一番下に追加（存在しない場合）compiler_output_flags機能をツールチェーンの一番下に追加（存在しない場合）
機能のリストは長くなります。Starlark での Crosstool が完了したら、これらを削除する予定です。詳しくは、CppActionConfigs の実装をご覧ください。本番環境のツールチェーンの場合は、no_legacy_features を追加してツールチェーンをよりスタンドアロンにすることを検討してください。