BazelCon 2025 の登録と CFP が開始されました。

このページは Cloud Translation API によって翻訳されました。

ルール

問題を報告ソースを表示 Nightly · 8.3 · 8.2 · 8.1 · 8.0 · 7.6

ルールは、一連のアクションを定義します。Bazel は、入力に対してこれらのアクションを実行して、一連の出力を生成します。これらの出力は、ルールの実装関数によって返されるプロバイダで参照されます。たとえば、C++ バイナリルールは次のようになります。

.cpp ソースファイル（入力）のセットを取得します。
ソースファイルに対して g++ を実行します（アクション）。
実行可能出力と、ランタイムで使用可能にする他のファイルを含む DefaultInfo プロバイダを返します。
ターゲットとその依存関係から収集された C++ 固有の情報を含む CcInfo プロバイダを返します。

Bazel の観点から見ると、g++ と標準 C++ ライブラリもこのルールの入力です。ルール作成者は、ルールにユーザーが指定した入力だけでなく、アクションの実行に必要なすべてのツールとライブラリも考慮する必要があります。

ルールを作成または変更する前に、Bazel のビルドフェーズを理解しておいてください。ビルドの 3 つのフェーズ（読み込み、分析、実行）を理解することが重要です。ルールとマクロの違いを理解するには、マクロについて学習することも役立ちます。まず、ルールチュートリアルをご覧ください。このページを参考にしてください。

Bazel 自体にはいくつかのルールが組み込まれています。cc_library や java_binary などのネイティブルールは、特定の言語に対するコアサポートを提供します。独自のルールを定義することで、Bazel がネイティブでサポートしていない言語やツールに対しても同様のサポートを追加できます。

Bazel は、Starlark 言語を使用してルールを記述するための拡張性モデルを提供します。これらのルールは .bzl ファイルに記述され、BUILD ファイルから直接読み込むことができます。

独自のルールを定義する際は、サポートする属性と出力の生成方法を決定できます。

ルールの implementation 関数は、分析フェーズ中の正確な動作を定義します。この関数は外部コマンドを実行しません。代わりに、実行フェーズで必要に応じてルールの出力を構築するために使用されるアクションを登録します。

ルールの作成

.bzl ファイルで、rule 関数を使用して新しいルールを定義し、結果をグローバル変数に保存します。rule の呼び出しでは、属性と実装関数を指定します。

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        "deps": attr.label_list(),
        ...
    },
)

これにより、example_library という名前のルールの種類が定義されます。

rule の呼び出しでは、ルールが実行可能ファイル（executable=True）を作成するのか、テスト実行可能ファイル（test=True）を作成するのかも指定する必要があります。後者の場合、ルールはテストルールであり、ルールの名前は _test で終わる必要があります。

ターゲットのインスタンス化

ルールは BUILD ファイルで読み込んで呼び出すことができます。

load('//some/pkg:rules.bzl', 'example_library')

example_library(
    name = "example_target",
    deps = [":another_target"],
    ...
)

ビルドルールへの各呼び出しは値を返しませんが、ターゲットを定義する副作用があります。これをルールのインスタンス化と呼びます。これは、新しいターゲットの名前と、ターゲットの属性の値を指定します。

ルールは Starlark 関数から呼び出すことも、.bzl ファイルに読み込むこともできます。ルールを呼び出す Starlark 関数は、Starlark マクロと呼ばれます。Starlark マクロは最終的に BUILD ファイルから呼び出す必要があり、BUILD ファイルが評価されてターゲットがインスタンス化される読み込みフェーズでのみ呼び出すことができます。

属性

属性はルール引数です。属性は、ターゲットの実装に特定の値を指定することも、他のターゲットを参照して依存関係のグラフを作成することもできます。

srcs や deps などのルール固有の属性は、属性名からスキーマ（attr モジュールを使用して作成）へのマップを rule の attrs パラメータに渡すことで定義されます。name や visibility などの共通属性は、すべてのルールに暗黙的に追加されます。追加の属性は、特に実行可能ファイルとテストルールに暗黙的に追加されます。ルールに暗黙的に追加される属性は、attrs に渡されるディクショナリに含めることはできません。

依存関係の属性

ソースコードを処理するルールでは、通常、さまざまな依存関係のタイプを処理するために次の属性を定義します。

srcs は、ターゲットのアクションによって処理されるソースファイルを指定します。多くの場合、属性スキーマでは、ルールが処理するソースファイルの種類のファイル拡張子を指定します。ヘッダーファイルを含む言語のルールでは、通常、ターゲットとそのコンシューマーによって処理されるヘッダー用に個別の hdrs 属性を指定します。
deps は、ターゲットのコード依存関係を指定します。属性スキーマでは、これらの依存関係を提供する必要があるプロバイダを指定する必要があります。（たとえば、cc_library は CcInfo を提供します）。
data は、ターゲットに依存する実行可能ファイルで実行時に利用可能にするファイルを指定します。これにより、任意のファイルを指定できるようになります。

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        "srcs": attr.label_list(allow_files = [".example"]),
        "hdrs": attr.label_list(allow_files = [".header"]),
        "deps": attr.label_list(providers = [ExampleInfo]),
        "data": attr.label_list(allow_files = True),
        ...
    },
)

これらは、依存関係属性の例です。入力ラベル（attr.label_list、attr.label、attr.label_keyed_string_dict で定義されたもの）を指定する属性は、ターゲットが定義されている場合、ターゲットとその属性にラベル（または対応する Label オブジェクト）がリストされているターゲットとの間の特定のタイプの依存関係を指定します。これらのラベルのリポジトリ（およびパス）は、定義されたターゲットを基準に解決されます。

example_library(
    name = "my_target",
    deps = [":other_target"],
)

example_library(
    name = "other_target",
    ...
)

この例では、other_target は my_target の依存関係であるため、other_target が最初に分析されます。ターゲットの依存関係グラフにサイクルがある場合はエラーになります。

プライベート属性と暗黙の依存関係

デフォルト値を持つ依存関係属性は、暗黙的な依存関係を作成します。これは、ユーザーが BUILD ファイルで指定しないターゲットグラフの一部であるため、暗黙的です。暗黙的な依存関係は、ルールとツール（コンパイラなどのビルド時の依存関係）の関係をハードコードする場合に便利です。ほとんどの場合、ユーザーはルールが使用するツールを指定することに関心がないためです。ルールの実装関数内では、他の依存関係と同じように扱われます。

ユーザーが値をオーバーライドできない暗黙的な依存関係を指定する場合は、アンダースコア（_）で始まる名前を付けて属性を非公開にできます。非公開属性にはデフォルト値が必要です。一般的に、プライベート属性は暗黙的な依存関係にのみ使用するのが妥当です。

example_library = rule(
    implementation = _example_library_impl,
    attrs = {
        ...
        "_compiler": attr.label(
            default = Label("//tools:example_compiler"),
            allow_single_file = True,
            executable = True,
            cfg = "exec",
        ),
    },
)

この例では、タイプ example_library のすべてのターゲットに、コンパイラ //tools:example_compiler への暗黙的な依存関係があります。これにより、ユーザーがラベルを入力として渡さなかった場合でも、example_library の実装関数はコンパイラを呼び出すアクションを生成できます。_compiler は非公開属性であるため、このルールタイプのすべてのターゲットで ctx.attr._compiler は常に //tools:example_compiler を指します。または、アンダースコアなしで属性に compiler という名前を付け、デフォルト値を保持することもできます。これにより、ユーザーは必要に応じて別のコンパイラを代用できますが、コンパイラのラベルを認識する必要はありません。

暗黙的な依存関係は通常、ルール実装と同じリポジトリにあるツールに使用されます。ツールが実行プラットフォームまたは別のリポジトリから提供される場合は、ルールでツールチェーンからツールを取得する必要があります。

出力属性

出力属性（attr.output や attr.output_list など）は、ターゲットが生成する出力ファイルを宣言します。これらは、次の 2 つの点で依存関係属性とは異なります。

他の場所で定義されたターゲットを参照するのではなく、出力ファイルターゲットを定義します。
出力ファイルターゲットは、インスタンス化されたルールターゲットに依存します。

通常、出力属性は、ルールでユーザー定義名を持つ出力を作成する必要があり、その名前をターゲット名に基づいて作成できない場合にのみ使用されます。ルールに 1 つの出力属性がある場合、通常は out または outs という名前が付けられます。

出力属性は、事前宣言された出力を作成する推奨の方法です。この出力は、特に依存関係があるか、コマンドラインでリクエストできます。

実装関数

すべてのルールに implementation 関数が必要です。これらの関数は、厳密に分析フェーズで実行され、読み込みフェーズで生成されたターゲットのグラフを、実行フェーズで実行されるアクションのグラフに変換します。そのため、実装関数は実際にファイルを読み書きできません。

ルール実装関数は通常、非公開です（先頭にアンダースコアが付いた名前が付けられます）。通常、ルールと同じ名前で、接尾辞 _impl が付いています。

実装関数は、ルールコンテキスト（通常は ctx と呼ばれます）という 1 つのパラメータのみを取ります。プロバイダのリストを返します。

ターゲット

依存関係は、分析時に Target オブジェクトとして表されます。これらのオブジェクトには、ターゲットの実装関数が実行されたときに生成されたプロバイダが含まれています。

ctx.attr には、各依存関係属性の名前に対応するフィールドがあり、その属性を介した各直接依存関係を表す Target オブジェクトが含まれています。label_list 属性の場合、これは Targets のリストです。label 属性の場合、これは単一の Target または None です。

プロバイダオブジェクトのリストは、ターゲットの実装関数によって返されます。

return [ExampleInfo(headers = depset(...))]

これらには、プロバイダのタイプをキーとしてインデックス表記（[]）を使用してアクセスできます。これらは、Starlark で定義されたカスタムプロバイダ、または Starlark グローバル変数として使用可能なネイティブルールのプロバイダにすることができます。

たとえば、ルールが hdrs 属性を介してヘッダーファイルを取得し、ターゲットとそのコンシューマーのコンパイルアクションに提供する場合、次のように収集できます。

def _example_library_impl(ctx):
    ...
    transitive_headers = [hdr[ExampleInfo].headers for hdr in ctx.attr.hdrs]

プロバイダオブジェクトのリストではなく、ターゲットの実装関数から struct が返される従来のスタイルの場合:

return struct(example_info = struct(headers = depset(...)))

プロバイダは、Target オブジェクトの対応するフィールドから取得できます。

transitive_headers = [hdr.example_info.headers for hdr in ctx.attr.hdrs]

このスタイルは強く推奨されず、ルールはこのスタイルから移行する必要があります。

ファイル

ファイルは File オブジェクトで表されます。Bazel は分析フェーズでファイル I/O を実行しないため、これらのオブジェクトを使用してファイルコンテンツを直接読み書きすることはできません。代わりに、アクショングラフの断片を構築するために、アクションを生成する関数（ctx.actions を参照）に渡されます。

File は、ソースファイルまたは生成されたファイルのいずれかになります。生成された各ファイルは、1 つのアクションの出力である必要があります。ソースファイルは、アクションの出力にできません。

依存関係属性ごとに、ctx.files の対応するフィールドには、その属性を介したすべての依存関係のデフォルト出力のリストが含まれます。

def _example_library_impl(ctx):
    ...
    headers = depset(ctx.files.hdrs, transitive=transitive_headers)
    srcs = ctx.files.srcs
    ...

ctx.file には、仕様で allow_single_file=True が設定されている依存関係属性の File または None が 1 つ含まれます。ctx.executable は ctx.file と同じように動作しますが、仕様で executable=True が設定されている依存関係属性のフィールドのみが含まれます。

出力を宣言する

分析フェーズでは、ルールの実装関数で出力を作成できます。すべてのラベルは読み込みフェーズで認識される必要があるため、これらの追加出力にはラベルがありません。出力用の File オブジェクトは、ctx.actions.declare_file と ctx.actions.declare_directory を使用して作成できます。多くの場合、出力の名前はターゲットの名前 ctx.label.name に基づいています。

def _example_library_impl(ctx):
  ...
  output_file = ctx.actions.declare_file(ctx.label.name + ".output")
  ...

出力属性用に作成されたものなどの事前宣言された出力の場合、ctx.outputs の対応するフィールドから File オブジェクトを取得できます。

操作

アクションは、一連の入力から一連の出力を生成する方法を記述します（例: 「hello.c で gcc を実行して hello.o を取得する」）。アクションが作成されても、Bazel はコマンドをすぐに実行しません。アクションは別のアクションの出力に依存する可能性があるため、依存関係のグラフに登録されます。たとえば、C では、コンパイラの後にリンカーを呼び出す必要があります。

アクションを作成する汎用関数は ctx.actions で定義されています。

ctx.actions.run: 実行可能ファイルを実行します。
ctx.actions.run_shell: シェルコマンドを実行します。
ctx.actions.write: 文字列をファイルに書き込みます。
ctx.actions.expand_template: テンプレートからファイルを生成します。

ctx.actions.args を使用すると、アクションの引数を効率的に蓄積できます。実行時まで depsets のフラット化を回避します。

def _example_library_impl(ctx):
    ...

    transitive_headers = [dep[ExampleInfo].headers for dep in ctx.attr.deps]
    headers = depset(ctx.files.hdrs, transitive=transitive_headers)
    srcs = ctx.files.srcs
    inputs = depset(srcs, transitive=[headers])
    output_file = ctx.actions.declare_file(ctx.label.name + ".output")

    args = ctx.actions.args()
    args.add_joined("-h", headers, join_with=",")
    args.add_joined("-s", srcs, join_with=",")
    args.add("-o", output_file)

    ctx.actions.run(
        mnemonic = "ExampleCompile",
        executable = ctx.executable._compiler,
        arguments = [args],
        inputs = inputs,
        outputs = [output_file],
    )
    ...

アクションは、入力ファイルのリストまたは depset を受け取り、出力ファイルの（空でない）リストを生成します。入力ファイルと出力ファイルのセットは、分析フェーズで把握しておく必要があります。依存関係のプロバイダなど、属性の値に依存する可能性がありますが、実行結果に依存することはできません。たとえば、アクションで unzip コマンドを実行する場合は、解凍するファイル（unzip を実行する前）を指定する必要があります。内部で可変数のファイルを作成するアクションは、それらを 1 つのファイル（zip、tar、その他のアーカイブ形式など）にラップできます。

アクションはすべての入力をリストする必要があります。使用されていない入力をリストすることは許可されていますが、非効率的です。

アクションはすべての出力を生成する必要があります。他のファイルを書き込むこともできますが、outputs に含まれていないものはコンシューマーが利用できません。宣言された出力はすべて、なんらかのアクションによって書き込まれる必要があります。

アクションは純粋関数に似ています。提供された入力のみに依存し、コンピュータ情報、ユーザー名、クロック、ネットワーク、I/O デバイスへのアクセスを避ける必要があります（入力の読み取りと出力の書き込みを除く）。出力はキャッシュに保存されて再利用されるため、これは重要です。

依存関係は Bazel によって解決され、実行されるアクションが決定されます。依存関係グラフにサイクルがある場合はエラーになります。アクションを作成しても、必ず実行されるとは限りません。実行されるかどうかは、ビルドでその出力が必要かどうかによって決まります。

プロバイダ

プロバイダは、ルールが依存する他のルールに公開する情報です。このデータには、出力ファイル、ライブラリ、ツールのコマンドラインで渡すパラメータなど、ターゲットのコンシューマーが知っておくべきものが含まれます。

ルールの実装関数は、インスタンス化されたターゲットの直接の依存関係からのみプロバイダを読み取ることができるため、ルールは、ターゲットのコンシューマーが知る必要があるターゲットの依存関係からの情報を転送する必要があります。通常は、depset に集約します。

ターゲットのプロバイダは、実装関数が返す Provider オブジェクトのリストで指定されます。

古い実装関数は、プロバイダオブジェクトのリストではなく struct を返すレガシースタイルで記述することもできます。このスタイルは強く推奨されず、ルールはこのスタイルから移行する必要があります。

デフォルトの出力

ターゲットのデフォルト出力は、コマンドラインでターゲットのビルドがリクエストされたときにデフォルトでリクエストされる出力です。たとえば、java_library ターゲット //pkg:foo のデフォルト出力は foo.jar であるため、コマンド bazel build //pkg:foo でビルドされます。

デフォルトの出力は、DefaultInfo の files パラメータで指定します。

def _example_library_impl(ctx):
    ...
    return [
        DefaultInfo(files = depset([output_file]), ...),
        ...
    ]

ルール実装で DefaultInfo が返されない場合、または files パラメータが指定されていない場合、DefaultInfo.files はデフォルトで、すべての事前宣言された出力（通常は出力属性によって作成されたもの）になります。

アクションを実行するルールでは、出力が直接使用されることが想定されていない場合でも、デフォルトの出力を提供する必要があります。リクエストされた出力のグラフに含まれていないアクションはプルーニングされます。出力がターゲットのコンシューマーでのみ使用される場合、ターゲットが分離してビルドされるときに、これらのアクションは実行されません。このため、失敗したターゲットだけを再ビルドしても失敗を再現できないため、デバッグが難しくなります。

Runfiles

ランファイルは、ビルド時ではなく実行時にターゲットで使用されるファイルのセットです。実行フェーズでは、Bazel は runfiles を指すシンボリックリンクを含むディレクトリツリーを作成します。これにより、バイナリの環境がステージングされ、実行時に runfile にアクセスできるようになります。

ルール作成時にランファイルを手動で追加できます。runfiles オブジェクトは、ルールコンテキスト ctx.runfiles の runfiles メソッドで作成し、DefaultInfo の runfiles パラメータに渡すことができます。実行可能ルールの実行可能出力は、runfiles に暗黙的に追加されます。

一部のルールでは、通常 data という名前の属性を指定します。この属性の出力は、ターゲットの runfile に追加されます。Runfiles は、data からだけでなく、最終的に実行するコードを提供する可能性のある属性（通常は srcs（関連付けられた data を含む filegroup ターゲットを含む場合がある）と deps）からもマージする必要があります。

def _example_library_impl(ctx):
    ...
    runfiles = ctx.runfiles(files = ctx.files.data)
    transitive_runfiles = []
    for runfiles_attr in (
        ctx.attr.srcs,
        ctx.attr.hdrs,
        ctx.attr.deps,
        ctx.attr.data,
    ):
        for target in runfiles_attr:
            transitive_runfiles.append(target[DefaultInfo].default_runfiles)
    runfiles = runfiles.merge_all(transitive_runfiles)
    return [
        DefaultInfo(..., runfiles = runfiles),
        ...
    ]

カスタムプロバイダ

provider 関数を使用してプロバイダを定義し、ルール固有の情報を伝達できます。

ExampleInfo = provider(
    "Info needed to compile/link Example code.",
    fields={
        "headers": "depset of header Files from transitive dependencies.",
        "files_to_link": "depset of Files from compilation.",
    })

ルール実装関数は、プロバイダインスタンスを構築して返すことができます。

def _example_library_impl(ctx):
  ...
  return [
      ...
      ExampleInfo(
          headers = headers,
          files_to_link = depset(
              [output_file],
              transitive = [
                  dep[ExampleInfo].files_to_link for dep in ctx.attr.deps
              ],
          ),
      )
  ]

プロバイダのカスタム初期化

カスタムのプリプロセスと検証ロジックを使用して、プロバイダのインスタンス化を保護できます。これは、すべてのプロバイダインスタンスが特定の不変条件に従うようにしたり、インスタンスを取得するためのよりクリーンな API をユーザーに提供したりするために使用できます。

これを行うには、provider 関数に init コールバックを渡します。このコールバックが指定されている場合、provider() の戻り値の型は 2 つの値のタプルに変更されます。1 つは init が使用されていない場合の通常の戻り値であるプロバイダシンボル、もう 1 つは「未加工のコンストラクタ」です。

この場合、プロバイダシンボルが呼び出されると、新しいインスタンスを直接返すのではなく、引数を init コールバックに転送します。コールバックの戻り値は、フィールド名（文字列）と値のマッピングである辞書でなければなりません。これは、新しいインスタンスのフィールドを初期化するために使用されます。コールバックには任意のシグネチャを指定できます。引数がシグネチャと一致しない場合は、コールバックが直接呼び出されたかのようにエラーが報告されます。

一方、未加工のコンストラクタは init コールバックをバイパスします。

次の例では、init を使用して引数を前処理し、検証しています。

# //pkg:exampleinfo.bzl

_core_headers = [...]  # private constant representing standard library files

# It's possible to define an init accepting positional arguments, but
# keyword-only arguments are preferred.
def _exampleinfo_init(*, files_to_link, headers = None, allow_empty_files_to_link = False):
    if not files_to_link and not allow_empty_files_to_link:
        fail("files_to_link may not be empty")
    all_headers = depset(_core_headers, transitive = headers)
    return {'files_to_link': files_to_link, 'headers': all_headers}

ExampleInfo, _new_exampleinfo = provider(
    ...
    init = _exampleinfo_init)

export ExampleInfo

ルール実装では、次のようにプロバイダをインスタンス化できます。

    ExampleInfo(
        files_to_link=my_files_to_link,  # may not be empty
        headers = my_headers,  # will automatically include the core headers
    )

未加工のコンストラクタを使用すると、init ロジックを経由しない代替のパブリックファクトリ関数を定義できます。たとえば、exampleinfo.bzl で次のように定義できます。

def make_barebones_exampleinfo(headers):
    """Returns an ExampleInfo with no files_to_link and only the specified headers."""
    return _new_exampleinfo(files_to_link = depset(), headers = all_headers)

通常、ユーザーコードがロードして任意のプロバイダインスタンスを生成できないように、未加工のコンストラクタは名前がアンダースコア（上記の _new_exampleinfo）で始まる変数にバインドされます。

init のもう 1 つの用途は、ユーザーがプロバイダシンボルを呼び出すのを完全に防ぎ、代わりにファクトリー関数を使用するように強制することです。

def _exampleinfo_init_banned(*args, **kwargs):
    fail("Do not call ExampleInfo(). Use make_exampleinfo() instead.")

ExampleInfo, _new_exampleinfo = provider(
    ...
    init = _exampleinfo_init_banned)

def make_exampleinfo(...):
    ...
    return _new_exampleinfo(...)

実行可能なルールとテストルール

実行可能なルールは、bazel run コマンドで呼び出すことができるターゲットを定義します。テストルールは、ターゲットを bazel test コマンドで呼び出すこともできる特殊な実行可能ルールです。実行可能ルールとテストルールは、rule の呼び出しでそれぞれの executable 引数または test 引数を True に設定することで作成されます。

example_binary = rule(
   implementation = _example_binary_impl,
   executable = True,
   ...
)

example_test = rule(
   implementation = _example_binary_impl,
   test = True,
   ...
)

テストルールの名前は _test で終わる必要があります。（テスト ターゲット名も、慣例として _test で終わることが多いですが、必須ではありません）。テスト以外のルールには、この接尾辞を付けないでください。

どちらの種類のルールでも、run コマンドまたは test コマンドによって呼び出される実行可能な出力ファイル（事前宣言されている場合とされていない場合があります）を生成する必要があります。この実行可能ファイルとして使用するルールの出力を Bazel に伝えるには、返された DefaultInfo プロバイダの executable 引数として渡します。この executable はルールのデフォルトの出力に追加されるため（executable と files の両方に渡す必要はありません）、runfiles にも暗黙的に追加されます。

def _example_binary_impl(ctx):
    executable = ctx.actions.declare_file(ctx.label.name)
    ...
    return [
        DefaultInfo(executable = executable, ...),
        ...
    ]

このファイルを生成するアクションは、ファイルに実行可能ビットを設定する必要があります。ctx.actions.run または ctx.actions.run_shell アクションの場合、これはアクションによって呼び出される基盤となるツールによって行われる必要があります。ctx.actions.write アクションの場合は、is_executable=True を渡します。

以前の動作として、実行可能ルールには特別な ctx.outputs.executable 事前宣言出力があります。このファイルは、DefaultInfo を使用して実行可能ファイルを指定しない場合のデフォルトの実行可能ファイルとして機能します。それ以外の場合には使用しないでください。この出力メカニズムは、分析時に実行可能ファイルの名前をカスタマイズできないため、非推奨となっています。

実行可能ルールとテストルールの例をご覧ください。

実行可能ルールとテストルールには、すべてのルールに追加された属性に加えて、暗黙的に定義された追加の属性があります。暗黙的に追加された属性のデフォルトは変更できませんが、デフォルトを変更する Starlark マクロで非公開ルールをラップすることで回避できます。

def example_test(size="small", **kwargs):
  _example_test(size=size, **kwargs)

_example_test = rule(
 ...
)

Runfiles の場所

実行可能ターゲットが bazel run（または test）で実行されると、runfiles ディレクトリのルートは実行可能ファイルの隣に配置されます。パスは次のように関連付けられます。

# Given launcher_path and runfile_file:
runfiles_root = launcher_path.path + ".runfiles"
workspace_name = ctx.workspace_name
runfile_path = runfile_file.short_path
execution_root_relative_path = "%s/%s/%s" % (
    runfiles_root, workspace_name, runfile_path)

runfiles ディレクトリの File へのパスは File.short_path に対応します。

bazel によって直接実行されるバイナリは、runfiles ディレクトリのルートに隣接しています。ただし、ランファイルから呼び出されるバイナリは、同じ前提を立てることはできません。この問題を軽減するため、各バイナリは、環境変数またはコマンドライン引数/フラグを使用して、ランファイルルートをパラメータとして受け入れる方法を提供する必要があります。これにより、バイナリは呼び出すバイナリに正しい正規の runfiles ルートを渡すことができます。設定されていない場合、バイナリは最初に呼び出されたバイナリであると推測し、隣接する runfiles ディレクトリを探します。

高度なトピック

出力ファイルをリクエストする

1 つのターゲットに複数の出力ファイルを設定できます。bazel build コマンドが実行されると、コマンドに指定されたターゲットの出力の一部がリクエストされたと見なされます。Bazel は、リクエストされたファイルと、それらが直接的または間接的に依存するファイルのみをビルドします。（アクショングラフの観点から見ると、Bazel はリクエストされたファイルの推移的依存関係として到達可能なアクションのみを実行します）。

デフォルトの出力に加えて、事前宣言された出力はコマンドラインで明示的にリクエストできます。ルールでは、出力属性を使用して、事前宣言された出力を指定できます。この場合、ユーザーはルールをインスタンス化するときに、出力のラベルを明示的に選択します。出力属性の File オブジェクトを取得するには、ctx.outputs の対応する属性を使用します。ルールは、ターゲット名に基づいて事前に宣言された出力を暗黙的に定義することもできますが、この機能は非推奨です。

デフォルトの出力に加えて、出力グループがあります。これは、一緒にリクエストされる可能性のある出力ファイルのコレクションです。これらは --output_groups でリクエストできます。たとえば、ターゲット //pkg:mytarget が debug_files 出力グループを持つルールタイプの場合、これらのファイルは bazel build //pkg:mytarget --output_groups=debug_files を実行してビルドできます。事前宣言されていない出力にはラベルがないため、デフォルトの出力または出力グループに表示されることでのみリクエストできます。

出力グループは OutputGroupInfo プロバイダで指定できます。多くの組み込みプロバイダとは異なり、OutputGroupInfo は任意の名前のパラメータを受け取り、その名前の出力グループを定義できます。

def _example_library_impl(ctx):
    ...
    debug_file = ctx.actions.declare_file(name + ".pdb")
    ...
    return [
        DefaultInfo(files = depset([output_file]), ...),
        OutputGroupInfo(
            debug_files = depset([debug_file]),
            all_files = depset([output_file, debug_file]),
        ),
        ...
    ]

また、ほとんどのプロバイダとは異なり、OutputGroupInfo は、同じ出力グループを定義しない限り、アスペクトと、そのアスペクトが適用されるルールターゲットの両方から返される可能性があります。その場合、結果のプロバイダが統合されます。

通常、OutputGroupInfo は、ターゲットからそのコンシューマーのアクションに特定の種類のファイルを伝えるために使用すべきではありません。代わりに、ルール固有のプロバイダを定義します。

構成

別のアーキテクチャ用の C++ バイナリをビルドするとします。ビルドは複雑で、複数のステップを伴う場合があります。コンパイラやコード生成ツールなどの中間バイナリの一部は、実行プラットフォーム（ホストまたはリモート実行ツール）で実行する必要があります。最終出力などの一部のバイナリは、ターゲットアーキテクチャ用にビルドする必要があります。

このため、Bazel には「構成」と「遷移」のコンセプトがあります。最上位のターゲット（コマンドラインでリクエストされたターゲット）は「target」構成でビルドされ、実行プラットフォームで実行されるツールは「exec」構成でビルドされます。ルールは、構成に基づいてさまざまなアクションを生成できます。たとえば、コンパイラに渡される CPU アーキテクチャを変更するなどです。場合によっては、同じライブラリが異なる構成で必要になることがあります。その場合、分析とビルドが複数回行われる可能性があります。

デフォルトでは、Bazel はターゲット自体と同じ構成でターゲットの依存関係をビルドします。つまり、移行なしでビルドします。依存関係がターゲットのビルドに必要なツールである場合、対応する属性で実行構成への移行を指定する必要があります。これにより、ツールとそのすべての依存関係が実行プラットフォーム用にビルドされます。

依存関係属性ごとに、cfg を使用して、依存関係を同じ構成でビルドするか、実行構成に移行するかを決定できます。依存関係属性にフラグ executable=True がある場合、cfg を明示的に設定する必要があります。これは、誤った構成のツールを誤ってビルドしないようにするためです。例を見る

一般に、実行時に必要となるソース、依存ライブラリ、実行可能ファイルは同じ構成を使用できます。

ビルドの一部として実行されるツール（コンパイラやコード生成ツールなど）は、exec 構成用にビルドする必要があります。この場合、属性で cfg="exec" を指定します。

それ以外の場合、実行時に使用される実行可能ファイル（テストの一部など）は、ターゲット構成用にビルドする必要があります。この場合、属性で cfg="target" を指定します。

cfg="target" は実際には何も行いません。ルール設計者が意図を明確にするための便宜的な値です。executable=False（cfg は省略可）の場合、読みやすさに本当に役立つ場合にのみ設定してください。

cfg=my_transition を使用してユーザー定義の遷移を使用することもできます。これにより、ルール作成者は構成を柔軟に変更できますが、ビルドグラフが大きくなり、理解しにくくなるという欠点があります。

注: 以前の Bazel には実行プラットフォームの概念がなく、すべてのビルドアクションはホストマシンで実行されるものと見なされていました。Bazel バージョン 6.0 より前では、これを表すために個別の「ホスト」構成が作成されていました。コードや古いドキュメントで「ホスト」という記述を見かけた場合は、このことを指しています。この余分な概念的オーバーヘッドを回避するには、Bazel 6.0 以降を使用することをおすすめします。

構成フラグメント

ルールは、cpp、java、jvm などの構成フラグメントにアクセスできます。ただし、アクセスエラーを回避するには、すべての必須フラグメントを宣言する必要があります。

def _impl(ctx):
    # Using ctx.fragments.cpp leads to an error since it was not declared.
    x = ctx.fragments.java
    ...

my_rule = rule(
    implementation = _impl,
    fragments = ["java"],      # Required fragments of the target configuration
    host_fragments = ["java"], # Required fragments of the host configuration
    ...
)

Runfiles シンボリックリンク

通常、runfiles ツリー内のファイルの相対パスは、ソースツリーまたは生成された出力ツリー内のそのファイルの相対パスと同じです。何らかの理由でこれらを異なるものにする必要がある場合は、root_symlinks 引数または symlinks 引数を指定できます。root_symlinks は、パスをファイルにマッピングする辞書です。パスは runfiles ディレクトリのルートを基準とする相対パスです。symlinks ディクショナリは同じですが、パスにはメインワークスペースの名前が暗黙的に接頭辞として付加されます（現在のターゲットを含むリポジトリの名前ではありません）。

    ...
    runfiles = ctx.runfiles(
        root_symlinks = {"some/path/here.foo": ctx.file.some_data_file2}
        symlinks = {"some/path/here.bar": ctx.file.some_data_file3}
    )
    # Creates something like:
    # sometarget.runfiles/
    #     some/
    #         path/
    #             here.foo -> some_data_file2
    #     <workspace_name>/
    #         some/
    #             path/
    #                 here.bar -> some_data_file3

symlinks または root_symlinks を使用する場合は、2 つの異なるファイルを runfiles ツリー内の同じパスにマッピングしないように注意してください。これにより、競合を説明するエラーが発生してビルドが失敗します。この問題を解決するには、ctx.runfiles 引数を変更して競合を解消する必要があります。このチェックは、ルールを使用するすべてのターゲットと、それらのターゲットに依存するあらゆる種類のターゲットに対して行われます。ツールが別のツールによって推移的に使用される可能性がある場合は、特に危険です。シンボリックリンク名は、ツールのランファイルとそのすべての依存関係で一意である必要があります。

コードカバレッジ

coverage コマンドを実行すると、ビルドで特定のターゲットのカバレッジ計測を追加する必要が生じることがあります。ビルドでは、計測されたソースファイルのリストも収集されます。考慮されるターゲットのサブセットは、フラグ --instrumentation_filter によって制御されます。--instrument_test_targets が指定されていない限り、テストターゲットは除外されます。

ルール実装でビルド時にカバレッジ計測を追加する場合は、実装関数でそれを考慮する必要があります。ターゲットのソースを計測する必要がある場合、カバレッジモードで ctx.coverage_instrumented は true を返します。

# Are this rule's sources instrumented?
if ctx.coverage_instrumented():
  # Do something to turn on coverage for this compile action

カバレッジモードで常にオンにする必要があるロジック（ターゲットのソースが明示的に計測されているかどうかに関係なく）は、ctx.configuration.coverage_enabled を条件にできます。

コンパイル前にルールが依存関係のソース（ヘッダーファイルなど）を直接含んでいる場合、依存関係のソースを計測する必要がある場合は、コンパイル時の計測を有効にする必要もあります。

# Are this rule's sources or any of the sources for its direct dependencies
# in deps instrumented?
if (ctx.configuration.coverage_enabled and
    (ctx.coverage_instrumented() or
     any([ctx.coverage_instrumented(dep) for dep in ctx.attr.deps]))):
    # Do something to turn on coverage for this compile action

ルールでは、coverage_common.instrumented_files_info を使用して構築された InstrumentedFilesInfo プロバイダによる補償に関連する属性に関する情報も提供する必要があります。instrumented_files_info の dependency_attributes パラメータには、deps などのコード依存関係や data などのデータ依存関係を含む、すべてのランタイム依存関係属性をリストする必要があります。カバレッジ計測が追加される可能性がある場合、source_attributes パラメータにはルールのソースファイル属性をリストする必要があります。

def _example_library_impl(ctx):
    ...
    return [
        ...
        coverage_common.instrumented_files_info(
            ctx,
            dependency_attributes = ["deps", "data"],
            # Omitted if coverage is not supported for this rule:
            source_attributes = ["srcs", "hdrs"],
        )
        ...
    ]

InstrumentedFilesInfo が返されない場合は、dependency_attributes に、属性スキーマで cfg を "host" または "exec" に設定していないツール以外の各依存関係属性を使用して、デフォルトのものが作成されます。（これは理想的な動作ではありません。srcs などの属性が source_attributes ではなく dependency_attributes に配置されるためです。ただし、依存関係チェーン内のすべてのルールに対して明示的なカバレッジ構成を行う必要がなくなります）。

検証アクション

ビルドについて何かを検証する必要がある場合、その検証に必要な情報がアーティファクト（ソースファイルまたは生成ファイル）にのみ含まれていることがあります。この情報はアーティファクトに含まれているため、ルールはファイルを読み取ることができないため、分析時にこの検証を行うことはできません。代わりに、アクションは実行時にこの検証を行う必要があります。検証に失敗すると、アクションが失敗し、ビルドも失敗します。

実行される検証の例としては、静的分析、linting、依存関係と整合性のチェック、スタイルチェックなどがあります。

検証アクションは、アーティファクトのビルドに必要のないアクションの一部を別のアクションに移動することで、ビルドのパフォーマンスを向上させることもできます。たとえば、コンパイルと lint を行う単一のアクションをコンパイルアクションと lint アクションに分離できる場合、lint アクションを検証アクションとして実行し、他のアクションと並行して実行できます。

これらの「検証アクション」は、入力に関するアサーションのみを行う必要があるため、ビルドの他の場所で使用されるものを生成しないことがよくあります。ただし、これには問題があります。検証アクションがビルドの他の場所で使用されるものを生成しない場合、ルールはどのようにしてアクションを実行するのでしょうか？従来は、検証アクションで空のファイルを出力し、その出力をビルド内の他の重要なアクションの入力に人工的に追加していました。

これは、コンパイルアクションが実行されると Bazel が常に検証アクションを実行するため機能しますが、次のような大きな欠点があります。

検証アクションはビルドのクリティカルパスにあります。Bazel は、コンパイルアクションを実行するには空の出力が必要であると認識するため、コンパイルアクションが入力を無視する場合でも、最初に検証アクションを実行します。これにより、並列処理が減少し、ビルドが遅くなります。
ビルド内の他のアクションがコンパイルアクションの代わりに実行される可能性がある場合は、検証アクションの空の出力もそれらのアクションに追加する必要があります（java_library のソース jar 出力など）。コンパイルアクションの代わりに実行される可能性のある新しいアクションが後で追加され、空の検証出力が誤って残された場合も、問題が発生します。

これらの問題を解決するには、検証出力グループを使用します。

Validations Output Group

検証出力グループは、検証アクションの未使用の出力を保持するように設計された出力グループです。これにより、他のアクションの入力に人工的に追加する必要がなくなります。

このグループは、--output_groups フラグの値や、ターゲットの依存関係（コマンドライン、依存関係、ターゲットの暗黙的な出力など）に関係なく、出力が常にリクエストされるという点で特殊です。通常のキャッシュ保存と増分は引き続き適用されます。検証アクションの入力が変更されておらず、検証アクションが以前に成功した場合は、検証アクションは実行されません。

この出力グループを使用する場合でも、検証アクションで空のファイルを含むファイルを出力する必要があります。通常は出力を生成しないツールをラップして、ファイルが作成されるようにする必要がある場合があります。

ターゲットの検証アクションは、次の 3 つの場合には実行されません。

ターゲットがツールとして依存されている場合
ターゲットが暗黙的な依存関係として依存している場合（たとえば、「_」で始まる属性）
ターゲットがホストまたは exec 構成でビルドされる場合。

これらのターゲットには、検証の失敗を検出する独自のビルドとテストが別個に存在すると想定されます。

Validations 出力グループの使用

検証出力グループの名前は _validation で、他の出力グループと同様に使用されます。

def _rule_with_validation_impl(ctx):

  ctx.actions.write(ctx.outputs.main, "main output\n")

  ctx.actions.write(ctx.outputs.implicit, "implicit output\n")

  validation_output = ctx.actions.declare_file(ctx.attr.name + ".validation")
  ctx.actions.run(
      outputs = [validation_output],
      executable = ctx.executable._validation_tool,
      arguments = [validation_output.path])

  return [
    DefaultInfo(files = depset([ctx.outputs.main])),
    OutputGroupInfo(_validation = depset([validation_output])),
  ]


rule_with_validation = rule(
  implementation = _rule_with_validation_impl,
  outputs = {
    "main": "%{name}.main",
    "implicit": "%{name}.implicit",
  },
  attrs = {
    "_validation_tool": attr.label(
        default = Label("//validation_actions:validation_tool"),
        executable = True,
        cfg = "exec"),
  }
)

検証出力ファイルは、DefaultInfo にも他のアクションの入力にも追加されません。このルール種類のターゲットの検証アクションは、ターゲットがラベルによって依存されている場合、またはターゲットの暗黙的な出力のいずれかが直接的または間接的に依存されている場合でも実行されます。

通常、検証アクションの出力は検証出力グループにのみ渡され、他のアクションの入力には追加されないことが重要です。これは、並列処理のメリットが失われる可能性があるためです。ただし、Bazel には現在、これを強制するための特別なチェックはありません。したがって、Starlark ルールのテストで、検証アクションの出力がアクションの入力に追加されないことをテストする必要があります。次に例を示します。

load("@bazel_skylib//lib:unittest.bzl", "analysistest")

def _validation_outputs_test_impl(ctx):
  env = analysistest.begin(ctx)

  actions = analysistest.target_actions(env)
  target = analysistest.target_under_test(env)
  validation_outputs = target.output_groups._validation.to_list()
  for action in actions:
    for validation_output in validation_outputs:
      if validation_output in action.inputs.to_list():
        analysistest.fail(env,
            "%s is a validation action output, but is an input to action %s" % (
                validation_output, action))

  return analysistest.end(env)

validation_outputs_test = analysistest.make(_validation_outputs_test_impl)

Validation Actions Flag

検証アクションの実行は、--run_validations コマンドラインフラグによって制御されます。このフラグのデフォルト値は true です。

サポートが終了した機能

事前宣言された出力のサポートを終了しました

事前宣言された出力を使用する方法は 2 つありますが、どちらも非推奨です。

rule の outputs パラメータは、出力属性名と、事前宣言された出力ラベルを生成するための文字列テンプレート間のマッピングを指定します。事前宣言されていない出力を使用し、出力を DefaultInfo.files に明示的に追加することをおすすめします。事前宣言された出力のラベルではなく、出力を消費するルールの入力としてルールターゲットのラベルを使用します。
実行可能ルールの場合、ctx.outputs.executable は、ルールターゲットと同じ名前の事前宣言された実行可能出力を参照します。ctx.actions.declare_file(ctx.label.name) などを使用して出力を明示的に宣言し、実行可能ファイルを生成するコマンドで実行を許可する権限が設定されていることを確認することをおすすめします。実行可能ファイルの出力を DefaultInfo の executable パラメータに明示的に渡します。

避けるべき Runfile の機能

ctx.runfiles 型と runfiles 型には複雑な機能セットがあり、その多くは以前の理由で保持されています。次の推奨事項は、複雑さを軽減するのに役立ちます。

ctx.runfiles の collect_data モードと collect_default モードの使用は避けてください。これらのモードでは、特定のハードコードされた依存関係エッジ全体で、実行ファイルが暗黙的に収集されます。代わりに、ctx.runfiles の files パラメータまたは transitive_files パラメータを使用してファイルを追加するか、runfiles = runfiles.merge(dep[DefaultInfo].default_runfiles) を使用して依存関係からランファイルにマージします。
DefaultInfo コンストラクタの data_runfiles と default_runfiles の使用は避けてください。代わりに DefaultInfo(runfiles = ...) を指定してください。「default」と「data」のランファイルが区別されているのは、以前の理由によるものです。たとえば、一部のルールでは、デフォルトの出力が data_runfiles に配置されますが、default_runfiles には配置されません。data_runfiles を使用する代わりに、ルールにはデフォルトの出力を含め、ランファイルを提供する属性（通常は data）から default_runfiles をマージする必要があります。
DefaultInfo から runfiles を取得する場合（通常は、現在のルールとその依存関係の間でランファイルのマージを行う場合のみ）、DefaultInfo.data_runfiles ではなく DefaultInfo.default_runfiles を使用します。

以前のプロバイダからの移行

これまで、Bazel プロバイダは Target オブジェクトの単純なフィールドでした。これらはドット演算子を使用してアクセスされ、ルールの実装関数によって返される構造体にフィールドを配置することで作成されました。

このスタイルは非推奨であり、新しいコードで使用すべきではありません。移行に役立つ情報については、以下をご覧ください。新しいプロバイダメカニズムにより、名前の衝突が回避されます。また、プロバイダインスタンスにアクセスするコードがプロバイダシンボルを使用してインスタンスを取得することを要求することで、データ隠蔽もサポートします。

当面の間、以前のプロバイダは引き続きサポートされます。ルールでは、次のようにレガシープロバイダと最新のプロバイダの両方を返すことができます。

def _old_rule_impl(ctx):
  ...
  legacy_data = struct(x="foo", ...)
  modern_data = MyInfo(y="bar", ...)
  # When any legacy providers are returned, the top-level returned value is a
  # struct.
  return struct(
      # One key = value entry for each legacy provider.
      legacy_info = legacy_data,
      ...
      # Additional modern providers:
      providers = [modern_data, ...])

dep がこのルールのインスタンスの結果の Target オブジェクトである場合、プロバイダとそのコンテンツは dep.legacy_info.x と dep[MyInfo].y として取得できます。

providers に加えて、返される構造体は特別な意味を持つ他のフィールドもいくつか受け取ることができます（そのため、対応するレガシープロバイダは作成されません）。

フィールド files、runfiles、data_runfiles、default_runfiles、executable は、DefaultInfo の同じ名前のフィールドに対応しています。DefaultInfo プロバイダを返すときに、これらのフィールドのいずれかを指定することはできません。
フィールド output_groups は構造体の値を受け取り、OutputGroupInfo に対応します。

ルールの provides 宣言と依存関係属性の providers 宣言では、以前のプロバイダは文字列として渡され、最新のプロバイダは *Info 記号で渡されます。移行する際は、必ず文字列からシンボルに変更してください。すべてのルールをアトミックに更新することが難しい複雑なルールセットや大規模なルールセットの場合は、次の手順に沿って操作すると、より簡単に更新できます。

上記の構文を使用して、レガシープロバイダを生成するルールを変更し、レガシープロバイダとモダンプロバイダの両方を生成します。以前のプロバイダを返すことを宣言するルールについては、その宣言を更新して、以前のプロバイダと最新のプロバイダの両方を含めます。
以前のプロバイダを使用するルールを、最新のプロバイダを使用するように変更します。属性宣言でレガシープロバイダが必要な場合は、最新のプロバイダが必要になるように更新します。必要に応じて、コンシューマーがプロバイダのいずれかを受け入れるか、必要とするようにして、この作業をステップ 1 とインターリーブできます。プロバイダ: hasattr(target, 'foo') を使用してレガシープロバイダの存在をテストするか、FooInfo in target を使用して新しいプロバイダの存在をテストします。
すべてのルールから以前のプロバイダを完全に削除します。

ルール