Migra de Maven a Bazel

Informar un problema Ver código fuente Nightly · 8.0 · 7.4 · 7.3 · 7.2 · 7.1 · 7.0 · 6.5

En esta página, se describe cómo migrar de Maven a Bazel, incluidos los requisitos previos y los pasos de instalación. Describe las diferencias entre Maven y Bazel, y proporciona un ejemplo de migración con el proyecto Guava.

Cuando migres de cualquier herramienta de compilación a Bazel, es mejor que ambas herramientas de compilación se ejecuten en paralelo hasta que hayas migrado por completo tu equipo de desarrollo, el sistema de CI y cualquier otro sistema relevante. Puedes ejecutar Maven y Bazel en el mismo repositorio.

Antes de comenzar

  • Instala Bazel si aún no lo hiciste.
  • Si es la primera vez que usas Bazel, consulta el instructivo Introducción a Bazel: compila Java antes de comenzar a migrar. En el instructivo, se explican los conceptos, la estructura y la sintaxis de las etiquetas de Bazel.

Diferencias entre Maven y Bazel

  • Maven usa archivos pom.xml de nivel superior. Bazel admite varios archivos de compilación y varios destinos por archivo BUILD, lo que permite compilaciones más incrementales que las de Maven.
  • Maven se encarga de los pasos del proceso de implementación. Bazel no automatiza la implementación.
  • Bazel te permite expresar dependencias entre idiomas.
  • A medida que agregues secciones nuevas al proyecto, es posible que debas agregar archivos BUILD nuevos con Bazel. La práctica recomendada es agregar un archivo BUILD a cada paquete Java nuevo.

Cómo migrar de Maven a Bazel

En los siguientes pasos, se describe cómo migrar tu proyecto a Bazel:

  1. Cómo crear el archivo WORKSPACE
  2. Crea un archivo BUILD
  3. Cómo crear más archivos BUILD
  4. Cómo compilar con Bazel

Los ejemplos que se muestran a continuación provienen de una migración del proyecto Guava de Maven a Bazel. El proyecto de Guava que se usa es la versión v31.1. Los ejemplos que usan Guava no explican cada paso de la migración, pero muestran los archivos y el contenido que se generan o agregan de forma manual para la migración.

$ git clone https://github.com/google/guava.git && cd guava
$ git checkout v31.1

1. Crea el archivo WORKSPACE

Crea un archivo llamado WORKSPACE en la raíz de tu proyecto. Si tu proyecto no tiene dependencias externas, el archivo del lugar de trabajo puede estar vacío.

Si tu proyecto depende de archivos o paquetes que no están en uno de los directorios del proyecto, especifica estas dependencias externas en el archivo del espacio de trabajo. Para automatizar la lista de dependencias externas del archivo de espacio de trabajo, usa rules_jvm_external. Para obtener instrucciones sobre el uso de este conjunto de reglas, consulta el archivo README.

Ejemplo de proyecto de Guava: dependencias externas

Puedes enumerar las dependencias externas del proyecto Guava con el conjunto de reglas rules_jvm_external.

Agrega el siguiente fragmento al archivo WORKSPACE:

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

RULES_JVM_EXTERNAL_TAG = "4.3"
RULES_JVM_EXTERNAL_SHA = "6274687f6fc5783b589f56a2f1ed60de3ce1f99bc4e8f9edef3de43bdf7c6e74"

http_archive(
    name = "rules_jvm_external",
    sha256 = RULES_JVM_EXTERNAL_SHA,
    strip_prefix = "rules_jvm_external-%s" % RULES_JVM_EXTERNAL_TAG,
    url = "https://github.com/bazelbuild/rules_jvm_external/archive/%s.zip" % RULES_JVM_EXTERNAL_TAG,
)

load("@rules_jvm_external//:defs.bzl", "maven_install")

maven_install(
    artifacts = [
        "com.google.code.findbugs:jsr305:3.0.2",
        "com.google.errorprone:error_prone_annotations:2.11.0",
        "com.google.j2objc:j2objc-annotations:1.3",
        "org.codehaus.mojo:animal-sniffer-annotations:1.20",
        "org.checkerframework:checker-qual:3.12.0",
    ],
    repositories = [
        "https://repo1.maven.org/maven2",
    ],
)

2. Crea un archivo BUILD

Ahora que tienes definido tu lugar de trabajo y se enumeran las dependencias externas (si corresponde), debes crear archivos BUILD para describir cómo se debe compilar tu proyecto. A diferencia de Maven, que tiene un solo archivo pom.xml, Bazel puede usar muchos archivos BUILD para compilar un proyecto. Estos archivos especifican varios destinos de compilación, que permiten que Bazel produzca compilaciones incrementales.

Agrega archivos BUILD en etapas. Comienza por agregar un archivo BUILD en la raíz de tu proyecto y úsalo para realizar una compilación inicial con Bazel. Luego, puedes definir mejor tu compilación agregando más archivos BUILD con objetivos más detallados.

  1. En el mismo directorio que el archivo WORKSPACE, crea un archivo de texto y cámbiale el nombre a BUILD.

  2. En este archivo BUILD, usa la regla adecuada para crear un destino para compilar tu proyecto. A continuación, se incluyen algunas sugerencias:

    • Usa la regla adecuada:

      • Para compilar proyectos con un solo módulo de Maven, usa la regla java_library de la siguiente manera:

        java_library(
    name = "everything",
    srcs = glob(["src/main/java/**/*.java"]),
    resources = glob(["src/main/resources/**"]),
    deps = ["//:all-external-targets"],
)

      • Para compilar proyectos con varios módulos de Maven, usa la regla java_library de la siguiente manera:

        java_library(
    name = "everything",
    srcs = glob([
        "Module1/src/main/java/**/*.java",
        "Module2/src/main/java/**/*.java",
        ...
    ]),
    resources = glob([
        "Module1/src/main/resources/**",
        "Module2/src/main/resources/**",
        ...
    ]),
    deps = ["//:all-external-targets"],
)

      • Para compilar objetos binarios, usa la regla java_binary:

        java_binary(
    name = "everything",
    srcs = glob(["src/main/java/**/*.java"]),
    resources = glob(["src/main/resources/**"]),
    deps = ["//:all-external-targets"],
    main_class = "com.example.Main"
)

    • Especifica los atributos:

      • name: Asigna un nombre significativo al objetivo. En los ejemplos anteriores, el objetivo se denomina "todo".
      • srcs: Usa globbing para enumerar todos los archivos .java de tu proyecto.
      • resources: Usa globbing para enumerar todos los recursos de tu proyecto.
      • deps: Debes determinar qué dependencias externas necesita tu proyecto. Por ejemplo, si generaste una lista de dependencias externas con la herramienta generate_workspace, las dependencias de java_library son las bibliotecas que se enumeran en la macro generated_java_libraries.

    • Consulta el ejemplo a continuación de este archivo BUILD de nivel superior de la migración del proyecto Guava.

  3. Ahora que tienes un archivo BUILD en la raíz de tu proyecto, compila tu proyecto para asegurarte de que funcione. En la línea de comandos, desde el directorio de tu espacio de trabajo, usa bazel build //:everything para compilar tu proyecto con Bazel.

    El proyecto se compiló correctamente con Bazel. Deberás agregar más archivos BUILD para permitir compilaciones incrementales del proyecto.

Ejemplo de proyecto de Guava: comienza con un archivo BUILD

Cuando se migra el proyecto Guava a Bazel, inicialmente se usa un archivo BUILD para compilar todo el proyecto. Este es el contenido de este archivo BUILD inicial en el directorio del espacio de trabajo:

java_library(
    name = "everything",
    srcs = glob([
        "guava/src/**/*.java",
        "futures/failureaccess/src/**/*.java",
    ]),
    deps = [
        "@maven//:com_google_code_findbugs_jsr305",
        "@maven//:com_google_errorprone_error_prone_annotations",
        "@maven//:com_google_j2objc_j2objc_annotations",
        "@maven//:org_checkerframework_checker_qual",
        "@maven//:org_codehaus_mojo_animal_sniffer_annotations",
    ],
)

3. Crea más archivos BUILD (opcional)

Bazel funciona con un solo BUILD file, como viste después de completar tu primera compilación. Aún debes considerar dividir la compilación en partes más pequeñas agregando más archivos BUILD con objetivos detallados.

Varios archivos BUILD con varios destinos le darán a la compilación mayor granularidad, lo que permitirá lo siguiente:

  • aumento de las compilaciones incrementales del proyecto
  • mayor ejecución en paralelo de la compilación
  • una mejor capacidad de mantenimiento de la compilación para los usuarios futuros
  • control sobre la visibilidad de los destinos entre paquetes, lo que puede evitar problemas, como bibliotecas que contienen detalles de implementación que se filtran en las APIs públicas.

Sugerencias para agregar más archivos BUILD:

  • Puedes comenzar por agregar un archivo BUILD a cada paquete de Java. Comienza con los paquetes de Java que tienen menos dependencias y avanza hasta los paquetes con más dependencias.
  • A medida que agregues archivos BUILD y especifiques destinos, agrega estos destinos nuevos a las secciones deps de los destinos que dependen de ellos. Ten en cuenta que la función glob() no cruza los límites de los paquetes, por lo que, a medida que aumenta la cantidad de paquetes, se reducirán los archivos que coincidan con glob().
  • Cada vez que agregues un archivo BUILD a un directorio main, asegúrate de agregar un archivo BUILD al directorio test correspondiente.
  • Ten cuidado de limitar la visibilidad correctamente entre los paquetes.
  • Para simplificar la solución de problemas en la configuración de archivos BUILD, asegúrate de que el proyecto siga compilándose con Bazel a medida que agregas cada archivo de compilación. Ejecuta bazel build //... para asegurarte de que se sigan compilando todos tus destinos.

4. Cómo compilar con Bazel

Has estado compilando con Bazel a medida que agregas archivos BUILD para validar la configuración de la compilación.

Cuando tengas archivos BUILD con el nivel de detalle deseado, puedes usar Bazel para producir todas tus compilaciones.