常見 C++ 建構用途

回報問題 查看原始碼 夜間 7.2 7.1 7.0 6.5 6.4

本節介紹一些建構 C++ 專案的常見用途 搭配使用 Bazel如果尚未建立，請先開始建構 C++ 完成教學課程 Bazel 簡介：建構 C++ 專案。

如需 cc_library 和 hdrs 標頭檔案的相關資訊，請參閱 cc_library。

在目標中加入多個檔案

在單一目標中加入多個檔案： glob。 例如：

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

有了這個目標，Bazel 就會建構其在指令列中找到的所有 .cc 和 .h 檔案 與包含此目標的 BUILD 檔案相同的目錄 (不包括 子目錄)。

使用遞移性包括

如果檔案含有標頭，則任何以該檔案為來源的規則 (也就是 該檔案位於 srcs、hdrs 或 textual_hdrs 屬性中) 應該 端視包含標頭的程式庫規則而定相反地， 必須將依附元件指定為依附元件。舉例來說，假設 sandwich.h 包含 bread.h 和 bread.h，其中包含 flour.h。sandwich.h 不包含 flour.h (誰想吃三明治？)，因此 BUILD 檔案看起來會像這樣：

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

在本例中，sandwich 程式庫依附於 bread 程式庫，後者依附於 在 flour 程式庫中。

新增 include 路徑

有時候，您無法 (或不想) 在工作區納入根路徑 根目錄。現有程式庫可能已有的 include 目錄 與工作區的路徑相符。舉例來說，假設您擁有 目錄結構：

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel 會將 some_lib.h 納入 legacy/some_lib/include/some_lib.h，但假設 some_lib.cc 包含 "some_lib.h"。如要讓包含路徑有效 legacy/some_lib/BUILD 需要指定 some_lib/include 目錄為 include 目錄：

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

這對外部依附元件來說特別實用，因為其標頭檔案 否則就必須加入 / 前置字元。

包括外部程式庫

假設您正在使用 Google Test。 您可以使用 WORKSPACE 檔案中的其中一個存放區函式： 下載 Google 測試，並在存放區中使用：

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

然後建立 gtest.BUILD，這是用於編譯 Google 測試的 BUILD 檔案。 Google 測試有幾項「特殊」cc_library規則必須符合的條件 更複雜：

  • googletest-release-1.10.0/src/gtest-all.cc的#include (其他) googletest-release-1.10.0/src/ 中的檔案：從 編譯以避免重複符號的連結錯誤。

  • 它會使用與 googletest-release-1.10.0/include/ 目錄 ("gtest/gtest.h")，因此您必須 把該目錄加入 include 路徑中。

  • 需要在 pthread 中連結，因此請將其新增為 linkopt。

因此最終規則會如下所示：

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/src/*.cc"],
        exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/include/**/*.h",
        "googletest-release-1.10.0/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/include",
        "-Iexternal/gtest/googletest-release-1.10.0"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

這看起來很混亂：所有內容開頭都是 googletest-release-1.10.0 加上封存的結構你可以製作http_archive條紋 加入 strip_prefix 屬性，即可達到這個前置字串：

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

則 gtest.BUILD 看起來會像這樣：

cc_library(
    name = "main",
    srcs = glob(
        ["src/*.cc"],
        exclude = ["src/gtest-all.cc"]
    ),
    hdrs = glob([
        "include/**/*.h",
        "src/*.h"
    ]),
    copts = ["-Iexternal/gtest/include"],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

現在 cc_ 規則可以使用 @gtest//:main。

編寫及執行 C++ 測試

舉例來說，您可以建立測試 ./test/hello-test.cc，例如：

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

然後為測試建立 ./test/BUILD 檔案：

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = ["-Iexternal/gtest/include"],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

如要讓 hello-test 可以看見「hello-greet」，你必須新增 將 "//test:__pkg__", 設為 ./main/BUILD 中的 visibility 屬性。

您現在可以使用 bazel test 執行測試。

bazel test test:hello-test

這會產生以下輸出內容：

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

新增預先編譯程式庫的依附元件

如果您想使用只有已編譯版本的程式庫， (例如標頭和 .so 檔案) 會納入 cc_library 規則中：

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

這樣一來，工作區中的其他 C++ 目標就能使用這項規則。