Depset は、ターゲットの推移的依存関係全体でデータを効率的に収集するための特別なデータ構造です。これらはルール処理に不可欠な要素です。
depset の特徴は、時間効率とスペース効率に優れたユニオン演算です。depset コンストラクタは、要素のリスト（「direct」）と他の depset のリスト（「transitive」）を受け取り、すべての直接要素を含むセットとすべての推移的セットの結合を表す depset を返します。概念的には、コンストラクタは直接ノードと推移ノードを後続ノードとする新しいグラフノードを作成します。依存関係には、このグラフの走査に基づいて明確に定義された順序セマンティクスがあります。
依存関係の使用例を次に示します。
プログラムのライブラリのすべてのオブジェクト ファイルのパスを保存します。このパスは、プロバイダを介してリンカー アクションに渡すことができます。
インタプリタ言語の場合、実行可能ファイルの runfile に含まれる推移的ソースファイルを保存します。
説明とオペレーション
概念的には、デプセットは有向非巡回グラフ（DAG）であり、通常はターゲット グラフによく似ています。葉から根まで体を形成します。依存関係チェーン内の各ターゲットは、読み取りやコピーをすることなく、以前のコンテンツの上に独自のコンテンツを追加できます。
DAG 内の各ノードは、直接要素のリストと子ノードのリストを保持します。depset の内容は推移的要素です（すべてのノードの直接要素など）。depset コンストラクタを使用して新しい depset を作成できます。このコンストラクタは直接要素のリストと子ノードのリストを受け入れます。
s = depset(["a", "b", "c"])
t = depset(["d", "e"], transitive = [s])
print(s) # depset(["a", "b", "c"])
print(t) # depset(["d", "e", "a", "b", "c"])
depset の内容を取得するには、to_list() メソッドを使用します。重複を除くすべての推移的要素のリストを返します。DAG の正確な構造を直接調べる方法はありませんが、この構造は要素が返される順序に影響します。
s = depset(["a", "b", "c"])
print("c" in s.to_list()) # True
print(s.to_list() == ["a", "b", "c"]) # True
ディクショナリで許可されるキーが制限されているのと同様に、depset で許可されるアイテムも制限されます。特に、depset のコンテンツは変更できない可能性があります。
Depset は参照等式を使用します。depset はそれ自体と等しいものの、内容や内部構造が同じであっても、他の depset とは等しくありません。
s = depset(["a", "b", "c"])
t = s
print(s == t) # True
t = depset(["a", "b", "c"])
print(s == t) # False
d = {}
d[s] = None
d[t] = None
print(len(d)) # 2
依存関係を内容によって比較するには、並べ替えたリストに変換します。
s = depset(["a", "b", "c"])
t = depset(["c", "b", "a"])
print(sorted(s.to_list()) == sorted(t.to_list())) # True
依存関係から要素を削除する機能はありません。これが必要な場合は、depset の内容全体を読み、削除する要素をフィルタリングして、新しい depset を再構築する必要があります。これは、特に効率的ではありません。
s = depset(["a", "b", "c"])
t = depset(["b", "c"])
# Compute set difference s - t. Precompute t.to_list() so it's not done
# in a loop, and convert it to a dictionary for fast membership tests.
t_items = {e: None for e in t.to_list()}
diff_items = [x for x in s.to_list() if x not in t_items]
# Convert back to depset if it's still going to be used for union operations.
s = depset(diff_items)
print(s) # depset(["a"])
注文
to_list オペレーションは DAG を走査します。走査の種類は、depset の作成時に指定された順序によって異なります。ツールが入力の順序を考慮する場合があるため、Bazel で複数の注文をサポートすると便利です。たとえば、リンカー アクションでは、B が A に依存している場合、リンカーのコマンドラインで A.o が B.o の前に来るようにする必要があります。逆の要件があるツールもあります。
サポートされている走査順序は、postorder、preorder、topological の 3 つです。最初の 2 つは、DAG を操作し、すでにアクセスしているノードをスキップする点を除き、ツリー トラバーサルとまったく同じように機能します。3 番目の順序は、ルートからリーフへのトポロジソートとして機能します。本質的に preorder と同じですが、共有された子はすべての親の後にのみリストされます。preorder と postorder は左から右のトラバーサルとして動作しますが、各ノード内で直接要素は子に対して順序付けされません。トポロジ順では、左から右への保証はなく、DAG の異なるノードに重複する要素がある場合、all-parents-before-child 保証は適用されません。
# This demonstrates different traversal orders.
def create(order):
cd = depset(["c", "d"], order = order)
gh = depset(["g", "h"], order = order)
return depset(["a", "b", "e", "f"], transitive = [cd, gh], order = order)
print(create("postorder").to_list()) # ["c", "d", "g", "h", "a", "b", "e", "f"]
print(create("preorder").to_list()) # ["a", "b", "e", "f", "c", "d", "g", "h"]
# This demonstrates different orders on a diamond graph.
def create(order):
a = depset(["a"], order=order)
b = depset(["b"], transitive = [a], order = order)
c = depset(["c"], transitive = [a], order = order)
d = depset(["d"], transitive = [b, c], order = order)
return d
print(create("postorder").to_list()) # ["a", "b", "c", "d"]
print(create("preorder").to_list()) # ["d", "b", "a", "c"]
print(create("topological").to_list()) # ["d", "b", "c", "a"]
走査の実装方法により、順序は、コンストラクタの order キーワード引数を使用して depset を作成するときに指定する必要があります。この引数を省略すると、depset は default という特殊な順序になります。この場合、要素の順序は保証されません（確定的である場合を除きます）。
完全な例
この例は https://github.com/bazelbuild/examples/tree/main/rules/depsets にあります。
仮のインタプリタ言語 Foo があるとします。各 foo_binary をビルドするには、それが直接的または間接的に依存するすべての *.foo ファイルを把握している必要があります。
# //depsets:BUILD
load(":foo.bzl", "foo_library", "foo_binary")
# Our hypothetical Foo compiler.
py_binary(
name = "foocc",
srcs = ["foocc.py"],
)
foo_library(
name = "a",
srcs = ["a.foo", "a_impl.foo"],
)
foo_library(
name = "b",
srcs = ["b.foo", "b_impl.foo"],
deps = [":a"],
)
foo_library(
name = "c",
srcs = ["c.foo", "c_impl.foo"],
deps = [":a"],
)
foo_binary(
name = "d",
srcs = ["d.foo"],
deps = [":b", ":c"],
)
# //depsets:foocc.py
# "Foo compiler" that just concatenates its inputs to form its output.
import sys
if __name__ == "__main__":
assert len(sys.argv) >= 1
output = open(sys.argv[1], "wt")
for path in sys.argv[2:]:
input = open(path, "rt")
output.write(input.read())
ここで、バイナリ d の推移ソースは、a、b、c、d の srcs フィールドにあるすべての *.foo ファイルです。foo_binary ターゲットが d.foo 以外のファイルを認識できるようにするには、foo_library ターゲットがそれらをプロバイダに渡す必要があります。各ライブラリは、独自の依存関係からプロバイダを受け取り、独自の即時ソースを追加して、拡張されたコンテンツを含む新しいプロバイダを渡します。foo_binary ルールも同じですが、プロバイダを返す代わりに、ソースの完全なリストを使用してアクションのコマンドラインを作成します。
foo_library ルールと foo_binary ルールの実装全体は次のとおりです。
# //depsets/foo.bzl
# A provider with one field, transitive_sources.
FooFiles = provider(fields = ["transitive_sources"])
def get_transitive_srcs(srcs, deps):
"""Obtain the source files for a target and its transitive dependencies.
Args:
srcs: a list of source files
deps: a list of targets that are direct dependencies
Returns:
a collection of the transitive sources
"""
return depset(
srcs,
transitive = [dep[FooFiles].transitive_sources for dep in deps])
def _foo_library_impl(ctx):
trans_srcs = get_transitive_srcs(ctx.files.srcs, ctx.attr.deps)
return [FooFiles(transitive_sources=trans_srcs)]
foo_library = rule(
implementation = _foo_library_impl,
attrs = {
"srcs": attr.label_list(allow_files=True),
"deps": attr.label_list(),
},
)
def _foo_binary_impl(ctx):
foocc = ctx.executable._foocc
out = ctx.outputs.out
trans_srcs = get_transitive_srcs(ctx.files.srcs, ctx.attr.deps)
srcs_list = trans_srcs.to_list()
ctx.actions.run(executable = foocc,
arguments = [out.path] + [src.path for src in srcs_list],
inputs = srcs_list + [foocc],
outputs = [out])
foo_binary = rule(
implementation = _foo_binary_impl,
attrs = {
"srcs": attr.label_list(allow_files=True),
"deps": attr.label_list(),
"_foocc": attr.label(default=Label("//depsets:foocc"),
allow_files=True, executable=True, cfg="host")
},
outputs = {"out": "%{name}.out"},
)
これをテストするには、これらのファイルを新しいパッケージにコピーし、ラベル名を適切に変更し、ダミー コンテンツを含むソース *.foo ファイルを作成して、d ターゲットを構築します。
パフォーマンス
依存関係を使用する動機を確認するため、get_transitive_srcs() がソースをリストに収集した場合にどうなるかを考えてみましょう。
def get_transitive_srcs(srcs, deps):
trans_srcs = []
for dep in deps:
trans_srcs += dep[FooFiles].transitive_sources
trans_srcs += srcs
return trans_srcs
重複は考慮されないため、a のソースファイルはコマンドラインで 2 回、出力ファイルの内容に 2 回表示されます。
もう 1 つの方法として、汎用セットを使用する方法があります。これは、キーが要素であり、すべてのキーが True にマッピングされている辞書によってシミュレートできます。
def get_transitive_srcs(srcs, deps):
trans_srcs = {}
for dep in deps:
for file in dep[FooFiles].transitive_sources:
trans_srcs[file] = True
for file in srcs:
trans_srcs[file] = True
return trans_srcs
これにより重複は取り除かれますが、コマンドライン引数の順序（つまりファイルの内容）は確定的ですが、指定されません。
さらに、どちらのアプローチも、デプセット ベースのアプローチよりも漸近的に悪くなっています。Foo ライブラリに長い依存関係チェーンがある場合を考えてみましょう。すべてのルールを処理するには、その前のすべての推移的ソースを新しいデータ構造にコピーする必要があります。つまり、個々のライブラリまたはバイナリ ターゲットの分析にかかる時間とスペースのコストは、チェーン内の自身の高さに比例します。長さ n のチェーンの場合、foolib_1 ← foolib_2 ← ... ← foolib_n の場合、全体のコストは実質的に O(n^2) になります。
一般に、推移的依存関係を通じて情報を蓄積する場合は常に depset を使用する必要があります。これにより、ビルドのスケーリングとターゲット グラフの成長が可能になります。
最後に、ルールの実装で depset のコンテンツを不必要に取得しないようにすることが重要です。全体的なコストは O(n) のみであるため、バイナリルールの最後に to_list() を 1 回呼び出すだけで十分です。多くの非終端ターゲットが to_list() を呼び出そうとすると、二次的な動作が発生します。
依存関係を効率的に使用する方法については、パフォーマンス ページをご覧ください。
API リファレンス
詳しくは、こちらをご覧ください。