Nesta página, descrevemos como migrar do Maven para o Bazel, incluindo os pré-requisitos e as etapas de instalação. Ele descreve as diferenças entre o Maven e o Bazel e fornece um exemplo de migração usando o projeto Guava.
Ao migrar de qualquer ferramenta de build para o Bazel, é melhor ter as duas ferramentas de build em execução em paralelo até que você tenha migrado totalmente sua equipe de desenvolvimento, o sistema de CI e todos os outros sistemas relevantes. É possível executar o Maven e o Bazel no mesmo repositório.
Antes de começar
- Instale o Bazel se ainda não estiver instalado.
- Se você não tiver experiência com o Bazel, siga o tutorial Introdução ao Bazel: crie em Java antes de iniciar a migração. Neste tutorial, explicamos os conceitos, a estrutura e a sintaxe de rótulos do Bazel.
Diferenças entre o Maven e o Bazel
- O Maven usa arquivos
pom.xml
de nível superior. O Bazel oferece suporte a vários arquivos de build e vários destinos por arquivoBUILD
, permitindo builds mais incrementais que os do Maven. - O Maven se encarrega das etapas do processo de implantação. Ele não automatiza a implantação.
- Ele permite expressar dependências entre linguagens.
- À medida que você adiciona novas seções ao projeto, com o Bazel, pode ser necessário adicionar novos
arquivos
BUILD
. A prática recomendada é adicionar um arquivoBUILD
a cada novo pacote Java.
Migrar do Maven para o Bazel
As etapas abaixo descrevem como migrar seu projeto para o Bazel:
- Crie o arquivo do ESPAÇO DE TRABALHO
- Crie um arquivo BUILD
- Crie mais arquivos BUILD
- Criar usando o Bazel
Os exemplos abaixo vêm de uma migração do
projeto Guava do Maven para o Bazel.
O projeto Guava usado é a versão v31.1
. Os exemplos que usam o Guava não abordam cada etapa da migração, mas mostram os arquivos e o conteúdo que são gerados ou adicionados manualmente para a migração.
$ git clone https://github.com/google/guava.git && cd guava
$ git checkout v31.1
1. Criar o arquivo do ESPAÇO DE TRABALHO
Crie um arquivo chamado WORKSPACE
na raiz do projeto. Se o projeto
não tiver dependências externas, o arquivo do espaço de trabalho poderá estar vazio.
Se o projeto depender de arquivos ou pacotes que não estejam em um dos diretórios do projeto, especifique essas dependências externas no arquivo do espaço de trabalho. Para automatizar a listagem de dependências externas do arquivo do espaço de trabalho, use rules_jvm_external
. Para instruções sobre como usar esse conjunto de regras, consulte
o README (em inglês).
Exemplo de projeto Guava: dependências externas
É possível listar as dependências externas do projeto Guava com o conjunto de regras rules_jvm_external
.
Adicione o seguinte snippet ao arquivo WORKSPACE
:
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
RULES_JVM_EXTERNAL_TAG = "4.3"
RULES_JVM_EXTERNAL_SHA = "6274687f6fc5783b589f56a2f1ed60de3ce1f99bc4e8f9edef3de43bdf7c6e74"
http_archive(
name = "rules_jvm_external",
sha256 = RULES_JVM_EXTERNAL_SHA,
strip_prefix = "rules_jvm_external-%s" % RULES_JVM_EXTERNAL_TAG,
url = "https://github.com/bazelbuild/rules_jvm_external/archive/%s.zip" % RULES_JVM_EXTERNAL_TAG,
)
load("@rules_jvm_external//:defs.bzl", "maven_install")
maven_install(
artifacts = [
"com.google.code.findbugs:jsr305:3.0.2",
"com.google.errorprone:error_prone_annotations:2.11.0",
"com.google.j2objc:j2objc-annotations:1.3",
"org.codehaus.mojo:animal-sniffer-annotations:1.20",
"org.checkerframework:checker-qual:3.12.0",
],
repositories = [
"https://repo1.maven.org/maven2",
],
)
2. Crie um arquivo BUILD
Agora que o espaço de trabalho está definido e as dependências externas (se aplicável) listadas, você precisa criar arquivos BUILD
para descrever como o projeto deve ser criado. Ao contrário do Maven, com um arquivo pom.xml
, o Bazel pode usar muitos
arquivos BUILD
para criar um projeto. Esses arquivos especificam vários destinos de build,
o que permite que o Bazel produza builds incrementais.
Adicione arquivos BUILD
em etapas. Comece adicionando um arquivo BUILD
na raiz do seu projeto e usando-o para fazer uma compilação inicial com o Bazel.
Em seguida, refine seu build adicionando mais arquivos BUILD
com destinos
mais granulares.
No mesmo diretório do arquivo
WORKSPACE
, crie um arquivo de texto e nomeie-o comoBUILD
.Neste arquivo
BUILD
, use a regra adequada para criar um destino e criar seu projeto. Veja algumas dicas:Use a regra apropriada:
Para criar projetos com um único módulo do Maven, use a regra
java_library
desta maneira:java_library( name = "everything", srcs = glob(["src/main/java/**/*.java"]), resources = glob(["src/main/resources/**"]), deps = ["//:all-external-targets"], )
Para criar projetos com vários módulos Maven, use a regra
java_library
desta maneira:java_library( name = "everything", srcs = glob([ "Module1/src/main/java/**/*.java", "Module2/src/main/java/**/*.java", ... ]), resources = glob([ "Module1/src/main/resources/**", "Module2/src/main/resources/**", ... ]), deps = ["//:all-external-targets"], )
Para criar binários, use a regra
java_binary
:java_binary( name = "everything", srcs = glob(["src/main/java/**/*.java"]), resources = glob(["src/main/resources/**"]), deps = ["//:all-external-targets"], main_class = "com.example.Main" )
Especifique os atributos:
name
: dá ao destino um nome significativo. Nos exemplos acima, o destino é chamado de "tudo".srcs
: use globbing para listar todos os arquivos .java no seu projeto.resources
: use globs para listar todos os recursos no projeto.deps
: você precisa determinar de quais dependências externas seu projeto precisa. Por exemplo, se você gerou uma lista de dependências externas usando a ferramentagenerate_workspace
, as dependências dejava_library
serão as bibliotecas listadas na macrogenerated_java_libraries
.
Dê uma olhada no exemplo abaixo deste arquivo BUILD de nível superior da migração do projeto Guava.
Agora que você tem um arquivo
BUILD
na raiz do projeto, crie o projeto para garantir que ele funcione. Na linha de comando, no diretório do espaço de trabalho, usebazel build //:everything
para criar seu projeto com o Bazel.O projeto foi criado com o Bazel. Você precisará adicionar mais arquivos
BUILD
para permitir builds incrementais do projeto.
Exemplo de projeto Guava: comece com um arquivo BUILD
Ao migrar o projeto Guava para o Bazel, inicialmente um arquivo BUILD
é usado
para criar todo o projeto. Veja o conteúdo desse arquivo BUILD
inicial no diretório do espaço de trabalho:
java_library(
name = "everything",
srcs = glob([
"guava/src/**/*.java",
"futures/failureaccess/src/**/*.java",
]),
deps = [
"@maven//:com_google_code_findbugs_jsr305",
"@maven//:com_google_errorprone_error_prone_annotations",
"@maven//:com_google_j2objc_j2objc_annotations",
"@maven//:org_checkerframework_checker_qual",
"@maven//:org_codehaus_mojo_animal_sniffer_annotations",
],
)
3. Crie mais arquivos BUILD (opcional)
O Bazel funciona com apenas um BUILD file
, como você viu ao concluir seu primeiro
build. Considere ainda dividir o build em partes menores
adicionando mais arquivos BUILD
com destinos granulares.
Vários arquivos BUILD
com vários destinos darão ao build maior granularidade, permitindo:
- o aumento de builds incrementais do projeto,
- de aumento na execução paralela do build,
- melhor capacidade de manutenção do build para futuros usuários e
- controle sobre a visibilidade de destinos entre pacotes, o que pode evitar problemas como bibliotecas que contêm detalhes de implementação vazando para APIs públicas.
Dicas para adicionar mais arquivos BUILD
:
- Para começar, adicione um arquivo
BUILD
a cada pacote Java. Comece com pacotes Java que têm o menor número de dependências e vá até pacotes com mais dependências. - À medida que você adicionar arquivos
BUILD
e especificar destinos, adicione esses novos destinos às seçõesdeps
dos destinos que dependem deles. Observe que a funçãoglob()
não ultrapassa os limites de pacotes. Portanto, à medida que o número de pacotes aumenta, os arquivos correspondidos porglob()
diminuem. - Sempre que você adicionar um arquivo
BUILD
a um diretóriomain
, inclua um arquivoBUILD
no diretóriotest
correspondente. - Tenha cuidado para limitar corretamente a visibilidade entre pacotes.
- Para simplificar a solução de erros na configuração de arquivos
BUILD
, verifique se o projeto continua a ser compilado com o Bazel à medida que você adiciona cada arquivo. Executebazel build //...
para garantir que todos os destinos ainda sejam criados.
4. Criar usando o Bazel
Você está compilando usando o Bazel à medida que adiciona arquivos BUILD
para validar a configuração
do build.
Quando você tem arquivos BUILD
com a granularidade desejada, pode usar o Bazel para produzir todas as suas builds.