빌드 스타일 가이드

7.3 · 7.2 · 7.1 · 7.0 · 6.5

BUILD 파일 형식 지정은 Go와 동일한 접근 방식을 따르며, 여기서는 표준화된 도구가 대부분의 서식 문제를 처리합니다. Buildifier는 소스 코드를 표준 스타일로 파싱하고 내보내는 도구입니다. 따라서 모든 BUILD 파일은 동일한 자동화된 방식으로 형식이 지정되므로 코드 검토 중에 형식 지정이 문제가 되지 않습니다. 또한 도구가 BUILD 파일을 더 쉽게 이해, 수정, 생성할 수 있습니다.

BUILD 파일 형식은 buildifier의 출력과 일치해야 합니다.

형식 지정 예

# Test code implementing the Foo controller.
package(default_testonly = True)

py_test(
    name = "foo_test",
    srcs = glob(["*.py"]),
    data = [
        "//data/production/foo:startfoo",
        "//foo",
        "//third_party/java/jdk:jdk-k8",
    ],
    flaky = True,
    deps = [
        ":check_bar_lib",
        ":foo_data_check",
        ":pick_foo_port",
        "//pyglib",
        "//testing/pybase",
    ],
)

파일 구조

권장사항: 다음 순서를 사용하세요 (모든 요소는 선택사항임).

패키지 설명(주석)
전체 load() 문
package() 함수
규칙 및 매크로 호출

Buildifier는 독립형 주석과 요소에 연결된 주석을 구분합니다. 주석이 특정 요소에 연결되어 있지 않은 경우 그 뒤에 빈 줄을 사용합니다. 이러한 구별은 자동 변경을 수행할 때 중요합니다 (예: 규칙을 삭제할 때 댓글 유지 또는 삭제).

# Standalone comment (such as to make a section in a file)

# Comment for the cc_library below
cc_library(name = "cc")

현재 패키지의 타겟 참조

파일은 패키지 디렉터리에 상대적인 경로로 참조되어야 합니다(..와 같은 상위 참조를 사용하지 않음). 생성된 파일의 접두어에는 ':'가 추가되어야 소스가 아님을 나타냅니다. 소스 파일에는 :이라는 접두사가 붙지 않아야 합니다. 규칙에는 : 프리픽스를 붙여야 합니다. 예를 들어 x.cc를 소스 파일이라고 가정해 보겠습니다.

cc_library(
    name = "lib",
    srcs = ["x.cc"],
    hdrs = [":gen_header"],
)

genrule(
    name = "gen_header",
    srcs = [],
    outs = ["x.h"],
    cmd = "echo 'int x();' > $@",
)

타겟 이름 지정

타겟 이름은 설명적이어야 합니다. 타겟에 소스 파일이 하나 포함된 경우 일반적으로 타겟의 이름은 해당 소스에서 파생된 이름이어야 합니다. 예를 들어 chat.cc의 cc_library는 chat로 이름을 지정할 수 있고 DirectMessage.java의 java_library는 direct_message로 이름을 지정할 수 있습니다.

패키지의 동명 타겟(포함하는 디렉터리와 동일한 이름의 타겟)은 디렉터리 이름으로 설명된 기능을 제공해야 합니다. 이러한 타겟이 없으면 동명의 타겟을 만들지 마세요.

동명이의 타겟을 참조할 때는 짧은 이름을 사용하는 것이 좋습니다(//x:x 대신 //x). 같은 패키지에 있는 경우 로컬 참조를 사용하는 것이 좋습니다(//x 대신 :x).

특별한 의미가 있는 '예약된' 타겟 이름은 사용하지 마세요. 여기에는 all, __pkg__, __subpackages__가 포함되며, 이러한 이름은 특수한 의미 체계를 가지므로 사용될 때 혼란과 예기치 않은 동작이 발생할 수 있습니다.

일반적인 팀 관례가 없는 경우 다음은 Google에서 널리 사용되는 비구속적 권장사항입니다.

일반적으로 'snake_case'를 사용합니다.
- src가 하나 있는 java_library의 경우 확장자가 없는 파일 이름과 동일하지 않은 이름을 사용합니다.
- Java *_binary 및 *_test 규칙의 경우 'Upper CamelCase'를 사용합니다. 이렇게 하면 대상 이름이 src 중 하나와 일치할 수 있습니다. java_test의 경우 이렇게 하면 test_class 속성을 타겟 이름에서 추론할 수 있습니다.
특정 타겟의 변형이 여러 개인 경우 구분하기 위해 접미사를 추가합니다(예: :foo_dev, :foo_prod 또는 :bar_x86, :bar_x64)
_test, _unittest, Test 또는 Tests로 _test 타겟의 접미사를 지정합니다.
_lib 또는 _library와 같이 무의미한 접미사는 사용하지 않습니다 (_library 타겟과 상응하는 _binary 간의 충돌을 피하는 데 필요한 경우는 예외).
proto 관련 타겟의 경우:
- proto_library 대상의 이름은 _proto(으)로 끝나야 합니다.
- 언어별 *_proto_library 규칙은 기본 프로토와 일치해야 하지만 _proto를 다음과 같은 언어별 접미사로 대체해야 합니다.
  - cc_proto_library: _cc_proto
  - java_proto_library: _java_proto
  - java_lite_proto_library: _java_proto_lite

공개 상태

가시성은 테스트 및 역 종속 항목의 액세스를 허용하는 동시에 최대한 엄격하게 범위를 지정해야 합니다. __pkg__ 및 __subpackages__를 적절하게 사용합니다.

default_visibility 패키지를 //visibility:public로 설정하지 마세요. //visibility:public는 프로젝트의 공개 API에 있는 타겟에 대해서만 개별적으로 설정해야 합니다. 외부 프로젝트에서 종속되도록 설계된 라이브러리 또는 외부 프로젝트의 빌드 프로세스에서 사용할 수 있는 바이너리일 수 있습니다.

종속 항목

종속 항목은 직접 종속 항목(규칙에 나열된 소스에 필요한 종속 항목)으로 제한해야 합니다. 전이 종속 항목은 나열하지 마세요.

패키지 로컬 종속 항목은 먼저 나열되고 위의 현재 패키지의 타겟 참조 섹션과 호환되는 방식으로 참조되어야 합니다(절대 패키지 이름이 아닌 방식으로 참조).

종속 항목을 단일 목록으로 직접 나열하는 것이 좋습니다. 여러 대상의 '공통' 종속 항목을 변수에 배치하면 유지보수성이 저하되고 도구가 대상의 종속 항목을 변경할 수 없게 되며 사용되지 않는 종속 항목이 발생할 수 있습니다.

Glob

[]로 '타겟 없음'을 나타냅니다. 아무것도 일치하지 않는 glob은 사용하지 마세요. 빈 목록보다 오류가 발생하기 쉽고 덜 명확합니다.

재귀적

재귀 glob를 사용하여 소스 파일을 일치시키지 마세요(예: glob(["**/*.java"])).

재귀형 글롭은 BUILD 파일이 포함된 하위 디렉터리를 건너뛰므로 BUILD 파일을 추론하기 어렵게 만듭니다.

재귀 glob은 디렉터리당 BUILD 파일이 있고 그 사이에 종속 항목 그래프가 정의되어 있는 것보다 일반적으로 덜 효율적입니다. 이렇게 하면 원격 캐싱 및 동시 로드가 향상되기 때문입니다.

각 디렉터리에 BUILD 파일을 작성하고 파일 간에 종속 항목 그래프를 정의하는 것이 좋습니다.

비재귀적

비재귀식 글롭은 일반적으로 허용됩니다.

기타 규칙

대문자와 밑줄을 사용하여 상수(예: GLOBAL_CONSTANT)를 선언하고 소문자와 밑줄을 사용하여 변수(예: my_variable)를 선언합니다.
라벨은 79자(영문 기준)를 초과하더라도 분할해서는 안 됩니다. 라벨은 가능하면 문자열 리터럴이어야 합니다. 사유: 쉽게 찾고 바꿀 수 있습니다. 가독성도 개선됩니다.
이름 속성의 값은 리터럴 상수 문자열이어야 합니다(매크로 제외). 근거: 외부 도구는 이름 속성을 사용하여 규칙을 참조합니다. 코드를 해석하지 않고도 규칙을 찾아야 합니다.
불리언 유형 속성을 설정할 때는 정수 값이 아닌 불리언 값을 사용하세요. 기존 이유로 인해 규칙은 필요에 따라 여전히 정수를 불리언으로 변환하지만, 그러지 않는 것이 좋습니다. 근거: flaky = 1는 '이 타겟을 한 번 다시 실행하여 불안정 제거'로 오해될 수 있습니다. flaky = True가 명확하게 '이 테스트는 불안정합니다'라고 말합니다.

Python 스타일 가이드와의 차이점

Python 스타일 가이드와의 호환성이 목표이지만 몇 가지 차이점이 있습니다.

엄격한 행 길이 제한은 없습니다. 긴 주석과 long 문자열은 종종 79개 열로 분할되지만 필수는 아닙니다. 코드 검토나 사전 제출 스크립트에서는 적용해서는 안 됩니다. 근거: 라벨이 길어 이 한도를 초과할 수 있습니다. BUILD 파일은 일반적으로 도구로 생성되거나 수정되며, 이는 줄 길이 제한과 잘 맞지 않습니다.
암시적 문자열 연결은 지원되지 않습니다. + 연산자를 사용합니다. 근거: BUILD 파일에는 많은 문자열 목록이 포함되어 있습니다. 쉼표를 잊어버리기 쉽고, 이로 인해 완전히 다른 결과가 나오기도 합니다. 이로 인해 과거에 많은 버그가 발생했습니다. 이 토론도 참고하세요.
규칙에서 키워드 인수에 = 기호 주위에 공백을 사용합니다. 사유: 이름이 지정된 인수는 Python보다 훨씬 자주 사용되며 항상 별도의 줄에 있습니다. 공백은 가독성을 개선합니다. 이 규칙은 오랫동안 사용되어 왔으므로 기존의 모든 BUILD 파일을 수정할 필요는 없습니다.
기본적으로 문자열에는 큰따옴표를 사용합니다. 근거: Python 스타일 가이드에 명시되어 있지는 않지만 일관성을 권장합니다. 따라서 큰따옴표로 묶은 문자열만 사용하기로 결정했습니다. 많은 언어에서 문자열 리터럴에 큰따옴표를 사용합니다
두 개의 최상위 정의 사이에 빈 줄 하나를 사용합니다. 사유: BUILD 파일의 구조는 일반적인 Python 파일과 다릅니다. 최상위 문이 빈 줄을 사용하면 BUILD 파일이 더 짧아집니다.