Chế độ hiển thị

Báo cáo vấn đề Xem nguồn Nightly · 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

Trang này trình bày về hai hệ thống chế độ hiển thị của Bazel: chế độ hiển thị mục tiêu và chế độ hiển thị tải.

Cả hai loại chế độ hiển thị này đều giúp các nhà phát triển khác phân biệt giữa API công khai của thư viện và thông tin triển khai của API đó, đồng thời giúp thực thi cấu trúc khi không gian làm việc của bạn phát triển. Bạn cũng có thể sử dụng chế độ hiển thị khi ngừng sử dụng API công khai để cho phép người dùng hiện tại trong khi từ chối người dùng mới.

Mức độ hiển thị mục tiêu

Chế độ hiển thị mục tiêu kiểm soát những đối tượng có thể phụ thuộc vào mục tiêu của bạn, tức là những đối tượng có thể sử dụng nhãn của mục tiêu bên trong một thuộc tính như deps.

A mục tiêu hiển thị với B mục tiêu nếu chúng nằm trong cùng một gói hoặc nếu A cấp quyền hiển thị cho gói của B. Do đó, gói là đơn vị độ chi tiết để quyết định có cho phép truy cập hay không. Nếu B phụ thuộc vào A nhưng A không hiển thị với B, thì mọi nỗ lực tạo B đều không thành công trong quá trình phân tích.

Xin lưu ý rằng việc cấp quyền hiển thị cho một gói không tự động cấp quyền hiển thị cho các gói con của gói đó. Để biết thêm thông tin chi tiết về gói và gói con, hãy xem phần Khái niệm và thuật ngữ.

Để tạo nguyên mẫu, bạn có thể tắt chế độ thực thi chế độ hiển thị mục tiêu bằng cách đặt cờ --check_visibility=false. Bạn không nên làm việc này cho mục đích sử dụng chính thức trong mã đã gửi.

Cách chính để kiểm soát chế độ hiển thị là sử dụng thuộc tính visibility trên các mục tiêu quy tắc. Phần này mô tả định dạng của thuộc tính này và cách xác định chế độ hiển thị của mục tiêu.

Thông số kỹ thuật về chế độ hiển thị

Tất cả mục tiêu quy tắc đều có thuộc tính visibility chứa danh sách nhãn. Mỗi nhãn có một trong các dạng sau. Ngoại trừ biểu mẫu cuối cùng, đây chỉ là các phần giữ chỗ cú pháp không tương ứng với bất kỳ mục tiêu thực tế nào.

• "//visibility:public": Cấp quyền truy cập vào tất cả gói. (Không được kết hợp với bất kỳ thông số kỹ thuật nào khác.)

• "//visibility:private": Không cấp thêm quyền truy cập nào; chỉ các mục tiêu trong gói này mới có thể sử dụng mục tiêu này. (Có thể không được kết hợp với bất kỳ thông số kỹ thuật nào khác.)

• "//foo/bar:__pkg__": Cấp quyền truy cập vào //foo/bar (nhưng không cấp quyền truy cập vào các gói con của nó).

• "//foo/bar:__subpackages__": Cấp quyền truy cập //foo/bar và tất cả các gói con trực tiếp và gián tiếp của gói này.

• "//some_pkg:my_package_group": Cấp quyền truy cập vào tất cả các gói thuộc package_group đã cho.

  • Nhóm gói sử dụng cú pháp khác để chỉ định gói. Trong một nhóm gói, các biểu mẫu "//foo/bar:__pkg__" và "//foo/bar:__subpackages__" tương ứng sẽ được thay thế bằng "//foo/bar" và "//foo/bar/...". Tương tự, "//visibility:public" và "//visibility:private" chỉ là "public" và "private".

Ví dụ: nếu //some/package:mytarget có visibility được đặt thành [":__subpackages__", "//tests:__pkg__"], thì nó có thể được bất kỳ mục tiêu nào thuộc cây nguồn //some/package/..., cũng như các mục tiêu được xác định trong //tests/BUILD sử dụng, nhưng không được sử dụng bởi các mục tiêu được xác định trong //tests/integration/BUILD.

Phương pháp hay nhất: Để hiển thị một số mục tiêu cho cùng một nhóm gói, hãy sử dụng package_group thay vì lặp lại danh sách trong thuộc tính visibility của mỗi mục tiêu. Điều này giúp tăng khả năng đọc và ngăn các danh sách bị mất đồng bộ hoá.

Lưu ý: Thuộc tính visibility có thể không chỉ định các mục tiêu không phải package_group. Việc này sẽ kích hoạt lỗi "Nhãn không tham chiếu đến một nhóm gói" hoặc "Vòng lặp trong biểu đồ phần phụ thuộc".

Mức hiển thị mục tiêu của quy tắc

Mức độ hiển thị của mục tiêu quy tắc là:

1. Giá trị của thuộc tính visibility, nếu được đặt; nếu không

2. Giá trị của đối số default_visibility của câu lệnh package trong tệp BUILD của mục tiêu, nếu có khai báo như vậy; nếu không

3. //visibility:private.

Phương pháp hay nhất: Tránh đặt default_visibility thành công khai. Việc này có thể thuận tiện cho việc tạo nguyên mẫu hoặc trong các cơ sở mã nhỏ, nhưng nguy cơ vô tình tạo mục tiêu công khai sẽ gia tăng khi cơ sở mã tăng lên. Bạn nên nêu rõ những mục tiêu nào thuộc giao diện công khai của gói.

Ví dụ:

Tệp //frobber/bin/BUILD:

# This target is visible to everyone
cc_binary(
    name = "executable",
    visibility = ["//visibility:public"],
    deps = [":library"],
)

# This target is visible only to targets declared in the same package
cc_library(
    name = "library",
    # No visibility -- defaults to private since no
    # package(default_visibility = ...) was used.
)

# This target is visible to targets in package //object and //noun
cc_library(
    name = "subject",
    visibility = [
        "//noun:__pkg__",
        "//object:__pkg__",
    ],
)

# See package group "//frobber:friends" (below) for who can
# access this target.
cc_library(
    name = "thingy",
    visibility = ["//frobber:friends"],
)

Tệp //frobber/BUILD:

# This is the package group declaration to which target
# //frobber/bin:thingy refers.
#
# Our friends are packages //frobber, //fribber and any
# subpackage of //fribber.
package_group(
    name = "friends",
    packages = [
        "//fribber/...",
        "//frobber",
    ],
)

Chế độ hiển thị mục tiêu tệp đã tạo

Mục tiêu tệp được tạo có chế độ hiển thị giống với mục tiêu quy tắc tạo ra mục tiêu đó.

Chế độ hiển thị mục tiêu của tệp nguồn

Bạn có thể đặt chế độ hiển thị của mục tiêu tệp nguồn một cách rõ ràng bằng cách gọi exports_files. Khi không có đối số visibility nào được chuyển đến exports_files, chế độ hiển thị sẽ được công khai. Không được dùng exports_files để ghi đè chế độ hiển thị của tệp đã tạo.

Đối với các mục tiêu tệp nguồn không xuất hiện trong lệnh gọi đến exports_files, chế độ hiển thị phụ thuộc vào giá trị của cờ --incompatible_no_implicit_file_export:

• Nếu bạn đặt cờ này, chế độ hiển thị sẽ là riêng tư.

• Nếu không, hành vi cũ sẽ áp dụng: Chế độ hiển thị giống với default_visibility của tệp BUILD hoặc chế độ riêng tư nếu bạn không chỉ định chế độ hiển thị mặc định.

Tránh dựa vào hành vi cũ. Luôn viết nội dung khai báo exports_files bất cứ khi nào mục tiêu tệp nguồn cần chế độ hiển thị không riêng tư.

Phương pháp hay nhất: Khi có thể, hãy ưu tiên hiển thị mục tiêu quy tắc thay vì tệp nguồn. Ví dụ: thay vì gọi exports_files trên tệp .java, hãy gói tệp đó trong mục tiêu java_library không riêng tư. Nhìn chung, mục tiêu quy tắc chỉ nên tham chiếu trực tiếp các tệp nguồn nằm trong cùng một gói.

Ví dụ:

Tệp //frobber/data/BUILD:

exports_files(["readme.txt"])

Tệp //frobber/bin/BUILD:

cc_binary(
  name = "my-program",
  data = ["//frobber/data:readme.txt"],
)

Chế độ hiển thị chế độ cài đặt cấu hình

Trước đây, Bazel không thực thi chế độ hiển thị cho các mục tiêu config_setting được tham chiếu trong các khoá của select(). Có hai cờ để xoá hành vi cũ này:

• --incompatible_enforce_config_setting_visibility cho phép kiểm tra chế độ hiển thị cho các mục tiêu này. Để hỗ trợ quá trình di chuyển, thao tác này cũng khiến mọi config_setting không chỉ định visibility sẽ được coi là công khai (bất kể default_visibility ở cấp gói).

• --incompatible_config_setting_private_default_visibility khiến các config_setting không chỉ định visibility tuân theo default_visibility của gói và sử dụng chế độ hiển thị riêng tư, giống như bất kỳ mục tiêu quy tắc nào khác. Phương thức này sẽ không hoạt động nếu bạn không đặt --incompatible_enforce_config_setting_visibility.

Tránh dựa vào hành vi cũ. Mọi config_setting dự định sử dụng bên ngoài gói hiện tại phải có visibility rõ ràng, nếu gói chưa chỉ định default_visibility phù hợp.

Chế độ hiển thị mục tiêu của nhóm gói

Mục tiêu package_group không có thuộc tính visibility. Các video này luôn hiển thị công khai.

Mức độ hiển thị của các phần phụ thuộc ngầm ẩn

Một số quy tắc có phần phụ thuộc ngầm ẩn – các phần phụ thuộc không được nêu rõ trong tệp BUILD nhưng vốn có trong mọi thực thể của quy tắc đó. Ví dụ: quy tắc cc_library có thể tạo một phần phụ thuộc ngầm ẩn từ mỗi mục tiêu quy tắc đến một mục tiêu có thể thực thi đại diện cho trình biên dịch C++.

Chế độ hiển thị của phần phụ thuộc ngầm ẩn như vậy được kiểm tra liên quan đến gói chứa tệp .bzl trong đó quy tắc (hoặc khía cạnh) được xác định. Trong ví dụ của chúng ta, trình biên dịch C++ có thể là riêng tư miễn là trình biên dịch đó nằm trong cùng một gói với định nghĩa của quy tắc cc_library. Để dự phòng, nếu phần phụ thuộc ngầm ẩn không hiển thị trong định nghĩa, thì phần phụ thuộc đó sẽ được kiểm tra liên quan đến mục tiêu cc_library.

Bạn có thể thay đổi hành vi này bằng cách tắt --incompatible_visibility_private_attributes_at_definition. Khi bị tắt, các phần phụ thuộc ngầm ẩn được coi như mọi phần phụ thuộc khác. Điều này có nghĩa là mục tiêu được phụ thuộc (chẳng hạn như trình biên dịch C++) phải hiển thị với mọi thực thể của quy tắc. Trong thực tế, điều này thường có nghĩa là mục tiêu phải có chế độ hiển thị công khai.

Nếu bạn muốn hạn chế việc sử dụng quy tắc cho một số gói nhất định, hãy dùng chế độ hiển thị tải.

Tải chế độ hiển thị

Load visibility (Chế độ hiển thị tải) kiểm soát việc tệp .bzl có thể được tải từ các tệp BUILD hoặc .bzl khác bên ngoài gói hiện tại hay không.

Tương tự như cách chế độ hiển thị mục tiêu bảo vệ mã nguồn được đóng gói bằng các mục tiêu, chế độ hiển thị tải sẽ bảo vệ logic bản dựng được đóng gói bằng các tệp .bzl. Ví dụ: tác giả tệp BUILD có thể muốn đưa một số định nghĩa mục tiêu lặp lại vào macro trong tệp .bzl. Nếu không có tính năng bảo vệ chế độ hiển thị tải, họ có thể thấy macro của mình được các cộng tác viên khác sử dụng lại trong cùng một không gian làm việc, do đó việc sửa đổi macro sẽ làm hỏng bản dựng của các nhóm khác.

Xin lưu ý rằng tệp .bzl có thể có hoặc không có mục tiêu tệp nguồn tương ứng. Nếu có, không có gì đảm bảo rằng chế độ hiển thị tải và chế độ hiển thị mục tiêu trùng khớp với nhau. Tức là cùng một tệp BUILD có thể tải tệp .bzl nhưng không liệt kê tệp đó trong srcs của filegroup hoặc ngược lại. Điều này đôi khi có thể gây ra sự cố cho các quy tắc muốn sử dụng tệp .bzl dưới dạng mã nguồn, chẳng hạn như để tạo hoặc kiểm thử tài liệu.

Để tạo bản mô hình, bạn có thể tắt tính năng thực thi chế độ hiển thị tải bằng cách đặt --check_bzl_visibility=false. Cũng như --check_visibility=false, bạn không nên làm điều này cho mã đã gửi.

Chế độ hiển thị tải có sẵn kể từ Bazel 6.0.

Khai báo chế độ hiển thị tải

Để đặt chế độ hiển thị tải của tệp .bzl, hãy gọi hàm visibility() từ bên trong tệp. Đối số cho visibility() là một danh sách thông số kỹ thuật của gói, giống như thuộc tính packages của package_group. Tuy nhiên, visibility() không chấp nhận thông số kỹ thuật gói âm.

Lệnh gọi đến visibility() chỉ được xảy ra một lần cho mỗi tệp, ở cấp cao nhất (không phải bên trong một hàm) và tốt nhất là ngay sau câu lệnh load().

Không giống như chế độ hiển thị mục tiêu, chế độ hiển thị tải mặc định luôn là công khai. Các tệp không gọi visibility() luôn có thể tải được từ bất kỳ đâu trong không gian làm việc. Bạn nên thêm visibility("private") vào đầu mọi tệp .bzl mới không dành riêng cho việc sử dụng bên ngoài gói.

Ví dụ:

# //mylib/internal_defs.bzl

# Available to subpackages and to mylib's tests.
visibility(["//mylib/...", "//tests/mylib/..."])

def helper(...):
    ...

# //mylib/rules.bzl

load(":internal_defs.bzl", "helper")
# Set visibility explicitly, even though public is the default.
# Note the [] can be omitted when there's only one entry.
visibility("public")

myrule = rule(
    ...
)

# //someclient/BUILD

load("//mylib:rules.bzl", "myrule")          # ok
load("//mylib:internal_defs.bzl", "helper")  # error

...

Các phương pháp hiển thị tải

Phần này mô tả các mẹo để quản lý việc khai báo chế độ hiển thị tải.

Phân tích chế độ hiển thị

Khi nhiều tệp .bzl có cùng chế độ hiển thị, bạn nên đưa thông số kỹ thuật của gói vào một danh sách chung. Ví dụ:

# //mylib/internal_defs.bzl

visibility("private")

clients = [
    "//foo",
    "//bar/baz/...",
    ...
]

# //mylib/feature_A.bzl

load(":internal_defs.bzl", "clients")
visibility(clients)

...

# //mylib/feature_B.bzl

load(":internal_defs.bzl", "clients")
visibility(clients)

...

Điều này giúp ngăn chặn sự cố vô tình lệch giữa các chế độ hiển thị của nhiều tệp .bzl. Mã này cũng dễ đọc hơn khi danh sách clients lớn.

Soạn thảo hiển thị

Đôi khi, tệp .bzl có thể cần hiển thị với danh sách cho phép bao gồm nhiều danh sách cho phép nhỏ hơn. Điều này tương tự như cách package_group có thể kết hợp các package_group khác thông qua thuộc tính includes.

Giả sử bạn đang ngừng sử dụng một macro được sử dụng rộng rãi. Bạn muốn gói này chỉ hiển thị cho những người dùng hiện tại và cho các gói do nhóm của bạn sở hữu. Bạn có thể viết:

# //mylib/macros.bzl

load(":internal_defs.bzl", "our_packages")
load("//some_big_client:defs.bzl", "their_remaining_uses")

# List concatenation. Duplicates are fine.
visibility(our_packages + their_remaining_uses)

Loại bỏ trùng lặp bằng các nhóm gói

Không giống như chế độ hiển thị mục tiêu, bạn không thể xác định chế độ hiển thị tải theo package_group. Nếu bạn muốn sử dụng lại cùng một danh sách cho phép cho cả chế độ hiển thị mục tiêu và chế độ hiển thị tải, tốt nhất bạn nên di chuyển danh sách thông số kỹ thuật của gói vào tệp .bzl, trong đó cả hai loại khai báo đều có thể tham chiếu đến tệp đó. Dựa trên ví dụ trong phần Tính đến chế độ hiển thị ở trên, bạn có thể viết:

# //mylib/BUILD

load(":internal_defs", "clients")

package_group(
    name = "my_pkg_grp",
    packages = clients,
)

Điều này chỉ hoạt động nếu danh sách không chứa thông số kỹ thuật gói phủ định nào.

Bảo vệ từng ký hiệu

Bất kỳ ký hiệu Starlark nào có tên bắt đầu bằng dấu gạch dưới đều không thể tải từ một tệp khác. Điều này giúp bạn dễ dàng tạo các biểu tượng riêng tư, nhưng không cho phép chia sẻ các biểu tượng này với một nhóm tệp đáng tin cậy có giới hạn. Mặt khác, chế độ hiển thị tải cho phép bạn kiểm soát những gói nào khác có thể thấy .bzl file của bạn, nhưng không cho phép bạn ngăn tải bất kỳ ký hiệu nào không có dấu gạch dưới.

May mắn là bạn có thể kết hợp hai tính năng này để có được quyền kiểm soát chi tiết.

# //mylib/internal_defs.bzl

# Can't be public, because internal_helper shouldn't be exposed to the world.
visibility("private")

# Can't be underscore-prefixed, because this is
# needed by other .bzl files in mylib.
def internal_helper(...):
    ...

def public_util(...):
    ...

# //mylib/defs.bzl

load(":internal_defs", "internal_helper", _public_util="public_util")
visibility("public")

# internal_helper, as a loaded symbol, is available for use in this file but
# can't be imported by clients who load this file.
...

# Re-export public_util from this file by assigning it to a global variable.
# We needed to import it under a different name ("_public_util") in order for
# this assignment to be legal.
public_util = _public_util

Tìm lỗi mã nguồn bzl-visibility Buildifier

Có một Trình tìm lỗi mã nguồn của trình tạo bản dựng đưa ra cảnh báo nếu người dùng tải tệp từ thư mục có tên internal hoặc private, khi tệp của người dùng không nằm trong thư mục gốc của thư mục đó. Công cụ tìm lỗi mã nguồn này ra mắt trước tính năng chế độ hiển thị cho nội dung tải và không cần thiết trong những không gian làm việc mà các tệp .bzl khai báo chế độ hiển thị.