Maven에서 Bazel로 마이그레이션

문제 신고 소스 보기 나이틀리 · 8.3 · 8.2 · 8.1 · 8.0 · 7.6

이 페이지에서는 필수 요건과 설치 단계를 비롯하여 Maven에서 Bazel로 이전하는 방법을 설명합니다. Maven과 Bazel의 차이점을 설명하고 Guava 프로젝트를 사용하는 이전 예를 제공합니다.

빌드 도구에서 Bazel로 이전할 때는 개발팀, CI 시스템, 기타 관련 시스템을 완전히 이전할 때까지 두 빌드 도구를 동시에 실행하는 것이 좋습니다. 동일한 저장소에서 Maven과 Bazel을 실행할 수 있습니다.

참고: Bazel은 rules_jvm_external을 사용하여 Maven 아티팩트 다운로드 및 게시를 지원하지만 Maven 기반 플러그인은 직접 지원하지 않습니다. Maven 호환성 레이어가 없으므로 Maven 플러그인을 Bazel에서 직접 실행할 수 없습니다.

시작하기 전에

• 아직 설치되어 있지 않다면 Bazel을 설치합니다.
• Bazel을 처음 사용하는 경우 이전하기 전에 Bazel 소개: Java 빌드 튜토리얼을 살펴보세요. 이 튜토리얼에서는 Bazel의 개념, 구조, 라벨 문법을 설명합니다.

Maven과 Bazel의 차이점

• Maven은 최상위 pom.xml 파일을 사용합니다. Bazel은 BUILD 파일당 여러 빌드 파일과 여러 타겟을 지원하므로 Maven보다 더 점진적인 빌드가 가능합니다.
• Maven이 배포 프로세스의 단계를 담당합니다. Bazel은 배포를 자동화하지 않습니다.
• Bazel을 사용하면 언어 간 종속 항목을 표현할 수 있습니다.
• 프로젝트에 새 섹션을 추가할 때 Bazel을 사용하면 새 BUILD 파일을 추가해야 할 수 있습니다. 각 새 Java 패키지에 BUILD 파일을 추가하는 것이 좋습니다.

Maven에서 Bazel로 이전

아래 단계에서는 프로젝트를 Bazel로 이전하는 방법을 설명합니다.

1. MODULE.bazel 파일 만들기
2. 하나의 BUILD 파일 만들기
3. BUILD 파일 추가 생성
4. Bazel을 사용하여 빌드

아래 예시는 Maven에서 Bazel로 Guava 프로젝트를 이전하는 과정에서 가져온 것입니다. 사용된 Guava 프로젝트는 v31.1 버전입니다. Guava를 사용하는 예시에서는 이전의 각 단계를 안내하지는 않지만 이전 시 생성되거나 수동으로 추가되는 파일과 콘텐츠를 보여줍니다.

$ git clone https://github.com/google/guava.git && cd guava
$ git checkout v31.1

1. MODULE.bazel 파일 만들기

프로젝트 루트에 MODULE.bazel라는 이름의 파일을 만듭니다. 프로젝트에 외부 종속 항목이 없는 경우 이 파일은 비어 있을 수 있습니다.

프로젝트가 프로젝트 디렉터리 중 하나에 없는 파일이나 패키지에 종속되는 경우 MODULE.bazel 파일에 이러한 외부 종속 항목을 지정합니다. rules_jvm_external을 사용하여 Maven의 종속 항목을 관리할 수 있습니다. 이 규칙 집합 사용에 대한 안내는 리드미를 참고하세요.

Guava 프로젝트 예: 외부 종속 항목

rules_jvm_external 규칙 세트를 사용하여 Guava 프로젝트의 외부 종속 항목을 나열할 수 있습니다.

MODULE.bazel 파일에 다음 스니펫을 추가합니다.

bazel_dep(name = "rules_jvm_external", version = "6.2")
maven = use_extension("@rules_jvm_external//:extensions.bzl", "maven")
maven.install(
    artifacts = [
        "com.google.code.findbugs:jsr305:3.0.2",
        "com.google.errorprone:error_prone_annotations:2.11.0",
        "com.google.j2objc:j2objc-annotations:1.3",
        "org.codehaus.mojo:animal-sniffer-annotations:1.20",
        "org.checkerframework:checker-qual:3.12.0",
    ],
    repositories = [
        "https://repo1.maven.org/maven2",
    ],
)
use_repo(maven, "maven")

2. BUILD 파일 하나 만들기

작업공간을 정의하고 외부 종속 항목 (해당하는 경우)을 나열했으므로 이제 프로젝트를 빌드하는 방법을 설명하는 BUILD 파일을 만들어야 합니다. pom.xml 파일 하나를 사용하는 Maven과 달리 Bazel은 여러 BUILD 파일을 사용하여 프로젝트를 빌드할 수 있습니다. 이러한 파일은 여러 빌드 타겟을 지정하므로 Bazel이 증분 빌드를 생성할 수 있습니다.

단계별로 BUILD 파일을 추가합니다. 프로젝트 루트에 BUILD 파일을 하나 추가하고 이를 사용하여 Bazel을 사용한 초기 빌드를 실행합니다. 그런 다음 더 세부적인 타겟이 있는 BUILD 파일을 추가하여 빌드를 개선합니다.

1. MODULE.bazel 파일과 동일한 디렉터리에서 텍스트 파일을 만들고 BUILD이라고 이름을 지정합니다.

2. 이 BUILD 파일에서 적절한 규칙을 사용하여 프로젝트를 빌드할 타겟 하나를 만듭니다. 다음은 몇 가지 팁입니다.

   • 적절한 규칙을 사용하세요.

     • 단일 Maven 모듈로 프로젝트를 빌드하려면 다음과 같이 java_library 규칙을 사용하세요.

       java_library(
          name = "everything",
          srcs = glob(["src/main/java/**/*.java"]),
          resources = glob(["src/main/resources/**"]),
          deps = ["//:all-external-targets"],
       )
       

     • 여러 Maven 모듈로 프로젝트를 빌드하려면 다음과 같이 java_library 규칙을 사용하세요.

       java_library(
          name = "everything",
          srcs = glob([
                "Module1/src/main/java/**/*.java",
                "Module2/src/main/java/**/*.java",
                ...
          ]),
          resources = glob([
                "Module1/src/main/resources/**",
                "Module2/src/main/resources/**",
                ...
          ]),
          deps = ["//:all-external-targets"],
       )
       

     • 바이너리를 빌드하려면 java_binary 규칙을 사용합니다.

       java_binary(
          name = "everything",
          srcs = glob(["src/main/java/**/*.java"]),
          resources = glob(["src/main/resources/**"]),
          deps = ["//:all-external-targets"],
          main_class = "com.example.Main"
       )
       

     • 속성을 지정합니다.

       • name: 타겟에 의미 있는 이름을 지정합니다. 위의 예에서 타겟은 'everything'이라고 합니다.
       • srcs: globbing을 사용하여 프로젝트의 모든 .java 파일을 나열합니다.
       • resources: globbing을 사용하여 프로젝트의 모든 리소스를 나열합니다.
       • deps: 프로젝트에 필요한 외부 종속 항목을 확인해야 합니다.

     • Guava 프로젝트의 이전에서 이 최상위 BUILD 파일의 아래 예를 살펴보세요.

3. 이제 프로젝트의 루트에 BUILD 파일이 있으므로 프로젝트를 빌드하여 작동하는지 확인합니다. 명령줄에서 워크스페이스 디렉터리에서 bazel build //:everything를 사용하여 Bazel로 프로젝트를 빌드합니다.

   이제 Bazel을 사용하여 프로젝트가 성공적으로 빌드되었습니다. 프로젝트의 증분 빌드를 허용하려면 BUILD 파일을 더 추가해야 합니다.

Guava 프로젝트 예시: 하나의 BUILD 파일로 시작

Guava 프로젝트를 Bazel로 이전할 때 처음에는 하나의 BUILD 파일을 사용하여 전체 프로젝트를 빌드합니다. 작업공간 디렉터리에 있는 이 초기 BUILD 파일의 내용은 다음과 같습니다.

java_library(
    name = "everything",
    srcs = glob([
        "guava/src/**/*.java",
        "futures/failureaccess/src/**/*.java",
    ]),
    javacopts = ["-XepDisableAllChecks"],
    deps = [
        "@maven//:com_google_code_findbugs_jsr305",
        "@maven//:com_google_errorprone_error_prone_annotations",
        "@maven//:com_google_j2objc_j2objc_annotations",
        "@maven//:org_checkerframework_checker_qual",
        "@maven//:org_codehaus_mojo_animal_sniffer_annotations",
    ],
)

3. BUILD 파일 추가 생성 (선택사항)

첫 번째 빌드를 완료한 후 확인했듯이 Bazel은 BUILD file 하나로도 작동합니다. 세부 타겟이 있는 BUILD 파일을 추가하여 빌드를 더 작은 청크로 나누는 것이 좋습니다.

타겟이 여러 개인 BUILD 파일이 여러 개 있으면 빌드의 세부사항이 증가하여 다음이 허용됩니다.

• 프로젝트의 증분 빌드 증가
• 빌드의 병렬 실행 증가
• 향후 사용자를 위해 빌드의 유지관리성을 개선합니다.
• 패키지 간 타겟의 공개 상태를 제어하여 구현 세부정보가 공개 API로 누출되는 라이브러리와 같은 문제를 방지할 수 있습니다.

BUILD 파일을 추가하는 방법에 관한 도움말:

• 각 Java 패키지에 BUILD 파일을 추가하여 시작할 수 있습니다. 종속 항목이 가장 적은 Java 패키지부터 시작하여 종속 항목이 가장 많은 패키지까지 진행합니다.
• BUILD 파일을 추가하고 타겟을 지정할 때 이러한 새 타겟을 종속된 타겟의 deps 섹션에 추가합니다. glob() 함수는 패키지 경계를 넘지 않으므로 패키지 수가 늘어날수록 glob()와 일치하는 파일이 줄어듭니다.
• main 디렉터리에 BUILD 파일을 추가할 때마다 해당 test 디렉터리에 BUILD 파일을 추가해야 합니다.
• 패키지 간 공개 상태를 적절하게 제한해야 합니다.
• BUILD 파일 설정의 오류 문제 해결을 간소화하려면 각 빌드 파일을 추가할 때 Bazel로 프로젝트가 계속 빌드되는지 확인하세요. bazel build //...를 실행하여 모든 타겟이 여전히 빌드되는지 확인합니다.

4. Bazel을 사용하여 빌드

빌드 설정을 검증하기 위해 BUILD 파일을 추가하면서 Bazel을 사용하여 빌드해 왔습니다.

원하는 세부사항으로 BUILD 파일이 있으면 Bazel을 사용하여 모든 빌드를 생성할 수 있습니다.