규칙

문제 신고하기 소스 보기

규칙은 Bazel이 출력 세트를 생성하기 위해 입력에 수행하는 일련의 작업을 정의합니다. 이러한 작업은 규칙의 구현 함수에서 반환된 providers에서 이 작업을 참조합니다. 예를 들어 C++ 바이너리 규칙은 다음과 같을 수 있습니다.

1. .cpp 소스 파일 (입력) 집합을 가져옵니다.
2. 소스 파일에서 g++를 실행합니다 (작업).
3. 실행 가능한 출력 및 기타 파일과 함께 DefaultInfo 제공자를 반환하여 런타임에 제공합니다.
4. 타겟 및 종속 항목에서 수집한 C++ 관련 정보가 있는 CcInfo 제공자를 반환합니다.

Bazel의 관점에서 볼 때 g++ 및 표준 C++ 라이브러리도 이 규칙의 입력입니다. 규칙 작성자는 규칙에 대한 사용자가 제공한 입력뿐 아니라 작업을 실행하는 데 필요한 모든 도구와 라이브러리를 고려해야 합니다.

규칙을 만들거나 수정하기 전에 Bazel의 빌드 단계를 숙지해야 합니다. 빌드의 세 단계 (로드, 분석, 실행)를 이해하는 것이 중요합니다. 규칙과 매크로의 차이를 이해하려면 매크로에 대해 알아두는 것도 도움이 됩니다. 시작하려면 먼저 규칙 튜토리얼을 검토합니다. 그런 다음 이 페이지를 참고하시기 바랍니다.

Bazel 자체에 몇 가지 규칙이 내장되어 있습니다. cc_library 및 java_binary와 같은 이러한 네이티브 규칙은 특정 언어에 몇 가지 핵심 지원을 제공합니다. 자체 규칙을 정의하여 Bazel이 기본적으로 지원하지 않는 언어 및 도구에 대한 유사한 지원을 추가할 수 있습니다.

Bazel은 Starlark 언어를 사용하여 규칙을 작성하기 위한 확장성 모델을 제공합니다. 이러한 규칙은 .bzl 파일로 작성되며 BUILD 파일에서 직접 로드할 수 있습니다.

자체 규칙을 정의할 때는 규칙이 지원하는 속성과 출력 생성 방법을 결정해야 합니다.

규칙의 implementation 함수는 분석 단계 동안 정확한 동작을 정의합니다. 이 함수는 외부 명령어를 실행하지 않습니다. 대신 필요한 경우 실행 단계 후반에 규칙 출력을 빌드하는 데 사용할 작업을 등록합니다.

규칙 생성

.bzl 파일에서 rule 함수를 사용하여 새 규칙을 정의하고 결과를 전역 변수에 저장합니다. rule 호출은 속성과 구현 함수를 지정합니다.

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        "deps": attr.label_list(),
        ...
    },
)

이는 example_library이라는 규칙의 종류를 정의합니다.

또한 rule 호출은 규칙이 실행 가능한 출력 (executable=True 포함)을 생성하는지 아니면 구체적으로 테스트 실행 파일 (test=True 사용)을 생성하는지 지정해야 합니다. 후자의 경우 규칙은 테스트 규칙이고 규칙의 이름은 _test로 끝나야 합니다.

타겟 인스턴스화

규칙은 BUILD 파일에서 로드하고 호출할 수 있습니다.

load('//some/pkg:rules.bzl', 'example_library')

example_library(
    name = "example_target",
    deps = [":another_target"],
    ...
)

빌드 규칙을 호출할 때마다 값이 반환되지 않지만 타겟을 정의하는 부작용이 있습니다. 이를 규칙 인스턴스화라고 합니다. 새 타겟의 이름과 타겟의 속성 값을 지정합니다.

규칙은 Starlark 함수에서 호출하여 .bzl 파일에 로드할 수도 있습니다. 규칙을 호출하는 Starlark 함수를 Starlark 매크로라고 합니다. Starlark 매크로는 궁극적으로 BUILD 파일에서 호출되어야 하며 BUILD 파일이 타겟을 인스턴스화하도록 평가되는 로드 단계 중에만 호출할 수 있습니다.

특성

속성은 규칙 인수입니다. 속성은 대상의 구현에 특정 값을 제공하거나 다른 대상을 참조하여 종속 항목 그래프를 만들 수 있습니다.

규칙별 속성(예: srcs 또는 deps)은 속성 이름에서 스키마(attr 모듈을 사용하여 만든)의 매핑을 rule의 attrs 매개변수에 전달하여 정의합니다. name 및 visibility과 같은 공통 속성은 모든 규칙에 암시적으로 추가됩니다. 추가 속성은 특히 실행 가능 규칙 및 테스트 규칙에 암시적으로 추가됩니다. 규칙에 암시적으로 추가되는 속성은 attrs에 전달되는 사전에 포함될 수 없습니다.

종속 항목 속성

소스 코드를 처리하는 규칙은 일반적으로 다양한 종속 항목 유형을 처리하기 위해 다음 속성을 정의합니다.

• srcs는 대상의 작업으로 처리되는 소스 파일을 지정합니다. 속성 스키마는 규칙이 처리하는 소스 파일 종류에 예상되는 파일 확장자를 지정하는 경우가 많습니다. 헤더 파일이 있는 언어 규칙은 일반적으로 타겟과 그 소비자가 처리하는 헤더에 별도의 hdrs 속성을 지정합니다.
• deps는 타겟의 코드 종속 항목을 지정합니다. 속성 스키마는 이러한 종속 항목이 제공해야 하는 제공자를 지정해야 합니다. 예를 들어 cc_library는 CcInfo를 제공합니다.
• data은 타겟에 종속된 모든 실행 파일이 런타임에 사용할 수 있도록 할 파일을 지정합니다. 그러면 임의의 파일을 지정할 수 있습니다.

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        "srcs": attr.label_list(allow_files = [".example"]),
        "hdrs": attr.label_list(allow_files = [".header"]),
        "deps": attr.label_list(providers = [ExampleInfo]),
        "data": attr.label_list(allow_files = True),
        ...
    },
)

다음은 종속 항목 속성의 예입니다. 입력 라벨을 지정하는 모든 속성 (attr.label_list, attr.label 또는 attr.label_keyed_string_dict로 정의된 속성)은 타겟과 타겟이 정의되었을 때 라벨 (또는 상응하는 Label 객체)이 해당 속성에 나열되는 타겟 사이의 특정 유형의 종속 항목을 지정합니다. 이러한 라벨의 저장소 및 경로는 정의된 타겟을 기준으로 확인됩니다.

example_library(
    name = "my_target",
    deps = [":other_target"],
)

example_library(
    name = "other_target",
    ...
)

이 예에서 other_target는 my_target의 종속 항목이므로 other_target가 먼저 분석됩니다. 대상의 종속 항목 그래프에 주기가 있으면 오류입니다.

비공개 속성 및 암시적 종속 항목

기본값이 있는 종속 항목 속성은 암시적 종속 항목을 생성합니다. 사용자가 BUILD 파일에 지정하지 않는 타겟 그래프의 일부이기 때문에 암시적입니다. 대부분의 경우 사용자는 규칙에서 사용하는 도구를 지정하는 데 관심이 없으므로 암시적 종속 항목은 규칙과 도구 (컴파일러와 같은 빌드 시간 종속 항목) 간의 관계를 하드 코딩하는 데 유용합니다. 이는 규칙의 구현 함수 내에서 다른 종속 항목과 동일하게 처리됩니다.

사용자가 해당 값을 재정의하도록 허용하지 않고 암시적 종속 항목을 제공하려면 밑줄 (_)로 시작하는 이름을 지정하여 속성을 private으로 설정하면 됩니다. 비공개 속성에는 기본값이 있어야 합니다. 일반적으로 암시적 종속 항목에는 비공개 속성을 사용하는 것이 합리적입니다.

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        ...
        "_compiler": attr.label(
            default = Label("//tools:example_compiler"),
            allow_single_file = True,
            executable = True,
            cfg = "exec",
        ),
    },
)

이 예에서 example_library 유형의 모든 타겟에는 컴파일러 //tools:example_compiler에 관한 암시적 종속 항목이 있습니다. 이렇게 하면 사용자가 라벨을 입력으로 전달하지 않았더라도 example_library의 구현 함수에서 컴파일러를 호출하는 작업을 생성할 수 있습니다. _compiler는 비공개 속성이므로 이 규칙 유형의 모든 대상에서 ctx.attr._compiler는 항상 //tools:example_compiler을 가리킵니다. 또는 밑줄 없이 속성 이름을 compiler로 지정하고 기본값을 유지할 수 있습니다. 이렇게 하면 필요한 경우 사용자가 다른 컴파일러를 대체할 수 있지만 컴파일러의 라벨을 인식할 필요는 없습니다.

암시적 종속 항목은 일반적으로 규칙 구현과 동일한 저장소에 있는 도구에 사용됩니다. 도구가 실행 플랫폼 또는 다른 저장소에서 제공되는 경우 규칙은 도구 모음에서 이 도구를 가져와야 합니다.

출력 속성

출력 속성(예: attr.output 및 attr.output_list)은 타겟이 생성하는 출력 파일을 선언합니다. 이는 종속 항목 속성과는 두 가지 측면에서 다릅니다.

• 다른 곳에 정의된 타겟을 참조하는 대신 출력 파일 타겟을 정의합니다.
• 출력 파일 대상은 그 반대가 아닌 인스턴스화된 규칙 대상에 종속됩니다.

일반적으로 출력 속성은 규칙이 대상 이름을 기반으로 할 수 없는 사용자 정의 이름으로 출력을 생성해야 하는 경우에만 사용됩니다. 규칙에 출력 속성이 한 개 있으면 일반적으로 이름이 out 또는 outs로 지정됩니다.

출력 속성은 사전 선언된 출력을 만드는 데 선호되는 방법이며, 구체적으로 종속되거나 명령줄에서 요청될 수 있습니다.

구현 함수

모든 규칙에는 implementation 함수가 필요합니다. 이러한 함수는 분석 단계에서 엄격하게 실행되며 로드 단계에서 생성된 타겟의 그래프를 실행 단계 중에 실행할 작업 그래프로 변환합니다. 따라서 구현 함수는 실제로 파일을 읽거나 쓸 수 없습니다.

규칙 구현 함수는 일반적으로 비공개입니다 (이름 앞에 밑줄이 표시됨). 일반적으로 이름은 규칙과 동일하지만 _impl가 접미사로 붙습니다.

구현 함수에서는 일반적으로 ctx라는 규칙 컨텍스트라는 매개변수를 정확히 하나만 사용합니다. 제공업체 목록을 반환합니다.

대상

종속 항목은 분석 시간에 Target 객체로 표시됩니다. 이러한 객체에는 타겟의 구현 함수가 실행될 때 생성되는 제공자가 포함됩니다.

ctx.attr에는 각 종속 항목 속성의 이름에 해당하는 필드가 있으며, 이 속성을 통해 각 직접 종속 항목을 나타내는 Target 객체가 포함되어 있습니다. label_list 속성의 경우 Targets 목록입니다. label 속성의 경우 단일 Target 또는 None입니다.

제공자 객체의 목록은 타겟의 구현 함수에 의해 반환됩니다.

return [ExampleInfo(headers = depset(...))]

이러한 항목은 제공자 유형을 키로 사용한 색인 표기법 ([])을 사용하여 액세스할 수 있습니다. Starlark에서 정의된 커스텀 제공자 또는 Starlark 전역 변수로 사용할 수 있는 네이티브 규칙용 제공자일 수 있습니다.

예를 들어 규칙이 hdrs 속성을 통해 헤더 파일을 가져와서 타겟과 그 소비자의 컴파일 작업에 제공하면 다음과 같이 헤더를 수집할 수 있습니다.

def _example_library_impl(ctx):
    ...
    transitive_headers = [hdr[ExampleInfo].headers for hdr in ctx.attr.hdrs]

struct가 제공자 객체 목록 대신 타겟의 구현 함수에서 반환되는 기존 스타일의 경우:

return struct(example_info = struct(headers = depset(...)))

Target 객체의 해당 필드에서 제공자를 가져올 수 있습니다.

transitive_headers = [hdr.example_info.headers for hdr in ctx.attr.hdrs]

이 스타일은 사용하지 않는 것이 좋으며, 규칙은 이 스타일에서 이전해야 합니다.

파일

파일은 File 객체로 표현됩니다. Bazel은 분석 단계 중에는 파일 I/O를 수행하지 않으므로 이러한 객체를 사용하여 파일 콘텐츠를 직접 읽거나 쓸 수 없습니다. 대신 작업을 내보내는 함수 (ctx.actions 참고)로 전달되어 작업 그래프의 조각을 구성합니다.

File은 소스 파일이거나 생성된 파일일 수 있습니다. 생성되는 각 파일은 정확히 하나의 작업으로 출력되어야 합니다. 소스 파일은 작업의 출력이 될 수 없습니다.

각 종속 항목 속성의 경우 ctx.files의 상응하는 필드에는 해당 속성을 통한 모든 종속 항목의 기본 출력 목록이 포함됩니다.

def _example_library_impl(ctx):
    ...
    headers = depset(ctx.files.hdrs, transitive=transitive_headers)
    srcs = ctx.files.srcs
    ...

ctx.file에는 사양이 allow_single_file=True로 설정된 종속 항목 속성의 단일 File 또는 None가 포함됩니다. ctx.executable는 ctx.file와 동일하게 작동하지만 사양이 executable=True로 설정된 종속 항목 속성의 필드만 포함합니다.

출력 선언

분석 단계에서는 규칙의 구현 함수가 출력을 생성할 수 있습니다. 로드 단계에서 모든 라벨을 알아야 하므로 이러한 추가 출력에는 라벨이 없습니다. 출력의 File 객체는 ctx.actions.declare_file 및 ctx.actions.declare_directory를 사용하여 만들 수 있습니다. 출력 이름은 대상의 이름 ctx.label.name를 기반으로 하는 경우가 많습니다.

def _example_library_impl(ctx):
  ...
  output_file = ctx.actions.declare_file(ctx.label.name + ".output")
  ...

출력 속성용으로 생성된 출력과 같은 사전 선언된 출력의 경우 File 객체를 ctx.outputs의 상응하는 필드에서 가져올 수 있습니다.

작업

작업은 입력 세트에서 출력 세트를 생성하는 방법을 설명합니다(예: 'hello.c에서 gcc를 실행하고 hello.o 가져오기'). 작업이 만들어지면 Bazel이 명령어를 즉시 실행하지 않습니다. 작업이 다른 작업의 출력에 종속될 수 있으므로 종속 항목 그래프에 등록합니다. 예를 들어 C에서 링커는 컴파일러 이후에 호출해야 합니다.

작업을 만드는 범용 함수는 ctx.actions에 정의되어 있습니다.

• ctx.actions.run: 실행 파일을 실행합니다.
• 셸 명령어를 실행하는 ctx.actions.run_shell
• ctx.actions.write: 파일에 문자열을 작성합니다.
• ctx.actions.expand_template: 템플릿에서 파일을 생성합니다.

ctx.actions.args를 사용하면 작업의 인수를 효율적으로 누적할 수 있습니다. 실행 시간까지 depset을 평면화하지 않습니다.

def _example_library_impl(ctx):
    ...

    transitive_headers = [dep[ExampleInfo].headers for dep in ctx.attr.deps]
    headers = depset(ctx.files.hdrs, transitive=transitive_headers)
    srcs = ctx.files.srcs
    inputs = depset(srcs, transitive=[headers])
    output_file = ctx.actions.declare_file(ctx.label.name + ".output")

    args = ctx.actions.args()
    args.add_joined("-h", headers, join_with=",")
    args.add_joined("-s", srcs, join_with=",")
    args.add("-o", output_file)

    ctx.actions.run(
        mnemonic = "ExampleCompile",
        executable = ctx.executable._compiler,
        arguments = [args],
        inputs = inputs,
        outputs = [output_file],
    )
    ...

작업은 입력 파일의 목록 또는 depset를 취하여 출력 파일 목록 (비어 있지 않음)을 생성합니다. 입력 및 출력 파일 세트는 분석 단계 중에 알려져 있어야 합니다. 종속 항목의 제공자를 비롯한 속성 값에는 의존할 수 있지만 실행 결과에는 의존할 수 없습니다. 예를 들어 작업에서 unzip 명령어를 실행하는 경우 압축 해제를 실행하기 전에 확장할 것으로 예상되는 파일을 지정해야 합니다. 내부적으로 가변적인 수의 파일을 생성하는 작업은 이러한 파일을 단일 파일 (예: zip, tar 또는 기타 보관 파일)로 래핑할 수 있습니다.

작업은 모든 입력을 나열해야 합니다. 사용되지 않는 입력 나열은 허용되지만 비효율적입니다.

작업은 모든 출력을 생성해야 합니다. 다른 파일을 쓸 수 있지만 출력에 없는 항목은 소비자가 사용할 수 없습니다. 선언된 모든 출력은 일부 작업으로 작성되어야 합니다.

작업은 순수한 함수와 유사합니다. 제공된 입력에만 종속되어야 하고 컴퓨터 정보, 사용자 이름, 시계, 네트워크 또는 I/O 기기 (입력 읽기 및 쓰기 출력 제외)에 액세스하지 않아야 합니다. 출력이 캐시되고 재사용되기 때문에 이 작업이 중요합니다.

종속 항목은 실행되는 작업을 결정하는 Bazel에 의해 결정됩니다. 종속 항목 그래프에 주기가 있으면 오류입니다. 작업을 만든다고 해서 실행이 보장되지는 않으며, 이는 출력이 빌드에 필요한지에 따라 달라집니다.

제공업체

제공자는 규칙에서 이에 의존하는 다른 규칙에 노출하는 정보입니다. 이 데이터에는 출력 파일, 라이브러리, 도구의 명령줄에 전달할 매개변수 또는 타겟의 소비자가 알아야 하는 다른 모든 것이 포함될 수 있습니다.

규칙의 구현 함수는 인스턴스화된 타겟의 즉각적인 종속 항목에서만 제공자를 읽을 수 있으므로 규칙은 일반적으로 타겟의 소비자가 알아야 하는 타겟의 종속 항목 정보를 모두 depset에 누적하여 전달해야 합니다.

타겟의 제공자는 구현 함수에서 반환된 Provider 객체 목록으로 지정됩니다.

구현 함수가 제공자 객체 목록 대신 struct을 반환하는 기존 스타일로 이전 구현 함수를 작성할 수도 있습니다. 이 스타일은 사용하지 않는 것이 좋으며, 규칙은 이 스타일에서 이전해야 합니다.

기본 출력

타겟의 기본 출력은 타겟이 명령줄에서 빌드를 요청할 때 기본적으로 요청되는 출력입니다. 예를 들어 java_library 타겟 //pkg:foo에는 foo.jar가 기본 출력이므로 bazel build //pkg:foo 명령어로 빌드됩니다.

기본 출력은 DefaultInfo의 files 매개변수로 지정됩니다.

def _example_library_impl(ctx):
    ...
    return [
        DefaultInfo(files = depset([output_file]), ...),
        ...
    ]

규칙 구현에서 DefaultInfo가 반환되지 않거나 files 매개변수가 지정되지 않은 경우 DefaultInfo.files는 기본적으로 모든 사전 선언된 출력 (일반적으로 출력 속성에서 생성되는 출력)으로 설정됩니다.

작업을 실행하는 규칙은 이러한 출력이 직접 사용될 것으로 예상되지 않더라도 기본 출력을 제공해야 합니다. 요청된 출력의 그래프에 없는 작업은 프루닝됩니다. 타겟의 소비자만 출력을 사용하는 경우 타겟이 격리된 상태로 빌드되면 해당 작업이 수행되지 않습니다. 이렇게 하면 실패한 타겟만 다시 빌드해도 오류가 재현되지 않으므로 디버깅이 더 어려워집니다.

실행 파일

실행 파일은 빌드 시간이 아닌 런타임 시 타겟에서 사용하는 파일 집합입니다. 실행 단계 중에 Bazel은 실행 파일을 가리키는 심볼릭 링크를 포함하는 디렉터리 트리를 만듭니다. 이렇게 하면 런타임 중에 실행 파일에 액세스할 수 있도록 바이너리의 환경이 스테이징됩니다.

규칙 생성 중에 실행 파일을 수동으로 추가할 수 있습니다. runfiles 객체는 규칙 컨텍스트 ctx.runfiles의 runfiles 메서드로 만들어 DefaultInfo의 runfiles 매개변수로 전달할 수 있습니다. 실행 가능 규칙의 실행 가능한 출력은 실행 파일에 암시적으로 추가됩니다.

일부 규칙은 일반적으로 이름이 data인 속성을 지정하며 이 속성의 출력이 대상의 실행 파일에 추가됩니다. 실행 파일은 또한 data는 물론 최종 실행의 코드를 제공할 수 있는 속성(일반적으로 srcs(연결된 data가 있는 filegroup 타겟 포함 가능) 및 deps)에서도 병합되어야 합니다.

def _example_library_impl(ctx):
    ...
    runfiles = ctx.runfiles(files = ctx.files.data)
    transitive_runfiles = []
    for runfiles_attr in (
        ctx.attr.srcs,
        ctx.attr.hdrs,
        ctx.attr.deps,
        ctx.attr.data,
    ):
        for target in runfiles_attr:
            transitive_runfiles.append(target[DefaultInfo].default_runfiles)
    runfiles = runfiles.merge_all(transitive_runfiles)
    return [
        DefaultInfo(..., runfiles = runfiles),
        ...
    ]

커스텀 제공업체

provider 함수를 사용하여 규칙별 정보를 전달하는 제공자를 정의할 수 있습니다.

ExampleInfo = provider(
    "Info needed to compile/link Example code.",
    fields={
        "headers": "depset of header Files from transitive dependencies.",
        "files_to_link": "depset of Files from compilation.",
    })

그러면 규칙 구현 함수에서 제공자 인스턴스를 구성하고 반환할 수 있습니다.

def _example_library_impl(ctx):
  ...
  return [
      ...
      ExampleInfo(
          headers = headers,
          files_to_link = depset(
              [output_file],
              transitive = [
                  dep[ExampleInfo].files_to_link for dep in ctx.attr.deps
              ],
          ),
      )
  ]

제공자 커스텀 초기화

맞춤 사전 처리 및 유효성 검사 로직을 사용하여 제공자의 인스턴스화를 보호할 수 있습니다. 이는 모든 제공업체 인스턴스가 특정 불변 항목을 준수하도록 하거나 사용자에게 인스턴스를 획득하기 위한 더 명확한 API를 제공하는 데 사용할 수 있습니다.

init 콜백을 provider 함수에 전달하면 됩니다. 이 콜백이 제공되면 provider()의 반환 유형은 두 값, 즉 init가 사용되지 않을 때 일반 반환 값인 제공자 기호와 '원시 생성자'의 튜플로 변경됩니다.

이 경우 제공자 기호가 호출되면 새 인스턴스를 직접 반환하는 대신 인수를 init 콜백에 전달합니다. 콜백의 반환 값은 필드 이름 (문자열)을 값에 매핑하는 dict여야 합니다. 이 값은 새 인스턴스의 필드를 초기화하는 데 사용됩니다. 콜백에는 서명이 있을 수 있으며 인수가 서명과 일치하지 않으면 콜백이 직접 호출된 것처럼 오류가 보고됩니다.

반면에 원시 생성자는 init 콜백을 우회합니다.

다음 예에서는 init를 사용하여 인수를 전처리하고 검증합니다.

# //pkg:exampleinfo.bzl

_core_headers = [...]  # private constant representing standard library files

# It's possible to define an init accepting positional arguments, but
# keyword-only arguments are preferred.
def _exampleinfo_init(*, files_to_link, headers = None, allow_empty_files_to_link = False):
    if not files_to_link and not allow_empty_files_to_link:
        fail("files_to_link may not be empty")
    all_headers = depset(_core_headers, transitive = headers)
    return {'files_to_link': files_to_link, 'headers': all_headers}

ExampleInfo, _new_exampleinfo = provider(
    ...
    init = _exampleinfo_init)

export ExampleInfo

그러면 규칙 구현이 다음과 같이 제공자를 인스턴스화할 수 있습니다.

    ExampleInfo(
        files_to_link=my_files_to_link,  # may not be empty
        headers = my_headers,  # will automatically include the core headers
    )

원시 생성자를 사용하여 init 로직을 통하지 않는 대체 공개 팩토리 함수를 정의할 수 있습니다. 예를 들어 exampleinfo.bzl에서는 다음과 같이 정의할 수 있습니다.

def make_barebones_exampleinfo(headers):
    """Returns an ExampleInfo with no files_to_link and only the specified headers."""
    return _new_exampleinfo(files_to_link = depset(), headers = all_headers)

일반적으로 원시 생성자는 이름이 밑줄 (위 _new_exampleinfo)으로 시작되는 변수에 바인딩되므로 사용자 코드가 생성자를 로드하고 임의의 제공자 인스턴스를 생성할 수 없습니다.

init의 또 다른 용도는 단순히 사용자가 제공자 기호를 전혀 호출하지 못하게 하고 대신 팩토리 함수를 사용하도록 강제하는 것입니다.

def _exampleinfo_init_banned(*args, **kwargs):
    fail("Do not call ExampleInfo(). Use make_exampleinfo() instead.")

ExampleInfo, _new_exampleinfo = provider(
    ...
    init = _exampleinfo_init_banned)

def make_exampleinfo(...):
    ...
    return _new_exampleinfo(...)

실행 가능한 규칙 및 테스트 규칙

실행 가능한 규칙은 bazel run 명령어로 호출할 수 있는 대상을 정의합니다. 테스트 규칙은 bazel test 명령어로도 대상을 호출할 수 있는 특수한 종류의 실행 가능한 규칙입니다. rule 호출에서 각각의 executable 또는 test 인수를 True로 설정하여 실행 가능 규칙과 테스트 규칙을 만듭니다.

example_binary = rule(
   implementation = _example_binary_impl,
   executable = True,
   ...
)

example_test = rule(
   implementation = _example_binary_impl,
   test = True,
   ...
)

테스트 규칙의 이름은 _test로 끝나야 합니다. 테스트 타겟 이름도 규칙에 따라 _test로 끝나는 경우가 많지만 반드시 그럴 필요는 없습니다. 테스트가 아닌 규칙에는 이 접미사가 없어야 합니다.

두 규칙 모두 run 또는 test 명령어에 의해 호출되는 실행 가능한 출력 파일 (사전 선언되거나 선언되지 않을 수 있음)을 생성해야 합니다. 이 실행 파일로 사용할 규칙의 출력을 Bazel에 알리려면 이를 반환된 DefaultInfo 제공자의 executable 인수로 전달합니다. executable가 규칙의 기본 출력에 추가되므로 executable와 files에 모두 전달할 필요가 없습니다. 또한 암시적으로 runfiles에 추가됩니다.

def _example_binary_impl(ctx):
    executable = ctx.actions.declare_file(ctx.label.name)
    ...
    return [
        DefaultInfo(executable = executable, ...),
        ...
    ]

이 파일을 생성하는 작업은 파일에서 실행 가능 비트를 설정해야 합니다. ctx.actions.run 또는 ctx.actions.run_shell 작업의 경우 이 작업에서 호출되는 기본 도구를 통해 실행해야 합니다. ctx.actions.write 작업의 경우 is_executable=True를 전달합니다.

레거시 동작으로, 실행 가능한 규칙에는 특수한 ctx.outputs.executable가 미리 선언된 출력이 있습니다. 이 파일은 DefaultInfo를 사용하여 지정하지 않으면 기본 실행 파일 역할을 하며, 달리 사용해서는 안 됩니다. 이 출력 메커니즘은 분석 시 실행 파일의 이름 맞춤설정을 지원하지 않으므로 지원 중단되었습니다.

실행 가능한 규칙 및 테스트 규칙의 예를 참고하세요.

실행 가능 규칙과 테스트 규칙에는 모든 규칙에 추가된 속성 외에도 암시적으로 정의된 추가 속성이 있습니다. 암시적으로 추가된 속성의 기본값은 변경할 수 없지만 기본값을 변경하는 Starlark 매크로에서 비공개 규칙을 래핑하여 해결할 수 있습니다.

def example_test(size="small", **kwargs):
  _example_test(size=size, **kwargs)

_example_test = rule(
 ...
)

실행 파일 위치

실행 파일 타겟이 bazel run (또는 test)로 실행되면 실행 파일 디렉터리의 루트가 실행 파일에 인접합니다. 경로는 다음과 같습니다.

# Given launcher_path and runfile_file:
runfiles_root = launcher_path.path + ".runfiles"
workspace_name = ctx.workspace_name
runfile_path = runfile_file.short_path
execution_root_relative_path = "%s/%s/%s" % (
    runfiles_root, workspace_name, runfile_path)

실행 파일 디렉터리 아래의 File 경로는 File.short_path에 해당합니다.

bazel에서 직접 실행되는 바이너리는 runfiles 디렉터리의 루트에 인접합니다. 그러나 실행 파일 에서 호출된 바이너리는 동일한 가정을 할 수 없습니다. 이 문제를 완화하려면 각 바이너리가 환경 또는 명령줄 인수/플래그를 사용하여 실행 파일 루트를 매개변수로 허용하는 방법을 제공해야 합니다. 이렇게 하면 바이너리가 올바른 표준 실행 파일 루트를 호출하는 바이너리에 전달할 수 있습니다. 이를 설정하지 않으면 바이너리는 호출된 첫 번째 바이너리라고 추측할 수 있고 인접한 runfiles 디렉터리를 찾을 수 있습니다.

고급 주제

출력 파일 요청

단일 대상에는 여러 출력 파일이 있을 수 있습니다. bazel build 명령어가 실행되면 이 명령어에 지정된 타겟의 출력 중 일부가 요청된 것으로 간주됩니다. Bazel은 이렇게 요청된 파일과 이러한 파일이 직간접적으로 의존하는 파일만 빌드합니다. 작업 그래프의 경우 Bazel은 요청된 파일의 전이 종속 항목으로 연결할 수 있는 작업만 실행합니다.

기본 출력 외에도 사전 선언된 출력을 명령줄에서 명시적으로 요청할 수 있습니다. 규칙은 출력 속성을 통해 사전 선언된 출력을 지정할 수 있습니다. 이 경우 사용자는 규칙을 인스턴스화할 때 출력 라벨을 명시적으로 선택합니다. 출력 속성의 File 객체를 가져오려면 ctx.outputs의 상응하는 속성을 사용합니다. 규칙은 타겟 이름도 기반으로 사전 선언된 출력을 암시적으로 정의할 수 있지만 이 기능은 지원 중단되었습니다.

기본 출력 외에도 함께 요청할 수 있는 출력 파일 컬렉션인 출력 그룹이 있습니다. 이는 --output_groups로 요청할 수 있습니다. 예를 들어 대상 //pkg:mytarget가 debug_files 출력 그룹이 있는 규칙 유형인 경우 bazel build //pkg:mytarget --output_groups=debug_files를 실행하여 이러한 파일을 빌드할 수 있습니다. 사전 선언되지 않은 출력에는 라벨이 없으므로 기본 출력 또는 출력 그룹에 표시되는 방법으로만 요청할 수 있습니다.

출력 그룹은 OutputGroupInfo 제공자를 사용하여 지정할 수 있습니다. 대부분의 기본 제공 제공자와 달리 OutputGroupInfo는 임의의 이름의 매개변수를 사용하여 해당 이름으로 출력 그룹을 정의할 수 있습니다.

def _example_library_impl(ctx):
    ...
    debug_file = ctx.actions.declare_file(name + ".pdb")
    ...
    return [
        DefaultInfo(files = depset([output_file]), ...),
        OutputGroupInfo(
            debug_files = depset([debug_file]),
            all_files = depset([output_file, debug_file]),
        ),
        ...
    ]

또한 대부분의 제공자와 달리 OutputGroupInfo는 동일한 출력 그룹을 정의하지 않는 한 요소와 해당 측면이 적용되는 규칙 대상 모두에서 반환될 수 있습니다. 이 경우 결과 제공자가 병합됩니다.

일반적으로 OutputGroupInfo는 타겟에서 소비자의 동작으로 특정 종류의 파일을 전달하는 데 사용하면 안 됩니다. 대신 규칙별 제공업체를 정의하세요.

구성

다른 아키텍처용 C++ 바이너리를 빌드하려고 한다고 가정해 보겠습니다. 빌드는 복잡하고 여러 단계가 포함될 수 있습니다. 컴파일러 및 코드 생성기와 같은 일부 중간 바이너리는 실행 플랫폼 (호스트 또는 원격 실행자일 수 있음)에서 실행되어야 합니다. 최종 출력과 같은 일부 바이너리는 타겟 아키텍처에 맞게 빌드되어야 합니다.

이러한 이유로 Bazel에는 '구성' 및 전환이라는 개념이 있습니다. 최상위 대상 (명령줄에서 요청된 대상)은 '대상' 구성에서 빌드되는 반면, 실행 플랫폼에서 실행되어야 하는 도구는 'exec' 구성으로 빌드됩니다. 규칙은 구성에 따라 다른 작업을 생성할 수 있습니다(예: 컴파일러에 전달되는 CPU 아키텍처 변경). 경우에 따라 다른 구성에 동일한 라이브러리가 필요할 수 있습니다. 이 경우 객체가 분석되고 여러 번 빌드될 수 있습니다.

기본적으로 Bazel은 대상의 종속 항목을 대상 자체와 동일한 구성, 즉 전환 없이 빌드합니다. 종속 항목이 타겟을 빌드하는 데 필요한 도구인 경우 상응하는 속성은 exec 구성으로의 전환을 지정해야 합니다. 그러면 도구와 모든 종속 항목이 실행 플랫폼용으로 빌드됩니다.

각 종속 항목 속성에 cfg를 사용하여 종속 항목을 동일한 구성에서 빌드해야 하는지 또는 exec 구성으로 전환해야 하는지 결정할 수 있습니다. 종속 항목 속성에 executable=True 플래그가 있으면 cfg를 명시적으로 설정해야 합니다. 이는 잘못된 구성의 도구를 실수로 빌드하는 것을 방지하기 위한 것입니다. 예시 보기

일반적으로 런타임에 필요한 소스, 종속 라이브러리, 실행 파일은 동일한 구성을 사용할 수 있습니다.

빌드의 일부로 실행되는 도구 (예: 컴파일러 또는 코드 생성기)는 exec 구성용으로 빌드되어야 합니다. 이 경우 속성에 cfg="exec"를 지정합니다.

그렇지 않으면 런타임 시 사용되는 실행 파일 (예: 테스트의 일부로)을 타겟 구성에 맞게 빌드해야 합니다. 이 경우 속성에 cfg="target"를 지정합니다.

cfg="target"는 실제로 아무것도 하지 않습니다. 규칙 디자이너가 의도를 명시적으로 나타낼 수 있도록 하는 편의 값일 뿐입니다. executable=False인 경우(즉, cfg가 선택사항인 경우) 가독성에 실제로 도움이 되는 경우에만 설정합니다.

cfg=my_transition를 사용하여 사용자 정의 전환을 사용할 수도 있습니다. 이 기능을 사용하면 규칙 작성자가 훨씬 유연하게 구성을 변경할 수 있으며 빌드 그래프를 더 크고 이해하기 쉽도록 만들 수 있다는 단점이 있습니다.

참고: 지금까지 Bazel에는 실행 플랫폼 개념이 없었으며 대신 모든 빌드 작업이 호스트 머신에서 실행되는 것으로 간주되었습니다. 6.0 이전의 Bazel 버전에서는 이를 나타내기 위해 고유한 '호스트' 구성을 만들었습니다. 코드나 이전 문서에 'host'에 대한 참조가 표시되면 이를 의미합니다. Bazel 6.0 이상을 사용하여 이러한 추가적인 개념적 오버헤드를 피하는 것이 좋습니다.

구성 프래그먼트

규칙은 cpp, java, jvm와 같은 구성 프래그먼트에 액세스할 수 있습니다. 그러나 액세스 오류를 방지하려면 모든 필수 프래그먼트를 선언해야 합니다.

def _impl(ctx):
    # Using ctx.fragments.cpp leads to an error since it was not declared.
    x = ctx.fragments.java
    ...

my_rule = rule(
    implementation = _impl,
    fragments = ["java"],      # Required fragments of the target configuration
    host_fragments = ["java"], # Required fragments of the host configuration
    ...
)

실행 파일 심볼릭 링크

일반적으로 실행 파일 트리에 있는 파일의 상대 경로는 소스 트리 또는 생성된 출력 트리에 있는 파일의 상대 경로와 동일합니다. 어떤 이유로든 두 값을 다르게 해야 하는 경우 root_symlinks 또는 symlinks 인수를 지정할 수 있습니다. root_symlinks는 파일에 매핑되는 사전 경로로, 여기서 경로는 실행 파일 디렉터리의 루트를 기준으로 합니다. symlinks 사전은 동일하지만 경로에 기본 작업공간의 이름 (현재 타겟이 포함된 저장소 이름이 아님)이 암시적으로 접두사로 붙습니다.

    ...
    runfiles = ctx.runfiles(
        root_symlinks = {"some/path/here.foo": ctx.file.some_data_file2}
        symlinks = {"some/path/here.bar": ctx.file.some_data_file3}
    )
    # Creates something like:
    # sometarget.runfiles/
    #     some/
    #         path/
    #             here.foo -> some_data_file2
    #     <workspace_name>/
    #         some/
    #             path/
    #                 here.bar -> some_data_file3

symlinks 또는 root_symlinks를 사용하는 경우 서로 다른 두 파일을 실행 파일 트리의 동일한 경로에 매핑하지 않도록 주의하세요. 이로 인해 충돌을 설명하는 오류와 함께 빌드가 실패합니다. 이 오류를 해결하려면 ctx.runfiles 인수를 수정하여 충돌을 삭제해야 합니다. 이 검사는 규칙을 사용하는 모든 대상 및 이러한 대상에 종속된 모든 종류의 대상에 대해 수행됩니다. 이는 도구가 다른 도구에서 전이적으로 사용될 가능성이 있는 경우 특히 위험합니다. 심볼릭 링크 이름은 도구 및 모든 종속 항목의 실행 파일에서 고유해야 합니다.

코드 적용 범위

coverage 명령어가 실행되면 빌드에서 특정 타겟의 적용 범위 계측을 추가해야 할 수도 있습니다. 빌드는 계측된 소스 파일 목록도 수집합니다. 고려되는 대상의 하위 집합은 --instrumentation_filter 플래그에 의해 제어됩니다. 테스트 대상은 --instrument_test_targets가 지정되지 않은 한 제외됩니다.

규칙 구현이 빌드 시간에 커버리지 계측을 추가하는 경우 구현 함수에서 이를 고려해야 합니다. 타겟의 소스를 계측해야 하는 경우 ctx.coverage_instrumented는 커버리지 모드에서 true를 반환합니다.

# Are this rule's sources instrumented?
if ctx.coverage_instrumented():
  # Do something to turn on coverage for this compile action

대상의 소스가 구체적으로 계측되는지 여부와 상관없이 적용 범위 모드에서 항상 켜져 있어야 하는 로직은 ctx.configuration.coverage_enabled에서 컨디셔닝할 수 있습니다.

규칙이 컴파일 전에 종속 항목의 소스(예: 헤더 파일)를 직접 포함하는 경우 종속 항목의 소스를 계측해야 한다면 컴파일 시간 계측을 사용 설정해야 할 수도 있습니다.

# Are this rule's sources or any of the sources for its direct dependencies
# in deps instrumented?
if (ctx.configuration.coverage_enabled and
    (ctx.coverage_instrumented() or
     any([ctx.coverage_instrumented(dep) for dep in ctx.attr.deps]))):
    # Do something to turn on coverage for this compile action

또한 규칙은 coverage_common.instrumented_files_info를 사용하여 구성된 InstrumentedFilesInfo 제공자의 적용 범위와 관련된 속성에 관한 정보를 제공해야 합니다. instrumented_files_info의 dependency_attributes 매개변수에는 코드 종속 항목(예: deps)과 데이터 종속 항목(예: data)을 포함한 모든 런타임 종속 항목 속성이 나열됩니다. 적용 범위 계측이 추가될 수 있는 경우 source_attributes 매개변수는 규칙의 소스 파일 속성을 나열해야 합니다.

def _example_library_impl(ctx):
    ...
    return [
        ...
        coverage_common.instrumented_files_info(
            ctx,
            dependency_attributes = ["deps", "data"],
            # Omitted if coverage is not supported for this rule:
            source_attributes = ["srcs", "hdrs"],
        )
        ...
    ]

InstrumentedFilesInfo가 반환되지 않으면 dependency_attributes에서 속성 스키마에서 cfg를 "host" 또는 "exec"로 설정하지 않는 도구가 아닌 각 종속 항목 속성을 사용하여 기본값이 생성됩니다. (이는 source_attributes 대신 dependency_attributes에 srcs과 같은 속성을 배치하므로 이상적인 동작은 아니지만 종속 항목 체인의 모든 규칙에 관한 명시적인 적용 범위 구성이 필요하지 않습니다.)

검증 작업

빌드에 관한 일부의 유효성을 검사해야 하는 경우가 있으며, 이 유효성 검사에 필요한 정보는 아티팩트(소스 파일 또는 생성된 파일)에서만 사용할 수 있습니다. 이 정보는 아티팩트에 있으므로 규칙이 파일을 읽을 수 없기 때문에 분석 시 규칙이 검증을 수행할 수 없습니다. 대신 작업은 실행 시 이 유효성 검사를 수행해야 합니다. 유효성 검사가 실패하면 작업도 실패하므로 빌드도 실패하게 됩니다.

실행할 수 있는 유효성 검사의 예로는 정적 분석, 린트 작업, 종속 항목 및 일관성 검사, 스타일 검사가 있습니다.

검증 작업은 아티팩트를 별도의 작업으로 빌드하는 데 필요하지 않은 작업 일부를 이동하여 빌드 성능을 개선하는 데도 도움이 될 수 있습니다. 예를 들어 컴파일과 린트를 실행하는 단일 작업을 컴파일 작업과 린트 작업으로 구분할 수 있다면 린트 작업을 유효성 검사 작업으로 실행하고 다른 작업과 동시에 실행할 수 있습니다.

이러한 '유효성 검사 작업'은 입력에 관해 어설션하기만 하면 되므로 빌드의 다른 곳에서 사용되는 작업을 생성하지 않는 경우가 많습니다. 하지만 여기에는 문제가 있습니다. 유효성 검사 작업이 빌드의 다른 곳에서 사용되는 것을 생성하지 않는 경우 규칙은 어떻게 작업을 실행할까요? 이전에는 유효성 검사 작업에서 빈 파일을 출력하고 이 출력을 빌드의 다른 중요한 작업의 입력에 인위적으로 추가하는 것이 접근 방식이었습니다.

컴파일 작업이 실행될 때 Bazel이 항상 유효성 검사 작업을 실행하기 때문에 이 방법이 효과가 있지만 여기에는 중요한 단점이 있습니다.

1. 유효성 검사 작업은 빌드의 주요 경로에서 이루어집니다. Bazel은 컴파일 작업을 실행하려면 빈 출력이 필요하다고 생각하기 때문에 컴파일 작업이 입력을 무시하더라도 유효성 검사 작업을 먼저 실행합니다. 따라서 동시 로드가 줄어들고 빌드 속도가 느려집니다.

2. 컴파일 작업 대신 빌드의 다른 작업을 실행할 수 있는 경우 유효성 검사 작업의 빈 출력을 이러한 작업에 추가해야 합니다 (예: java_library의 소스 jar 출력). 또한 컴파일 작업 대신 실행될 수 있는 새 작업이 나중에 추가되어 빈 유효성 검사 출력이 실수로 중단된 경우에도 문제가 됩니다.

이 문제의 해결 방법은 유효성 검사 출력 그룹을 사용하는 것입니다.

검증 출력 그룹

유효성 검사 출력 그룹은 다른 작업의 입력에 인위적으로 추가할 필요가 없도록 유효성 검사 작업의 사용되지 않은 출력을 보관하도록 설계된 출력 그룹입니다.

이 그룹은 --output_groups 플래그의 값과 무관하게 타겟이 종속된 방식 (예: 명령줄에서 종속 항목으로 또는 타겟의 암시적 출력을 통해)과 상관없이 출력이 항상 요청된다는 점에서 특별합니다. 일반 캐싱과 성과 증분이 계속 적용됩니다. 유효성 검사 작업에 대한 입력이 변경되지 않고 이전에 유효성 검사 작업이 성공한 경우 유효성 검사 작업이 실행되지 않습니다.

이 출력 그룹을 사용하려면 빈 파일을 포함하여 일부 파일을 출력해야 합니다. 이를 위해서는 일반적으로 출력을 생성하지 않는 일부 도구를 래핑하여 파일이 생성되도록 해야 할 수 있습니다.

대상의 유효성 검사 작업은 다음 세 가지 경우에 실행되지 않습니다.

• 대상이 도구로 사용되는 경우
• 타겟이 암시적 종속 항목으로 사용되는 경우 (예: '_'로 시작하는 속성)
• 타겟이 호스트 또는 exec 구성에서 빌드되는 경우

이러한 타겟에는 유효성 검사 실패를 발견할 수 있는 별도의 빌드와 테스트가 있다고 가정합니다.

검증 출력 그룹 사용

검증 출력 그룹의 이름은 _validation이며 다른 출력 그룹처럼 사용됩니다.

def _rule_with_validation_impl(ctx):

  ctx.actions.write(ctx.outputs.main, "main output\n")

  ctx.actions.write(ctx.outputs.implicit, "implicit output\n")

  validation_output = ctx.actions.declare_file(ctx.attr.name + ".validation")
  ctx.actions.run(
      outputs = [validation_output],
      executable = ctx.executable._validation_tool,
      arguments = [validation_output.path])

  return [
    DefaultInfo(files = depset([ctx.outputs.main])),
    OutputGroupInfo(_validation = depset([validation_output])),
  ]


rule_with_validation = rule(
  implementation = _rule_with_validation_impl,
  outputs = {
    "main": "%{name}.main",
    "implicit": "%{name}.implicit",
  },
  attrs = {
    "_validation_tool": attr.label(
        default = Label("//validation_actions:validation_tool"),
        executable = True,
        cfg = "exec"),
  }
)

유효성 검사 출력 파일은 DefaultInfo 또는 다른 작업의 입력에 추가되지 않습니다. 이 규칙 종류의 대상에 대한 유효성 검사 작업은 대상이 라벨에 종속되거나 대상의 암시적 출력이 직간접적으로 종속된 경우 계속 실행됩니다.

일반적으로 유효성 검사 작업의 출력은 유효성 검사 출력 그룹에만 해당되고 다른 작업의 입력에는 추가되지 않는 것이 중요합니다. 동시 로드 획득이 무효화될 수 있기 때문입니다. 그러나 Bazel에는 현재 이를 시행하기 위한 특별한 검사가 없습니다. 따라서 검증 작업 출력이 Starlark 규칙 테스트의 작업 입력에 추가되지 않는지 테스트해야 합니다. 예를 들면 다음과 같습니다.

load("@bazel_skylib//lib:unittest.bzl", "analysistest")

def _validation_outputs_test_impl(ctx):
  env = analysistest.begin(ctx)

  actions = analysistest.target_actions(env)
  target = analysistest.target_under_test(env)
  validation_outputs = target.output_groups._validation.to_list()
  for action in actions:
    for validation_output in validation_outputs:
      if validation_output in action.inputs.to_list():
        analysistest.fail(env,
            "%s is a validation action output, but is an input to action %s" % (
                validation_output, action))

  return analysistest.end(env)

validation_outputs_test = analysistest.make(_validation_outputs_test_impl)

유효성 검사 작업 플래그

유효성 검사 작업 실행은 기본값이 true인 --run_validations 명령줄 플래그로 제어됩니다.

지원이 중단된 기능

지원 중단된 사전 선언 출력

사전 선언된 출력을 사용하는 방법에는 지원 중단되는 두 가지 방법이 있습니다.

• rule의 outputs 매개변수는 사전 선언된 출력 라벨을 생성하기 위한 출력 속성 이름과 문자열 템플릿 간의 매핑을 지정합니다. 사전 선언되지 않은 출력을 사용하고 출력을 DefaultInfo.files에 명시적으로 추가하는 것을 선호합니다. 미리 선언된 출력 라벨 대신 출력을 사용하는 규칙의 입력으로 규칙 대상의 라벨을 사용합니다.

• 실행 가능 규칙의 경우 ctx.outputs.executable는 규칙 대상과 이름이 같은 사전 선언된 실행 가능 출력을 나타냅니다. 예를 들어 ctx.actions.declare_file(ctx.label.name)를 사용하여 출력을 명시적으로 선언하는 것을 선호하고 실행 파일을 생성하는 명령어가 실행을 허용하도록 권한을 설정했는지 확인합니다. 실행 가능한 출력을 DefaultInfo의 executable 매개변수에 명시적으로 전달합니다.

피해야 할 실행 파일 기능

ctx.runfiles 및 runfiles 유형에는 복잡한 기능 집합이 있으며 그 중 다수는 레거시 이유로 유지됩니다. 다음 권장사항은 복잡성을 줄이는 데 도움이 됩니다.

• ctx.runfiles의 collect_data 모드와 collect_default 모드를 사용하지 마세요. 이러한 모드는 하드코딩된 특정 종속 항목 에지에서 혼란을 일으키는 방식으로 실행 파일을 암시적으로 수집합니다. 대신 ctx.runfiles의 files 또는 transitive_files 매개변수를 사용하거나 종속 항목의 실행 파일에서 runfiles = runfiles.merge(dep[DefaultInfo].default_runfiles)를 사용하여 파일을 추가하세요.

• DefaultInfo 생성자의 data_runfiles 및 default_runfiles를 사용하지 마세요. 대신 DefaultInfo(runfiles = ...)를 지정하세요. '기본' 실행 파일과 '데이터' 실행 파일의 구분은 레거시 이유로 유지됩니다. 예를 들어 일부 규칙은 기본 출력을 data_runfiles에 배치하지만 default_runfiles에 넣지 않습니다. 규칙은 data_runfiles를 사용하는 대신 둘 다 실행 파일을 제공하는 속성 (보통 data)을 제공하는 속성의 default_runfiles에서 병합해야 합니다.

• DefaultInfo에서 runfiles를 가져올 때 (일반적으로 현재 규칙과 종속 항목 간의 실행 파일을 병합하는 경우에만) DefaultInfo.data_runfiles가 아닌 DefaultInfo.default_runfiles를 사용합니다.

기존 제공업체에서 마이그레이션

지금까지 Bazel 제공자는 Target 객체의 단순 필드였습니다. 이러한 필드는 점 연산자를 사용하여 액세스했으며 규칙의 구현 함수가 반환하는 구조체에 필드를 넣어 생성되었습니다.

이 스타일은 지원 중단되었으며 새 코드에 사용해서는 안 됩니다. 이전하는 데 도움이 되는 정보는 아래를 참고하세요. 새로운 제공업체 메커니즘은 이름 충돌을 방지합니다. 또한 제공업체 인스턴스에 액세스하는 모든 코드가 제공업체 기호를 사용하여 인스턴스를 검색하도록 함으로써 데이터 숨기기를 지원합니다.

현재 기존 제공업체는 계속 지원됩니다. 규칙은 다음과 같이 기존 제공업체와 최신 제공업체를 모두 반환할 수 있습니다.

def _old_rule_impl(ctx):
  ...
  legacy_data = struct(x="foo", ...)
  modern_data = MyInfo(y="bar", ...)
  # When any legacy providers are returned, the top-level returned value is a
  # struct.
  return struct(
      # One key = value entry for each legacy provider.
      legacy_info = legacy_data,
      ...
      # Additional modern providers:
      providers = [modern_data, ...])

dep가 이 규칙 인스턴스의 결과 Target 객체인 경우 제공자와 그 콘텐츠는 dep.legacy_info.x 및 dep[MyInfo].y로 검색할 수 있습니다.

반환된 구조체는 providers 외에도 특별한 의미가 있는 다른 여러 필드를 사용할 수 있습니다 (따라서 상응하는 레거시 제공자를 만들지 않음).

• 필드 files, runfiles, data_runfiles, default_runfiles, executable는 DefaultInfo의 동일한 이름의 필드에 해당합니다. 이러한 필드를 지정할 수 없으며 DefaultInfo 제공자도 반환됩니다.

• output_groups 필드는 구조체 값을 사용하며 OutputGroupInfo에 해당합니다.

규칙의 provides 선언과 종속 항목 속성의 providers 선언에서 기존 제공자는 문자열로 전달되고 최신 제공자는 *Info 기호로 전달됩니다. 이전할 때는 문자열에서 기호로 변경해야 합니다. 모든 규칙을 원자적으로 업데이트하기 어려운 복잡하거나 큰 규칙 세트의 경우 다음 단계를 따르면 더 수월할 수 있습니다.

1. 위의 구문을 사용하여 기존 제공업체를 생성하는 규칙을 수정하여 기존 및 최신 제공업체를 모두 생성합니다. 기존 제공자를 반환한다고 선언하는 규칙의 경우 기존 제공자와 최신 제공자를 모두 포함하도록 선언을 업데이트하세요.

2. 대신 최신 제공업체를 사용하도록 기존 제공업체를 사용하는 규칙을 수정합니다. 속성 선언에 기존 제공자가 필요한 경우 대신 최신 제공자를 요구하도록 업데이트합니다. 선택적으로 1단계와 함께 소비자가 제공자 중 하나를 수락/요구하도록 하여 이 작업을 인터리브 처리할 수 있습니다. hasattr(target, 'foo')를 사용하여 기존 제공자가 있는지 테스트하거나 FooInfo in target를 사용하여 새 제공자가 있는지 테스트합니다.

3. 모든 규칙에서 기존 제공업체를 완전히 삭제합니다.