如果您刚开始接触 Bazel,请先学习使用 Bazel 构建 Android 教程。
概览
Bazel 可以在多种不同的 build 配置中运行,其中包括一些使用 Android 原生开发套件 (NDK) 工具链的 build。这意味着,可以直接在 Bazel 中针对 Android 编译常规的 cc_library
和 cc_binary
规则。Bazel 会使用 android_ndk_repository
代码库规则完成此操作。
前提条件
请确保您已安装 Android SDK 和 NDK。
如需设置 SDK 和 NDK,请将以下代码段添加到 WORKSPACE
中:
android_sdk_repository(
name = "androidsdk", # Required. Name *must* be "androidsdk".
path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)
android_ndk_repository(
name = "androidndk", # Required. Name *must* be "androidndk".
path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)
如需详细了解 android_ndk_repository
规则,请参阅构建百科全书条目。
如果您使用的是最新版本的 Android NDK(r22 及更高版本),请使用 android_ndk_repository
的 Starlark 实现。按照相关 README 文件中的说明进行操作。
快速入门
如需构建适用于 Android 的 C++,只需将 cc_library
依赖项添加到您的 android_binary
或 android_library
规则即可。
以 Android 应用的以下 BUILD
文件为例:
# In <project>/app/src/main/BUILD.bazel
cc_library(
name = "jni_lib",
srcs = ["cpp/native-lib.cpp"],
)
android_library(
name = "lib",
srcs = ["java/com/example/android/bazel/MainActivity.java"],
resource_files = glob(["res/**/*"]),
custom_package = "com.example.android.bazel",
manifest = "LibraryManifest.xml",
deps = [":jni_lib"],
)
android_binary(
name = "app",
deps = [":lib"],
manifest = "AndroidManifest.xml",
)
此 BUILD
文件会生成以下目标图表:
图 1. 包含 cc_library 依赖项的 Android 项目的 build 图。
如需构建应用,只需运行以下命令:
bazel build //app/src/main:app
bazel build
命令会编译 Java 文件、Android 资源文件和 cc_library
规则,并将所有内容打包到 APK 中:
$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF
Bazel 会将所有 cc_ libraries 编译为单个共享对象 (.so
) 文件,该文件默认针对 armeabi-v7a
ABI。如需同时为多个 ABI 更改此设置或进行 build,请参阅配置目标 ABI 部分。
示例设置
您可以在 Bazel 示例代码库中找到此示例。
在 BUILD.bazel
文件中,使用 android_binary
、android_library
和 cc_library
规则定义了三个目标。
android_binary
顶级目标用于构建 APK。
cc_library
目标包含具有 JNI 函数实现的单个 C++ 源文件:
#include <jni.h>
#include <string>
extern "C"
JNIEXPORT jstring
JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
JNIEnv *env,
jobject /* this */) {
std::string hello = "Hello from C++";
return env->NewStringUTF(hello.c_str());
}
android_library
目标指定了 Java 源代码、资源文件和对 cc_library
目标的依赖项。在此示例中,MainActivity.java
会加载共享对象文件 libapp.so
,并定义 JNI 函数的方法签名:
public class MainActivity extends AppCompatActivity {
static {
System.loadLibrary("app");
}
@Override
protected void onCreate(Bundle savedInstanceState) {
// ...
}
public native String stringFromJNI();
}
配置目标 ABI
如需配置目标 ABI,请使用 --android_platforms
标志,如下所示:
bazel build //:app --android_platforms=comma-separated list of platforms
与 --platforms
标志一样,传递给 --android_platforms
的值是 platform
目标的标签,使用标准约束值来描述您的设备。
例如,对于搭载 64 位 ARM 处理器的 Android 设备,您可以按如下方式定义平台:
platform(
name = "android_arm64",
constraint_values = [
"@platforms//os:android",
"@platforms//cpu:arm64",
],
)
每个 Android platform
都应使用 @platforms//os:android
操作系统限制条件。如需迁移 CPU 约束条件,请查看以下图表:
CPU 值 | 平台 |
---|---|
armeabi-v7a |
@platforms//cpu:arm |
arm64-v8a |
@platforms//cpu:arm64 |
x86 |
@platforms//cpu:x86_32 |
x86_64 |
@platforms//cpu:x86_64 |
当然,对于多架构 APK,您需要传递多个标签,例如:--android_platforms=//:arm64,//:x86_64
(假设您在顶级 BUILD.bazel
文件中定义了这些标签)。
Bazel 无法选择默认 Android 平台,因此必须使用 --android_platforms
定义和指定平台。
根据 NDK 修订版本和 Android API 级别,提供以下 ABI:
NDK 修订版本 | ABI |
---|---|
16 及更低版本 | armeabi、armeabi-v7a、arm64-v8a、mips、mips64、x86、x86_64 |
17 岁及以上 | armeabi-v7a、arm64-v8a、x86、x86_64 |
如需详细了解这些 ABI,请参阅 NDK 文档。
不建议为发布 build 使用多 ABI 脂肪 APK,因为这类 APK 会增加 APK 的大小,但对开发和质量检查 build 很有用。
选择 C++ 标准
根据 C++ 标准,使用以下标志进行构建:
C++ 标准 | 标志 |
---|---|
C++98 | 默认,无需任何标志 |
C++11 | --cxxopt=-std=c++11 |
C++14 | --cxxopt=-std=c++14 |
C++17 | --cxxopt=-std=c++17 |
例如:
bazel build //:app --cxxopt=-std=c++11
如需详细了解如何使用 --cxxopt
、--copt
和 --linkopt
传递编译器和链接器标志,请参阅用户手册。
也可以使用 copts
和 linkopts
在 cc_library
中将编译器和链接器标志指定为属性。例如:
cc_library(
name = "jni_lib",
srcs = ["cpp/native-lib.cpp"],
copts = ["-std=c++11"],
linkopts = ["-ldl"], # link against libdl
)
在不使用 android_binary
的情况下构建适用于 Android 的 cc_library
如需在不使用 android_binary
的情况下为 Android 构建独立的 cc_binary
或 cc_library
,请使用 --platforms
标志。
例如,假设您已在 my/platforms/BUILD
中定义 Android 平台:
bazel build //my/cc/jni:target \
--platforms=//my/platforms:x86_64
这种方法会影响整个 build 树。
可以将这些标志放入 project/.bazelrc
中的 bazelrc
配置(每个 ABI 对应一个配置):
common:android_x86 --platforms=//my/platforms:x86
common:android_armeabi-v7a --platforms=//my/platforms:armeabi-v7a
# In general
common:android_<abi> --platforms=//my/platforms:<abi>
然后,如需为 x86
构建 cc_library
,例如,请运行以下命令:
bazel build //my/cc/jni:target --config=android_x86
一般来说,可针对低级别目标(如 cc_library
)或在您确切构建目标时使用此方法;对于您希望构建大量无法控制的目标的高级别目标,请依赖于从 android_binary
自动转换配置。